Shaderをマテリアルにアタッチするとマテリアルエラーの色になる

Question

こんにちは。
こちらの記事を参考にして、炎のエフェクトを作成しています。
https://styly.cc/ja/tips/shader-effect-fire/
〇発生している問題・エラー
記事の中では、ParticleにMaterialをアタッチすると白い四角のParticleとなる記述ですが、エラーの色（ピンク）になってしまいました。解決方法で何かアドバイスいただけると嬉しいです。
質問がわかりにくくてすみませんが、よろしくお願いいたします。

〇出ているエラーメッセージ Consoleにはエラーメッセージは出力されていません。 しかし、Inspectorにエラーメッセージが表示されています。（添付画像）

自分が行った手順が間違っている可能性がありますので、手順を記載します。
1.Project>Shader>Unlit Shaderで新規Shaderを作成、名前をFireとする。
2.参考サイトで紹介されているコードを、コピペしてFireに貼る。
3.新規Materialを作成し、参考サイトと同様のテクスチャを設定する。
4.新規で作成したParticle Systemに３で作成したMaterialをアタッチする。

Shader "Custom/Particles/Alpha Blended - Clamp(TEXCOORD0.z)" 
{ Properties{ _MainTex("Grayscale Texture", 2D) = "white" {} }

Category{
        Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "PreviewType" = "Plane" }
        Blend SrcAlpha OneMinusSrcAlpha // Alpha Blended
        ColorMask RGB
        Cull Off Lighting Off ZWrite Off

        SubShader {
            Pass {

                CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag
                #pragma target 2.0
                #pragma multi_compile_particles
                #pragma multi_compile_fog

                #include "UnityCG.cginc"

                sampler2D _MainTex;
                fixed4 _TintColor;

                struct appdata_t {
                    float4 vertex : POSITION;
                    fixed4 color : COLOR;
                    float4 texcoord : TEXCOORD0;
                    UNITY_VERTEX_INPUT_INSTANCE_ID
                };

                struct v2f {
                    float4 vertex : SV_POSITION;
                    fixed4 color : COLOR;
                    float2 texcoord : TEXCOORD0;
                    float2 texcoord2 : TEXCOORD1;
                    UNITY_FOG_COORDS(1)
                    UNITY_VERTEX_OUTPUT_STEREO
                };

                float4 _MainTex_ST;

                v2f vert(appdata_t v)
                {
                    v2f o;
                    UNITY_SETUP_INSTANCE_ID(v);
                    UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
                    o.vertex = UnityObjectToClipPos(v.vertex);
                    o.color = v.color;
                    o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
                    o.texcoord2.xy = v.texcoord.zw; // Copy TEXCOORD0.zw
                    UNITY_TRANSFER_FOG(o,o.vertex);
                    return o;
                }

                fixed4 frag(v2f i) : SV_Target
                {
                    fixed4 texColor = i.color * tex2D(_MainTex, i.texcoord);
                    fixed4 col = i.color * step(i.texcoord2.x, texColor.r);
                    col.rgb *= col.a;
                    UNITY_APPLY_FOG_COLOR(i.fogCoord, col, fixed4(0,0,0,0)); // fog towards black due to our blend mode
                    return col;
                }
                ENDCG
            }
        }
}






ード

Answer 1

UNITY_FOG_COORDS(1)をUNITY_FOG_COORDS(2)にしたところ、動くようになりました。ありがとうございました。

Answer 2

おそらくコピペミスか編集ミスでファイル末尾に}が1つ不足していますので追加すれば白い四角のパーティクルが表示されます。
質問中のコードの最後のードは記入誤りだと思いますが、実際のコードに入っているなら削除してください。

Comments

[MikanChan]

teratailへのコピペミスで、一つ}が抜けてしまっていたようです。実際のコードには入っていました。すみません。（本文訂正しました）

[shiena]

記事のリンク先にサンプルプロジェクトがあり、以下が同じシェーダーです。これなら動作するはずです。また手元のコードと比較すると空白や改行以外に差分があるはずなので誤りの元を探してみてください。

https://github.com/styly-dev/STYLY-Unity-Examples/blob/master/Assets/STYLY_Examples/ShurikenShader_Fire/Shaders/Particle-AlphaBlended-Clamp.shader