VBA ユーザーフォーム コンボボックスについて

Question

画面上にコンボボックス１,2,3があり、入力リストをdatasheetから表示します。

（やりたいこと、実現したいこと）
入力リスト"datasheet"に空白行がある場合、下記のようにコンボボックス２に空白行が表示されました。もちろん間違いではないのですが、ユーザーにそれを選択して欲しくないため、上に詰めることはできますでしょうか。もし詰めることができない時は、空白行を選択したら、エラーメッセージにすればいいのでしょうか。

よろしければ、ご教授いただけませんでしょうか、よろしくお願いいたします。

Private Sub ComboBox2_Change()

    Dim MyData3 As New Collection
    Dim cnt3 As Long
    Dim i3 As Long
    Dim ProductName As Variant  '製品名
    Dim Size        As Variant  'サイズ

    cnt3 = Sheets("datasheet").Range("A1").CurrentRegion.Rows.Count

    ProductName = ComboBox1.Text
    Size = ComboBox2.Text

    ComboBox3.Clear

    'On Error Resume Next
    For i3 = 2 To cnt3
        If CStr(Sheets("datasheet").Range("B" & i3).Value) = ProductName _
        And CStr(Sheets("datasheet").Range("C" & i3).Value) = Size Then
            key = CStr(Sheets("datasheet").Range("D" & i3).Value)
            If isExists(MyData3, key) = False Then
                MyData3.Add key, key
            End If
        End If
    Next i3
    'On Error GoTo 0

    For i3 = 1 To MyData3.Count
        ComboBox3.AddItem MyData3(i3)
    Next

End Sub
Private Sub ComboBox1_Change()
    Dim MyData2 As New Collection
    Dim cnt2 As Long
    Dim i2 As Long
    Dim key         As Variant
    Dim ProductName As Variant  '製品名

    cnt2 = Sheets("datasheet").Range("A1").CurrentRegion.Rows.Count

    ProductName = ComboBox1.Text

    ComboBox2.Clear

    '■重複しないProductNameのリストを作成
    'On Error Resume Next
    For i2 = 2 To cnt2
        If CStr(Sheets("datasheet").Range("B" & i2).Value) = ProductName Then
            key = CStr(Sheets("datasheet").Range("C" & i2).Value)
            If isExists(MyData2, key) = False Then
                MyData2.Add key, key
            End If
        End If
    Next i2
    'On Error GoTo 0

    '■ProductNameのリストを作成

    For i2 = 1 To MyData2.Count
        ComboBox2.AddItem MyData2(i2)
    Next


End Sub

Private Sub UserForm_Initialize()
    Dim MyData1 As New Collection

    Dim cnt As Long
    Dim i As Long
    Dim key         As Variant

    cnt = Sheets("datasheet").Range("A1").CurrentRegion.Rows.Count

    '■重複しないProductNameのリストを作成
    'On Error Resume Next
    For i = 2 To cnt
        key = CStr(Sheets("datasheet").Range("B" & i).Value)
        If isExists(MyData1, key) = False Then
            MyData1.Add key, key
        End If
    Next i
    'On Error GoTo 0


    '■ProductNameのリストを作成

    For i = 1 To MyData1.Count
        ComboBox1.AddItem MyData1(i)
    Next

End Sub
' Collectionの中にすでに登録されているか確認
Function isExists(col As Collection, item As Variant) As Boolean
    Dim Var As Variant
    For Each Var In col
        If Var = item Then
            isExists = True
            Exit Function
        End If
    Next Var
    isExists = False
End Function

Answer 1

        If isExists(MyData1, key) = False Then

の部分に下記のように条件を追加すればいいだけです。

        If key <> "" And isExists(MyData1, key) = False Then

ただし、
こうすると、サイズコンボボックスで空白が選択できない、つまり、数量コンボボックスで -50 が選択できないということになりますが、そういう仕様でいいのでしょうか。

Comments

[koko2]

ありがとうございました。はい、データが揃っていない列は選択できないようにしたかったので、やりたかったことが実現できました。