Word VBA カーソルの位置から後の全ての塗りつぶしの色を置き換えたい

Question

カーソルの位置から後の全ての塗りつぶしの色を置き換えたいのですが、うまく動作しませんでした。
.Font.Shading.BackgroundPatternColor = -721354906
.Font.Shading.BackgroundPatternColor = -553582746
は、マクロの記録を使用して調べた値です。
Word VBA初心者です。ご教授のほどよろしくお願いします。

Sub replaceText()

With Selection.Find
.Font.Shading.BackgroundPatternColor = -721354906
With .Replacement
.Font.Shading.BackgroundPatternColor = -553582746
End With
.Execute Replace:=wdReplaceAll
End With

End Sub

Answer 1

以下のコードでいかがでしょうか。
一度、別の条件で検索をすると、検索の履歴がデフォルトとして残る場合がありますので、
文書を閉じて、再び開いてから実行してみてください。
私の手元ではうまく行ってます。

Sub replaceText()
    Dim blnExecute As Boolean
    
    Do
        With Selection.Find
            .Font.Shading.BackgroundPatternColor = -721354906
            blnExecute = .Execute
        End With
        With Selection
            .Font.Shading.BackgroundPatternColor = -553582746
            .Collapse Direction:=wdCollapseEnd
        End With
    Loop Until blnExecute = False
    
End Sub

Comments

[addresshopeph]

前回はいろいろとありがとうございました。
度重なるご教授感謝します。
教えていただいたコードでもうまく動作しました。
どうもありがとうございます。

Answer 2

ちょっと調べて書いてみました。
背景色の場合は文字色とは別の手段になるようです。
以下の例では色は定義値の赤と青を使っていますので、適宜置き換えてください。
提示いただいた値か、前回のように「その他の色」から値を引っ張ってきてください。
あと実行前に置換範囲を選択しておいてください。

Sub replaceText()

    With Selection.Find
        .Font.Shading.BackgroundPatternColor = wdColorRed
        While .Execute
            Selection.Font.Shading.BackgroundPatternColor = wdColorBlue
            'Selection.Font.Color = wdColorBlack           ' 指定しないと自動で白になる
            Selection.Collapse wdCollapseEnd
        Wend

    End With

End Sub

ちなみにここのページを参考にしました。

Comments

[addresshopeph]

次のように置き換えて実行しましたが、うまく動作しませんでした。

Sub replace()

With Selection.Find
.Font.Shading.BackgroundPatternColor = -721354906
While .Execute
Selection.Font.Shading.BackgroundPatternColor = -553582746
Selection.Font.Color = wdColorBlack
Selection.Collapse wdCollapseEnd
Wend
End With

End Sub

置換範囲を選択せずに、文書全体(カーソルから後の部分)を全て置換するにはどうすればいいでしょうか。
ご教授のほどよろしくお願いします。

[ttyp03]

色の値を前回同様RGBを使ってみてはどうでしょうか。

文書全体についてはSelectionをActiveDocument.Rangeに置き換えればよいかと。

今手元に実行できる環境がないので、もし間違ってたらすみません。

[addresshopeph]

どこがおかしかったのかわかりませんが、次のコードで何回かやっているうちにうまく動作しました。
どうもありがとうございます。

Sub replace()

With Selection.Find
.Font.Shading.BackgroundPatternColor = -721354906
While .Execute
Selection.Font.Shading.BackgroundPatternColor = -553582746
Selection.Font.Color = wdColorBlack
Selection.Collapse wdCollapseEnd
Wend
End With

End Sub

Answer 3

これではどうでしょうか。

Sub replaceText()
    doc_Sta = Selection.Range.Start
    doc_end = ActiveDocument.Bookmarks("\EndOfDoc").End
    ActiveDocument.Range(doc_Sta, doc_end).Select
    Selection.Font.Shading.BackgroundPatternColor = -553582746
End Sub

Comments

[addresshopeph]

どうもありがとうございます。
カーソルから後の部分の全てを置換するようにするにはどうすればいいでしょうか。

[addresshopeph]

問題が解決しました。
どうもありがとうございます。