Initializeでのユーザーフォームへのコントロールの設置

Question

ユーザーフォームへの初期設定（Initialize）で、コマンドボタンを設置する場合として以下の様なコードを作成しました。

Private Sub TestForm_Initialize()
 Dim A As CommandButton
 Set A = TestForm.Controls.Add("Forms.CommandButton.1", "TEST", True)
With A
            .Top = 24
            .Left = 10
            .Height = 20
            .Width = 50
            .Caption = "テスト"
         End With
End Sub

Private Sub TEST_Click()
MsgBox "成功"
End Sub

これを実行するとフォームに何も表示されません。
不足しているコード等有りましたらご教授ください。

上記のコードでは、「Top」や「Left」などの配置場所が一定ですが、ここに変数が入る予定であり、且つ条件式の中に入れ込む予定となっており、「動的」なボタンとなっております。
※静的なボタンは既にツールボックスから挿入しております。

ユーザーフォームでのボタン配置ではなく、Initializeで設定した場合のご回答をいただければ嬉しく思います。
よろしくお願いします。

Answer 1

イベントプロシージャを付けたいなら、
WithEvents をつけてモジュールレベルで宣言してください。

Option Explicit
Dim WithEvents A As CommandButton

Private Sub UserForm_Initialize()

    Set A = UserForm1.Controls.Add("Forms.CommandButton.1", "TEST", True)

    With A
        .Top = 24
        .Left = 10
        .Height = 20
        .Width = 50
        .Caption = "テスト"
    End With

End Sub

Private Sub a_Click()
    MsgBox "成功"
End Sub

---

Initializeで一個のボタンを生成するぐらいなら、静的に追加すればいいことなので、たぶん何かに関連付けて複数のボタンを動的に追加したいのだと思われますが、だとしたら、WithEvents付きのコントロール変数は配列にできないのでクラスモジュールを使う必要が出てきます。

その辺の説明を追記するか、複雑なことなら、これはいったん解決済みにして、別に新規に質問を立てたほうがいいかもです。

Comments

[ice930]

ありがとうございます！
おっしゃる通りの事がやりたかったです（笑）
一旦頭を整理してコードを作り、また質問させていただきます！

[hatena19]

クラスモジュールはかなり敷居が高いので、
予想される最大数のコマンドボタンを非表示で配置しておいて、必要に応じて表示させるという方法も検討してもいいかと思います。

[hatena19]

ice930さんの過去の質問を見てみると、クラスモジュール関連でいろいろ質問してますが、最終目的を出さずに、今回のように部分的な処理の質問だったり、中途半端な質問のため、過去のいきさつを知らない回答者がそれぞれの立場で回答しているため（これは回答者の責任ではないです。いちいち過去の質問の内容まで確認して回答するなんてとてもできないので）、微妙に異なる回答になり、かつ、理解が不十分なまま解決済みにして新たに中途半端な質問をする。その質問に対しては適切なものだとしても、全体から見たら目的とは合わないものだったりてし、結局、どんどん混乱の深みにはまっているように見えます。
まずはクラスから離れて、最初から複数のコントロールを配置しておいて、それで目的のものを作成してみてください。それができたら、この部分が繰り返しが多いので共通化できないか、というような形で質問したほうがいいように思います。

[ice930]

ご指摘ごもっともと思います。
過去の質問を読み返し、「さすがに伝わらないだろう」という質問文の書き方や、「捉え方によっては失礼では？」というコメントも見受けられました。
今後は、「最終目的」や「経緯」「困っている事」を明確にし、必要に応じて画像を張り付けるなど、回答しやすい文章となる様心がけます。

Answer 2

下記コードを試したところ問題なく動作しました。　※他のボタン等は配置していません

Private Sub UserForm_Initialize()

    Dim A As CommandButton
    Set A = UserForm1.Controls.Add("Forms.CommandButton.1", "TEST", True)

    With A
        .Top = 24
        .Left = 10
        .Height = 20
        .Width = 50
        .Caption = "テスト"
    End With
    
End Sub

Comments

[ice930]

ありがとうございます！「Private Sub UserForm_Initialize()」をPrivate Sub TestForm_Initialize()にしていました。

ちなみにイベントを「Private Sub TEST_Click()」と記載したのですが、クリックしても「MsgBox "成功"」が表示されません。
どの様な原因が考えられるでしょうか。

[meg_]

hatena19さんの回答が適切です。

ちなみにツールボックスでボタン等を配置した後、UserForm_Initialize()内で配置位置を変えることも出来ます。（ボタンの数が事前に決まっていればこちらの方法でも良いでしょう）

[ice930]

位置が変わるだけの物については、そのやり方を使わせていただきます！
とても参考になりました
ありがとうございます！！