アプリカティブファンクターについて

Question

書籍「すごいHaskellたのしく学ぼう！」を現在学習中です。

(+) <$> (*2) <*> (+10)

第14章に上記のコードが出てきましたが、最終的にどんな動作をする関数になるのか分かりません。
実行してみると、引数を3倍した値?に10を足したような結果が出てきます。

1引数関数同士をfmapすると関数合成と同じになるので(+) <$> (*2)が(+) ((*2) x)になるのは理解できますが、
これに対して<*> (+10)を適用するとどんな風になるのでしょうか。

<*>は以下のように「ファンクターに包まれた関数を取り出して、ファンクター値に適用する」という風に理解をしてしまっています。

(+) <$> Just 10 <*> Just 20

Answer 1

結論からいうと次のようになります。

(+) <$> (* 2) <*> (+ 10) ≡ \x -> (x * 2) + (x + 10)

---

ここからはなぜそうなるのかを見ていきます。

まず (<$>) と (<*>) の定義を見ましょう。

-- https://hackage.haskell.org/package/base-4.14.0.0/docs/src/GHC.Base.html#line-973
instance Applicative ((->) r) where
    …
    (<*>) f g x = f x (g x)
    …
infixl 4 <*>

-- https://hackage.haskell.org/package/base-4.14.0.0/docs/src/Data.Functor.html#%3C%24%3E
(<$>) :: Functor f => (a -> b) -> f a -> f b
(<$>) = fmap
infixl 4 $>

-- https://hackage.haskell.org/package/base-4.14.0.0/docs/src/GHC.Base.html#line-973
instance Functor ((->) r) where
    fmap = (.)

この定義に沿って式変形をしていきます。

  (+) <$> (* 2) <*> (+ 10)
≡〈優先順位の括弧を明記〉-- (1)
  ((+) <$> (* 2)) <*> (+ 10)
≡〈(<*>) の定義を代入〉 -- (2)
  \x -> ((+) <$> (* 2)) x ((+ 10) x)
≡〈中置記法に変換〉 -- (3)
  \x -> ((+) <$> (* 2)) x (x + 10)
≡〈(<$>) の定義を代入〉
  \x -> ((+) . (* 2)) x (x + 10)
≡〈(.) の定義を代入〉
  \x -> (\y -> (+) ((* 2) y)) x (x + 10)
≡〈中置記法に変換〉
  \x -> (\y -> (+) (y * 2)) x (x + 10)
≡〈関数適用〉
  \x -> ((+) (x * 2)) (x + 10)
≡〈中置記法に変換〉
  \x -> (x * 2) + (x + 10)

1. (<$>) と (<*>) はともに同じ優先順位の左結合です。
2. (<*>) f g x = f x (g x) は (<*>) = \f -> \g -> \x -> f x (g x) と同じです。
3. (+ 10) x が x + 10 になります。

定義に沿ってひとつずつ変形してくと理解が深まると思います。

Comments

[okitou]

どうやってその式になるのか詳細に書いていただいたのでなんとか理解できました！
ちゃんと実装を確認することも重要ですね。

非常に丁寧なご回答感謝いたします。

Answer 2

@kakkun61 さんの回答に補足します。

要約すると関数->における<*>は、同じ引数を共有しながら合成する演算子となっています。

例えば<*>の定義

instance Applicative ((->) r) where
    …
    (<*>) f g x = f x (g x)

においても、xをfとg両方に渡しながら（共有させながら）fとgを合成していますよね？

そしてラムダ式に変換した、

(+) <$> (* 2) <*> (+ 10) ≡ \x -> (x * 2) + (x + 10)

でも、やはりxを(* 2)と(+ 10)という二つの関数で共有しています。

Comments

[okitou]

"同じ引数を共有しながら"でかなりイメージを掴めました。

とても分かりやすい補足ありがとうございます。