【VBA】マッチしない想定の正規表現にマッチしてしまう

Question

表題の通りですが、VBAの正規表現が上手く機能しません。

マッチさせたい文字列①
「OK改行yyyy/mm/dd」か「NG改行yyyy/mm/dd」
例）
OK
2020/11/11

例）
NG
2020/11/11

マッチさせたい文字列②
「NG改行yyyy/mm/dd改行OK改行yyyy/mm/dd」
例）
NG
2020/11/11
OK
2020/11/12

★プログラムの概要★
入力されたセル値に対して①に合致するか判定し、合致しない場合は、②に合致するか判定する。
どちらにも合致しない場合は、ダイアログボックスに、どのセルへの入力値がマッチしていないか表示する。

★事象の詳細★
以下のセル値を入力しています。

OK
2020/11/11
OK
2020/11/11

Sub checkValue()

    Dim date_pattern As String  '// 日付の正規表現パターン
    Dim is_correct As Boolean   '// テスト結果入力値の判定フラグ
    Dim msg As String           '// ダイアログボックスに表示するメッセージ

    '// デフォルト値を設定
    is_correct = True
    date_pattern = "[0-9]{4}/(0[1-9]|1[0-2])/(0[1-9]|[12][0-9]|3[01])" '// yyyy/mm/dd

    '// 正規表現オブジェクトを生成
    Set re = New RegExp
    re.Pattern = "^(T|NT)|(OK|NG)\n" & date_pattern & "$" '// 「T」か「NT」か「OK\nyyyy/mm/dd」か「NG\nyyyy/mm/dd」


    For i = 1 To 5
        For j = 1 To 7
            ' // 正規表現にマッチしない場合
            If re.Test(Worksheets(2).Cells(i, j)) = False Then '// ①の条件判定
                Debug.Print "1 if"
                '// 「T」か「NT」か「NG\nyyyy/mm/dd\nOK\nyyyy/mm/dd」か
                re.Pattern = "^NG\n" & date_pattern & "\nOK\n" & date_pattern & "$"
                ' // 正規表現にマッチしない場合
                If re.Test(Worksheets(2).Cells(i, j)) = False Then '// ②の条件判定
                    '// フラグを偽にする
                    is_correct = False
                End If
            Else
                Debug.Print "1 else"
            End If

            '// テスト結果入力値が不正であれば終了
            If is_correct = False Then
                msg = Worksheets(2).Cells(i, j).Address(RowAbsolute:=False, ColumnAbsolute:=False) & "の値が不正です。(" & Worksheets(2).Cells(i, j) & ")"
                MsgBox msg
                Exit Sub
            End If
        Next j
    Next i
    msg = "問題ありません。"
    MsgBox msg
End Sub

この場合、①と②のどちらにも、マッチしないはずですが、イミディエイトウィンドウに「"1 else"」と表示されるので、①の判定部分でマッチしています。なぜでしょうか。ソースコードでおかしな部分がありますでしょうか。

※補足
・(T|NT)の部分は気にしないでください。上手く動作しています。
・ループ変数の「i」「j」はセルの位置を指します。

以上です。
よろしくお願い致します。

Answer 1

全体のパターンが^(T|NT)|(OK|NG)\n（日付パターン略）$となりますが、これでは「TまたはNTで始まるもの」と「（OKまたはNG）（改行）日付で終わるもの」という選択となっています。

Comments

[Chandler_Bing]

ありがとうございます。

ではどのように記述すれば、
「OK」か「NG」で始まり、改行、日付で終わるパターン
か
「T」か「NT」
を判定できますでしょうか。
^(OK|NG)\n（日付パターン略）$
のみを記述し、TとNTは、また別の条件分岐で聞いた方がよいのでしょうか。

[maisumakun]

^と$の間を1つの丸括弧に入れてください。

^(T|NT|(OK|NG)\n（日付パターン略）)$

[maisumakun]

> (T|NT)の部分は気にしないでください

それがあるがゆえの問題だったのですが…

[Chandler_Bing]

なるほど、、、お騒がせしました。
ありがとうございました。

[Chandler_Bing]

申し訳ありません。
もう一点、追加で質問させて下さい。

^(T|NT)|(OK|NG)\n（日付パターン略）$

上記の正規表現の場合は「「TまたはNTで始まるもの」と「（OKまたはNG）（改行）日付で終わるもの」」になると回答を頂きました。

始まり（^）が(T|NT)の部分だけに影響し、終わり（$）が(OK|NG)\n（日付パターン略）の部分だけに影響する理由は

「^(T|NT) OR (OK|NG)\n（日付パターン略）$」という判断になっており「^」と「$」が、
(T|NT)と(OK|NG)\n（日付パターン略）の両方それぞれに掛かっていないから、という認識であっていますでしょうか。

[maisumakun]

そのとおりです。

なお、|で選択される両側に^と$を入れて、「^(T|NT)$|^(OK|NG)\n（日付パターン略）$」のような形で対応することもできます。

[Chandler_Bing]

ありがとうございました。
正規表現への理解が、また深まりました。