Access フォーム チェックボックスを用いた同一フィールドの複数条件検索について

Question

Access(2007-2016)のフォームで、チェックボックスを用いて同一フィールドを複数条件で検索したいと思っています。

検索条件は以下のチェックボックスです。
検索ボタンを押すと、「月数」フィールドからここでチェックを入れた月数に合致するレコードが抽出されるようにしたいです。
※「月数」フィールドは1月,2月,3月……12月,終了,未登録の14種類からなる短いテキスト型のフィールド

複数チェックボックスの組み合わせによって条件を分岐するスマートな方法を参考にしようとしたのですが、14つも条件があると分岐の数が2^14=16384ととんでもない数になってしまいます。こういった、チェックボックスによる複数条件検索の分岐が多い場合、どのような検索方法をとるのがスマートなのでしょうか？

※ほかの検索箇所は基本的に以下のようなVBAコードを記述して動かしています。

Private Sub 検索ボタン_Click()
Dim strSearch As String

'変数の初期化'
strSearch = ""

If 検索条件1 <> "" Then
    strSearch = strSearch & "(フィールド名1=" & 検索条件1 & ")"
End If

If 検索条件2 <> "" Then
  If strSearch <> "" Then strSearch = strSearch & " AND "
    strSearch = strSearch & "(フィールド名2='" & 検索条件2 & "')"
End If

Forms!フォーム名.Filter = strSearch
Forms!フォーム.FilterOn = True
Forms!フォーム.AllowAdditions = False

Answer 1

一つのフィールドでの条件ですね。

なら、OR演算子ではなく、In演算子を使えば簡単なコードになります。

例えば、1月、3月、10月、終了 にチェックが入っていたら、
月数 In ('1月','3月','10月','終了') というような条件式でOKです。

Private Sub 検索ボタン_Click()
    Dim strSearch As String

    If Me.Chk1 = True Then
        strSearch = strSearch & ",'1月'"
    End If
    If Me.Chk2 = True Then
        strSearch = strSearch & ",'2月'"
    End If
    If Me.Chk3 = True Then
        strSearch = strSearch & ",'3月'"
    End If
  
    '中略

    If Me.Chk13 = True Then
        strSearch = strSearch & ",'終了'"
    End If
    If Me.Chk14 = True Then
        strSearch = strSearch & ",'未登録'"
    End If

    strSearch = "月数 In (" & Mid(strSearch, 2) & ")"

    With Forms!フォーム名
        .Filter = strSearch
        .FilterOn = True
        .AllowAdditions = False
    End With
End Sub

ベタにIf文を繰り返し記述しましたが、チェックボックスの名前がChk1, Chk2, ・・・,Chk14 というように規則的になっていれば For文でまとめることもできます。

For文でまとめるコード例

チェックボックスの名前 Chk1, Chk2, ・・・,Chk14
対応するラベルの名前 Lbl1, Lbl2, ・・・,Lbl14

Private Sub 検索ボタン_Click()
    Dim strSearch As String

    Dim i As Long
    For i = 1 To 12
        If Me("Chk" & i) = True Then
            strSearch = strSearch & ",'" & Me("Lbl" & i).Caption & "'"
        End If
    Next

    strSearch = "月数 In (" & Mid(strSearch, 2) & ")"

    With Forms!フォーム名
        .Filter = strSearch
        .FilterOn = True
        .AllowAdditions = False
    End With
End Sub

Comments

[ryoya_access]

AccessにはIn演算子というものがあるのですね。ExcelVBAはよく触っていたのですが、Accessは不慣れで困っていたため助かりました。「For文でまとめるコード例」は大変参考になりました。無事実装できました、ありがとうございました。

[ryoya_access]

今後この回答をコピペされる方へ。

Dim i As Long
For i = 1 To 12
If Me("Chk" & i) = True Then
strSearch = strSearch & "," & Me("Lbl" & i).Caption & "'"
End If
Next

の「strSearch = strSearch & "," & Me("Lbl" & i).Caption & "'"」部分、正しくは「strSearch = strSearch & "," & "'" & Me("Lbl" & i).Caption & "'"」のようでした。

「Me("Lbl" & i).Caption」を囲むシングルクオーテーションが後ろにしかなかったため、一応記載しておきます。

[hatena19]

あっ、間違ってますね。ご指摘ありがとうございます。
回答の方、修正しておきます。