Elmのアロー関数の後のタプルが分かりません

Question

下記のコードの( Loading, getRandomCatGif )は何を意味するのでしょうか？？
MorePleaseを実行したときの返り値でしょうか？？
また、Modelの状態を監視しているソースなのですが、Cmdの意味やMorePleaseを押した時の挙動がよく分かっておりません。
ご存知の方がいればお聞きしたいです。

module Main exposing (main)


import Browser
import Html exposing (..)

import Html.Attributes exposing (..)

import Html.Events exposing (..)

import Http
import Json.Decode exposing (Decoder, field, string)



-- MAIN


main : Program () Model Msg
main =
    Browser.document
        { init = init
        , update = update
        , subscriptions = subscriptions
        , view = viewDocument
        }



-- MODEL


type Model
    = Failure
    | Loading
    | Success String


init : () -> ( Model, Cmd Msg )
init _ =
    ( Loading, getRandomCatGif )



-- UPDATE


type Msg
    = MorePlease
    | GotGif (Result Http.Error String)


update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        MorePlease ->
            ( Loading, getRandomCatGif )

        GotGif result ->
            case result of
                Ok url ->
                    ( Success url, Cmd.none )

                Err _ ->
                    ( Failure, Cmd.none )



-- SUBSCRIPTIONS


subscriptions : Model -> Sub Msg
subscriptions model =
    Sub.none



-- VIEW


viewDocument : Model -> Browser.Document Msg
viewDocument model =
    { title = "Some cats", body = [ view model ] }


view : Model -> Html Msg
view model =
    div []
        [ h2 [] [ text "Random Cats" ]
        , viewGif model
        ]


viewGif : Model -> Html Msg
viewGif model =
    case model of
        Failure ->
            div []
                [ text "I could not load a random cat for some reason. "
                , button [ onClick MorePlease ] [ text "Try Again!" ]
                ]

        Loading ->
            text "Loading..."

        Success url ->
            div []
                [ button [ onClick MorePlease, style "display" "block" ] [ text "More Please!" ]
                , img [ src url ] []
                ]



-- HTTP


getRandomCatGif : Cmd Msg
getRandomCatGif =
    Http.get
        { url = "https://api.giphy.com/v1/gifs/random?api_key=dc6zaTOxFJmzC&tag=cat"
        , expect = Http.expectJson GotGif gifDecoder
        }


gifDecoder : Decoder String
gifDecoder =
    field "data" (field "image_url" string)

Comments

[kakkun61]

Haskell ではないので Haskell タグは外してください

Answer 1

init _ =
    ( Loading, getRandomCatGif )

この部分は Model の初期値と最初に実行する Cmd a を指定します。

button [ onClick MorePlease, style "display" "block" ] [ text "More Please!" ]

“More Please!” を押すと onClick で指定した Msg である MorePlease が update の第1引数 msg に渡されます。

（掲載のコードには Msg の定義がありませんので、type Msg = MorePlease であるとして回答しています。）

Comments

[best_engineer]

なるほど！ありがとうございます。