Access 標準モジュールに移したクリック時イベントコードの「Me」を代替するには

Question

Access(2007-2016)で、利用フォーム間を遷移するためのボタン「Btn_メニュー」を各フォームに配置しており、各フォームの「Btn_メニュー」クリック時イベントに以下のようなコードを書いていました。

Private Sub Btn_メニュー_Click()
　DoCmd.OpenForm "F_メニュー"
　Forms![F_メニュー]![Txt_ログインユーザー名] = Me.Txt_ログインユーザー名.Value
　DoCmd.Close acForm, "F_各フォーム名"
End sub

最近、同じコードはクラスモジュール・標準モジュールにまとめ、そこから呼び出して各フォームで使う方法があるのだと知り、保守運用の観点からその方法に移行したいと考えています。

そこで標準モジュール、各フォームに以下のようなコードを記載しました。

【標準モジュール】
Public Sub メニュー遷移()
 DoCmd.OpenForm "F_メニュー"
 Forms![F_メニュー]![Txt_ログインユーザー名] = Me.Txt_ログインユーザー名.Value
 DoCmd.Close acForm, Me.Name
End Sub

【各フォーム】
Private Sub Btn_メニュー_Click()
 Call メニュー遷移
End Sub

これを実行したところ、「F_メニュー」を開くところまでは動いたのですが、自フォームに記載されているテキストボックス「Txt_ログインユーザー名」の値を「F_メニュー」に代入する3行目の処理と、自フォームを閉じる4行目の処理が上手くいきませんでした。

調べたところ、標準モジュールでは「Me」が使えないとのことでした。代わりに「Screen.ActiveForm」なども試してみたのですが、「指定した式はいずれかの引数とデータ型が一致していません」とのエラーが発生し、なかなかうまく動いてくれません。

標準モジュールにて、「Me」のような対象指定を代わりに行うにはどうすればよいのでしょうか。既出の質問でしたら、参考になるサイトの情報を教えていただけるだけでも助かります。よろしくお願いいたします。

Answer 1

標準モジュールでは Me の変わりは CodeContextObject にすればいいけど、sousukeさんの最初のコードのように引数で渡した方がいいと思います。

CodeContextObject.Txt_ログインユーザー名 とコントロール名を決め打ちすると、コントロール名を修正したときにエラーになったり、バグの原因になりやすいので。

あと、下記のように Function にしておくと、

Public Function メニュー遷移(LoginUserName as variant)
    DoCmd.OpenForm "F_メニュー"
    Forms![F_メニュー]![Txt_ログインユーザー名] = LoginUserName 
    DoCmd.Close acForm, , acSaveNo
End Function

コマンドボタンの「クリック時」プロパティに、

=メニュー遷移([Txt_ログインユーザー名])

と設定するだけで呼び出すことができます。

Comments

[sousuke]

私もやるとしたら完全にこれ。ボタン自体コピペして動くようにするのが自分の中のジャスティス。

[ryoya_access]

皆様丁寧なご回答ありがとうございました。迷いましたが、今回はエラー処理等を踏まえてくださったhatena様をベストアンサーとさせていただきます。勉強になりました。

Answer 2

自分はよくこう記載する。

【標準モジュール】
Public Sub メニュー遷移(Fm as Form)
 DoCmd.OpenForm "F_メニュー"
 Forms![F_メニュー]![Txt_ログインユーザー名] = Fm.Txt_ログインユーザー名.Value
 DoCmd.Close acForm, Fm.Name
End Sub

【各フォーム】
Private Sub Btn_メニュー_Click()
 Call メニュー遷移(Me)
End Sub

Comments

[sousuke]

Docmd.CloseにMeが残ってます笑

[kuma_kuma_]

sousukeさん
指摘ありがとうございます。修正しておきました。

Answer 3

Meの代わりにCodeContextObject使うよろし

といいたいけど名前は省略可だからそれでいいような気もする
ユーザー名は引数で渡すとかTempVars使うとかしてなんとかしよう

Public Sub メニュー遷移(LoginUserName as variant)
 DoCmd.OpenForm "F_メニュー"
 'Forms![F_メニュー]![Txt_ログインユーザー名] = Me.Txt_ログインユーザー名.Value
 Forms![F_メニュー]![Txt_ログインユーザー名] = LoginUserName 
 'DoCmd.Close acForm, Me.Name
 DoCmd.Close acForm,, acSaveNo
End Sub

【各フォーム】
Private Sub Btn_メニュー_Click()
 Call メニュー遷移(Me.Txt_ログインユーザー名.Value)
End Sub

CodeContextObjectに変えただけだとこう。

【標準モジュール】
Public Sub メニュー遷移()
 DoCmd.OpenForm "F_メニュー"
 Forms![F_メニュー]![Txt_ログインユーザー名] = CodeContextObject.Txt_ログインユーザー名.Value
 DoCmd.Close acForm, CodeContextObject.Name
End Sub