VBA Fuction 戻り値

Question

以下はtarget変数に文字列が入っており、別のシートにその文字列が存在するか判定するプログラムです。
hikaku2プロシージャを複数呼び出して何回か処理しているのですが、別シートに存在するはずなのにFuction関数の戻り値がFalseになってしまいます。
Debug.printで結果がTrueになっていることも確認していますがhikaku2ではElseで処理されてしまいます。
以下のコードの中は問題ないのでしょうか
ちなみに以下のコードとほぼ同じものが、もう一つ存在します。複数回使えないものなどあるのでしょうか？

Sub hikaku2()

e = 2
Set this = ThisWorkbook.Worksheets("イベント")

Do While e = 2

target = this.Cells(2, 7).Value

         Application.ScreenUpdating = False
     
        If target Like "初期表示" Then '初期表示という文字列なら

           Call IsContained2(target)

           If kekka2 = True Then

             this.Cells(e, 9).Value = "一致"
             
           Else '全てこっちで処理されてしますう

             this.Cells(e, 9).Value = "不一致"

           End If
               
        End If
        

        If Not target Like "初期表示" Then　'初期表示という文字列以外なら
        
        Call tes2(target)

           If answer2 = True Then
           this.Cells(e, 9).Value = "一致"
           
           Else　'全てこっちで処理されてしまう
           this.Cells(e, 9).Value = "不一致"
           
           End If

        End If

      e = e + 1

 Loop
     
End Sub



Function IsContained2(target) As Boolean

On Error Resume Next

num2 = Application.WorksheetFunction.Match(target, ThisWorkbook.Worksheets("Sheet3").Range("A1:A1000").Offset(0, nn), 0) '　ここで別シートにtargetがあるか判定　nnは別で更新しています

On Error GoTo 0

If num2 = 0 Then
   kekka2 = False
Else 'こっちになるときもある
   kekka2 = True
End If

End Function




Function tes2(target) As Boolean

On Error Resume Next

num2 = Application.WorksheetFunction.Match(target, ThisWorkbook.Worksheets("Sheet3").Range("A1:A800").Offset(0, nn), 0)

On Error GoTo 0

If num2 = 0 Then
   answer2 = False

Else　'こっちになるときもある
   answer2 = True

End If


End Function

Answer 1

解決済みですが、
Functionの機能を理解されていないようなので、補足説明します。

おそらくkekka2、answer2 をグローバル変数として宣言して(標準モジュールの先頭で宣言)解決したのだと思いますが、せっかくのFunctionの機能がまったく生かされていない使い方なのでもったいないです。
また、グローバル変数はコードの可読性が下がるし、バグの原因になりやすいので避けるべきだとされています。

下記のようにFunctionの戻り値を利用すればグローバル変数を使う必要はありません。
また、nnもグローバル変数としているようですが、引数で渡すように変更しましょう。
（詳細が不明なので、下のコードではグローバル変数のままにしてますが。）

Option Explicit '変数宣言強制 バグを防ぐために必須

Dim nn As Long

Sub hikaku2()
    Dim this As Worksheet
    Set this = ThisWorkbook.Worksheets("イベント")

    Dim e As Long
    e = 2

    Application.ScreenUpdating = False

    Do While e = 2  'このDo While は必要ですか？現状だと常に一回しか実行れません。
        Dim target
        target = this.Cells(2, 7).Value

        If target Like "初期表示" Then    '"初期表示"という文字列なら

            If IsContained2(target) = True Then 'Functionの戻り値で判別
                this.Cells(e, 9).Value = "一致"
            Else
                this.Cells(e, 9).Value = "不一致"
            End If

        Else  '"初期表示"という文字列以外なら

            If tes2(target) = True Then 'Functionの戻り値で判別
                this.Cells(e, 9).Value = "一致"
            Else
                this.Cells(e, 9).Value = "不一致"
            End If

        End If

        e = e + 1

    Loop

    Application.ScreenUpdating = True    '画面更新許可に戻しておく

End Sub

Function IsContained2(target) As Boolean

    On Error Resume Next
    
    Dim num2 As Long
    num2 = Application.WorksheetFunction.Match( _
               target, _
               ThisWorkbook.Worksheets("Sheet3").Range("A1:A1000").Offset(0, nn), _
               0)
                   'ここで別シートにtargetがあるか判定
                   'このnnはどこで取得しているか不明なのでそのままにしているが、
                   'グローバル変数とするのではなく引数で渡すようにすべき
    On Error GoTo 0

    If num2 = 0 Then
        IsContained2 = False '結果を関数名に代入することで戻り値して利用できる。
    Else
        IsContained2 = True '結果を関数名に代入することで戻り値して利用できる。
    End If
    
    '上記の4行は下記のように1行で記述することもできる。
    IsContained2 = (num2 = 0)

End Function

Function tes2(target) As Boolean

    On Error Resume Next

    Dim num2 As Long
    num2 = Application.WorksheetFunction.Match( _
               target, _
               ThisWorkbook.Worksheets("Sheet3").Range("A1:A800").Offset(0, nn), _
               0)
                   'ここで別シートにtargetがあるか判定
                   'このnnはどこで取得しているか不明なのでそのままにしているが、
                   'グローバル変数とするのではなく引数で渡すようにすべき

    On Error GoTo 0

    If num2 = 0 Then
        tes2 = False
    Else
        tes2 = True
    End If
    
    '上記の4行は下記のように1行で記述することもできる。
    tes2 = (num2 = 0)

End Function

Comments

[sousuke]

めんどくさくて書かなかったことをやってもらって申し訳ない気分だぁ…ありがとうございます！m(__)m

[yakumo02]

ご指摘ありがとうございます！

Answer 2

解決してしまっていますが、一言二言。

今回の原因を再発させないためにも、コード内冒頭でOption Explicitを定義することをお勧めします。
これを定義しておくと未定義の変数はエラーになります。

またコード内に全角スペースが3ヵ所をありました（コメント内を除く）
基本的にプログラムのコードに全角スペースは論外です。
VBAは割とルーズなので許されているようですが、他の言語ではほぼエラーになります。
今はVBAだからいいじゃん、という考えもありますが、半角か全角かは意識して使うようにしたほうがよいでしょう。

Comments

[yakumo02]

ご指摘ありがとうございます！

Answer 3

私の認識ではVBAのFunctionの戻り値というのは
「そのFunction内でFunction名に対して代入して呼び出し元に値を返す」
ことを言います。

提示のコードを直すと以下のようになります。

Function IsContained2(target) As Boolean

On Error Resume Next

num2 = Application.WorksheetFunction.Match(target, ThisWorkbook.Worksheets("Sheet3").Range("A1:A1000").Offset(0, nn), 0) '　ここで別シートにtargetがあるか判定　nnは別で更新しています

On Error GoTo 0

If num2 = 0 Then
   ' kekka2 = False
    IsContained2 = False ' Booleanを返す
Else 'こっちになるときもある
   ' kekka2 = True
    IsContained2 = True
End If

End Function

で呼び出し元で「Functionの戻り値」を受け取ります。

    Dim kekka2 As Boolean ' 変数は宣言しましょ
'~~~ 略

    'Call IsContained2(target)
    kekka2 = IsContained2(target)  ' Functionの戻り値を変数に代入する

    if kekka2 = True Then

Answer 4

kekka2もanswer2もどこでも宣言されていないので
各プロシージャ内だけの変数になっています。
そのため見た目は同じ変数でもhikaku2の中では
変数に何も入っておらずFalseになります。

Comments

[yakumo02]

ありがとうございます
宣言していませんでした