PNG画像のピクセルサイズ取得について

Question

VBAで取得した画像サイズと、プロパティで確認したサイズ（ピクセル）が異なっており、原因を知りたく質問いたしました。
（※サイズとは、画像の縦横の長さのサイズです。）

このサイトを参考にPNG画像のサイズを取得しようと試みました。
（URL：https://excel-ubara.com/excelvba4/EXCEL263.html）
※「AddPictureしてから取得」の所です。

ほぼ同じコードですが以下にそのコードを記載します。

Sub sample2()
    Dim sp As Shape
    Dim pWidth As Long
    Dim pheight As Long
    Dim Path As String

    Path = "パスがここに入ります.png"'ここにPNG画像のパスが入ります。

    If strFile = "False" Then
        Exit Sub
    End If

    Set sp = ActiveSheet.Shapes.AddPicture( _
                Filename:=Path, _
                LinkToFile:=False, _
                SaveWithDocument:=True, _
                Left:=0, _
                Top:=0, _
                Width:=0, _
                Height:=0 _
                )
    With sp
        .LockAspectRatio = msoTrue
        .ScaleHeight 1, msoTrue
        .ScaleWidth 1, msoTrue
        pWidth = CLng(.Width * 4 / 3)
        pheight = CLng(.Height * 4 / 3)
        .Delete
    End With
    MsgBox "横：" & pWidth & vbLf & "縦：" & pheight
End Sub

画像のプロパティで確認すると、155×211ですが、最後のMsgBoxでは「幅68　縦92」と表示されます。
比率を調べると、縦、横共に2.279・・・・　となるのですが関連性がわかりません。
プロパティで表示されているピクセルと、コード中でのピクセルは異なるものなのでしょうか。

サイトの上部には「ピクセル数を取得する方法について・・・」とあるので、「.Width * 4 / 3」でピクセル数になっているとは思うのですが。

原因、対策についてご助言いただければと思います。
よろしくお願いします。

Answer 1

質問のコードで私の環境で試してみましたか、やはり実際のサイズとはズレがありました。
私の場合は、取得サイズに 1.5倍すると実際のサイズになりました。
環境によって変わるようですね。

参考にされたリンク先でも「GDIに依存する」という記述があります。
さらにAPIで取得する方法も紹介されてます。ただ、コードが間違っているのでエラーになりますので、動くように修正したもので試したら正確なサイズが取得できました。（64bitOfficeにも対応するように書き換えましたのでExcel2007以前ではエラーになります。）

Private Declare PtrSafe Function GdiplusStartup Lib "gdiplus" ( _
        ByRef token As LongPtr, _
        ByRef inputbuf As GdiplusStartupInput, _
        Optional ByVal outputbuf As LongPtr = 0) As Long
Private Declare PtrSafe Sub GdiplusShutdown Lib "gdiplus" ( _
        ByVal token As LongPtr)
Private Declare PtrSafe Function GdipLoadImageFromFile Lib "gdiplus" ( _
        ByVal FileName As LongPtr, _
        ByRef image As LongPtr) As Long
Private Declare Function GdipGetImageDimension Lib "gdiplus" ( _
        ByVal image As LongPtr, _
        ByRef Width As Single, _
        ByRef Height As Single) As Long
Private Type GdiplusStartupInput
    GdiplusVersion As Long
    DebugEventCallback As LongPtr
    SuppressBackgroundThread As Long
    SuppressExternalCodecs As Long
End Type

Function GetImgSize(ByVal sImageFilePath As String, _
                 ByRef x As Single, _
                 ByRef y As Single) As Boolean
    Dim uGdiStartupInput As GdiplusStartupInput
    Dim nGdiToken As Long
    Dim nStatus As Long
    Dim hImage As Long
    GetImgSize = False
    x = 0: y = 0
    uGdiStartupInput.GdiplusVersion = 1
    nStatus = GdiplusStartup(nGdiToken, uGdiStartupInput, 0&)
    If nStatus = 0 Then
        nStatus = GdipLoadImageFromFile(ByVal StrPtr(sImageFilePath), hImage)
        If nStatus = 0 Then
            nStatus = GdipGetImageDimension(hImage, x, y)
            If nStatus = 0 Then
                GetImgSize = True
            End If
        End If
        Call GdiplusShutdown(nGdiToken)
    End If
End Function

Sub sample1()
    Dim path As String
    path = "パスがここに入ります.png"

    Dim x As Single, y As Single

    If GetImgSize(path, x, y) Then
        MsgBox "横：" & x & vbLf & "縦：" & y
    Else
        MsgBox "サイズ取得失敗"
    End If
End Sub

Comments

[ice930]

ありがとうございます！
APIさえ習得できれば「出来ること」の幅が広がりそうです！
今のところAPIの知識は有りませんが、今後APIを学習する際に参考にさせていただきます！

Answer 2

他の方の回答にあるようにポイントからピクセルへの換算の問題なので、ディスプレイの拡大率に依存しますね。
具体的にはここです。たぶんあなたの環境では225%なのではないかと。

しばらく前までWindowsではディスプレイの拡大縮小は一般的ではなく、OS上での解像度は現実のディスプレイによらず96dpiに固定されていたので、1ポイント(=1/72インチ)は3/4ドット固定でした。それを前提に作られたプログラムなのだと思います。
拡大率をVBAから取得できれば解決するのですが、方法があるかちょっと分かりません。

---

なるほど、ポイント→ピクセル変換の問題を思わせる状況でしたが、100%であったとなると、hatena19さんの言うとおりそうではないのでしょうね。
私の回答は的外れだったようです。

Comments

[ice930]

画像添付など、分かり易い回答ありがとうございます！
確認したところ、画像の比率は100％となっておりましたが、今後不具合等が起きた際は参考にさせていただきます！

Answer 3

誤回答のため削除いたします。

> VBAで取得した画像サイズと、プロパティで確認したサイズ（ピクセル）が異なっており

~~とのことですが、下記サイトによるとLoadPicture()で取得したオブジェクトの幅・高さの単位はポイントのようです。なので数値が異なっているのではなく単位が異なっているのです。
~~

Excel VBAでJPG・GIF・PNGの画像ファイルから画像サイズを取得してみる

> 取得した幅と高さは単位がポイントなので、ピクセルに変換します。

Comments

[hatena19]

LoadPicture() はPNGには対応していないので、質問のコードは別の方法を使ってます。
よって、ポイント→ピクセル変換の問題ではないです。

[meg_]

> 「.Width * 4 / 3」でピクセル数になっているとは思う
ここより”単位”の問題かと思ってしまいました。

> 155×211ですが、最後のMsgBoxでは「幅68　縦92」と表示
> 比率を調べると、縦、横共に2.279
こちらが質問の意図だったのですね。

VBAの知識もないのに間違った回答をしてしまい申し訳ありませんでした。

[ice930]

とんでもございません。
Lordpictureも良く使用するので、参考になりました！
ありがとうございました！