コード中で生成されたコマンドボタンの処理の指定

Question

プラットフォームに表示されたURLの左のボタンをクリックした時に、URLをクリップボードにコピーするものが作りたく,必要な数だけコマンドボタン、URLを記載したﾗﾍﾞﾙを生成するコードを作成しました。

コード中でこ必要な数だけコマンドボタンを作成しているのですが、コマンドボタンを押された時の処理は、Private Sub actButton_Click()～end sub と記憶しています。
それぞれのコマンドボタンのコピー先は異なっており、コマンドボタン毎にプロージャを呼び出す場合、各行のプロージャを作成しなければならず、膨大な量になってしまいます。

コマンドボタン作成部分に処理を入力することはできないでしょうか。
以下がコードです。

Sub UserForm_Initialize() '質問用
With UserForm2

Row = ActiveCell.Row '行番号取得

 For n = 1 To 5
  
   With .Controls.Add("Forms.Label.1", "url" & n, True)
        .Top = 34 * n                   'Top位置(表示位置を移動する)
        .Left = 70                          'Left位置
        .Height = 20                        '高さ
        .Width = 250                        '幅
        .BorderStyle = fmBorderStyleSingle  '枠線
        .BackColor = RGB(128, 128, 128)     '背景色
        .ForeColor = RGB(255, 255, 255)     '文字色
        .Font.Name = "メイリオ"             'テキストのスタイル
        .TextAlign = 2                      'テキストの位置
        .FontSize = 16                      'テキストのサイズ
        .Caption = Cells(Row, 5)         '''ここにパスワードの題名を付ける
   End With
  
   With .Controls.Add("Forms.CommandButton.1", "url" & n, True)’ここに処理を入力したいです！
       .Top = 34 * n
       .Left = 10
       .Height = 20
       .Width = 50
       .Caption = "copy"
   End With

  Row = Row + 1
 Next
End With
End Sub

コマンドボタンの部位に「ここに処理を入力したいです！」と書かせていただきました。
よろしくお願いします。

Answer 1

イベントであればこんな感じです。
Classモジュール名:EventButtonClass

'(Test_Sample_Miniature)
Private Const MAX_CONTROL_NUMBER = 100
Private ctrlBtn(1 To MAX_CONTROL_NUMBER) As New EventButtonClass
Sub UserForm_Initialize() '質問用   
    With UserForm2
        Row = ActiveCell.Row '行番号取得
        For n = 1 To 5
            With .Controls.Add("Forms.Label.1", "url" & n, True)
                 .Top = 34 * n                   'Top位置(表示位置を移動する)
                 .Left = 70                          'Left位置
                 .Height = 20                        '高さ
                 .Width = 250                        '幅
                 .BorderStyle = fmBorderStyleSingle  '枠線
                 .BackColor = RGB(128, 128, 128)     '背景色
                 .ForeColor = RGB(255, 255, 255)     '文字色
                 .Font.Name = "メイリオ"             'テキストのスタイル
                 .TextAlign = 2                      'テキストの位置
                 .FontSize = 16                      'テキストのサイズ
                 .Caption = Cells(Row, 5)         '''ここにパスワードの題名を付ける
            End With
            
            Dim NewB As CommandButton
            Set NewB = UserForm2.Controls.Add("Forms.CommandButton.1", "url" & n, True)
            Call ctrlBtn(n).SetCtrl(NewB)
            NewB.Top = 34 * n
            NewB.Left = 10
            NewB.Height = 20
            NewB.Width = 50
            NewB.Caption = "copy"
            Row = Row + 1
        Next
    End With
End Sub

Private WithEvents tgtCtrl As MSForms.CommandButton
Public Sub SetCtrl(new_ctrl As MSForms.CommandButton)
  Set tgtCtrl = new_ctrl
End Sub
Private Sub tgtCtrl_Click()
  MsgBox "コントロール名: " & tgtCtrl.Name
End Sub

Comments

[ice930]

ご回答ありがとうございます。
理解を深めるため、各行の意味を確認しながら打っているのですが、
Private Const MAX_CONTROL_NUMBER = 100
の部分がわかりません。
単に For分の中に数字の100を第入した場合や、数値を50にした場合の影響などご教授いただけると幸いです。

[tosi]

Private Const MAX_CONTROL_NUMBER = 100
はクラスから作成されるオブジェクト最大可能数です。
画面ではCopyボタンが5ケありますので、100でなく5でも構いませんし、
または、
Private ctrlBtn(1 To 5)の固定値でも良いです。
または、
Private ctrlBtn1 As New EventButtonClass
Private ctrlBtn2 As New EventButtonClass
Private ctrlBtn3 As New EventButtonClass
Private ctrlBtn4 As New EventButtonClass
Private ctrlBtn5 As New EventButtonClass
とCopyボタン用に5ケ準備してそれぞれを割り当てても良いです。

[ice930]

ありがとうございます！
理解できました！
他でも応用できそうです！

Answer 2

こちらの記事を参考にしてみてください。
クラスを作って、そちらでイベントを拾う形になります。
全てのボタンが同じクラスのイベントに飛んでくるので、何かで識別しないといけません。
クラス内にメンバ変数を用意し番号や何かを入れておいてもいいですし、ボタン自体のプロパティで判定してもよいかもしれません。
Tagプロパティに情報を持たせるのはよくやる手です。

   With .Controls.Add("Forms.CommandButton.1", "url" & n, True)
       .Top = 34 * n
       .Left = 10
       .Height = 20
       .Width = 50
       .Caption = "copy"
       .Tag = n                  ' Tagに番号を入れておく

クラス側で拾える。

Private Sub myCmdBtn_Click()
    MsgBox myCmdBtn.Tag
End Sub

Answer 3

クラスモジュールを使ってイベントの共通化ができます。

「VBA クラスモジュール イベント 共通化」で検索するとサンプルコードはいろいろ見つかります。

VBA クラスモジュール イベント共通 - Google 検索

---

この質問の場合、コマンドボタンとラベルがワンセットなので、クラスモジュールもその２つをセットにしたものにするといいでしょう。

クラスモジュール CmdBtnWithLabel

Option Explicit

Private WithEvents myCmdBtn As MSForms.CommandButton
Private myLabel As MSForms.Label

Private Sub myCmdBtn_Click()
    If myLabel.Caption = "" Then Exit Sub
   
    With New MSForms.DataObject
        .SetText myLabel.Caption 'ラベルのCaptionをDataObjectに格納する
        .PutInClipboard          'DataObjectのデータをクリップボードに格納する
    End With

    MsgBox "URLをクリップボードにコピーしました。"
End Sub

Public Sub setBtnLbl(Cmdbtn As MSForms.CommandButton, lbl As MSForms.Label)
    Set myCmdBtn = Cmdbtn
    Set myLabel = lbl
End Sub

UserForm2 モジュール

Option Explicit

Dim myCol As Collection
Dim myBtnLbl As CmdBtnWithLabel

Sub UserForm_Initialize()
    Set myCol = New Collection

    Dim row As Long
    row = ActiveCell.row '行番号取得
       
    With Me   
        Dim n As Long
        For n = 1 To 5
            Dim lbl As MSForms.Label
            Set lbl = .Controls.Add("Forms.Label.1", "url" & n, True)
            With lbl
                 .Top = 34 * n                   'Top位置(表示位置を移動する)
                 .Left = 70                          'Left位置
                 .Height = 20                        '高さ
                 .Width = 250                        '幅
                 .BorderStyle = fmBorderStyleSingle  '枠線
                 .BackColor = RGB(128, 128, 128)     '背景色
                 .ForeColor = RGB(255, 255, 255)     '文字色
                 .Font.Name = "メイリオ"             'テキストのスタイル
                 .TextAlign = 2                      'テキストの位置
                 .FontSize = 16                      'テキストのサイズ
                 .Caption = Cells(row, 5)         '''ここにパスワードの題名を付ける
            End With
            
            Dim btn As MSForms.CommandButton
            Set btn = .Controls.Add("Forms.CommandButton.1", "url" & n, True)
            With btn
                .Top = 34 * n
                .Left = 10
                .Height = 20
                .Width = 50
                .Caption = "copy"
            End With
            
             Set myBtnLbl = New CmdBtnWithLabel
             myBtnLbl.setBtnLbl btn, lbl
             myCol.Add myBtnLbl
            
            row = row + 1
         Next
     
    End With
End Sub

Comments

[ice930]

ご回答ありがとうございます。
ﾕｰｻﾞｰﾌｫｰﾑからステップインで実行すると、CmdBtnWithLabelのところで、「ユーザー定義型はていぎされていません」と表示されます。
解決策としてツール→参照設定　からライブラリファイルを追加しようかと思ったのですが、何を追加していいかわかりません・・・。
もしご存じでしたら必要なライブラリファイルの名称と、このような時に何のライブラリが必要か知る方法をご教授いただけるとありがたいです。

[radames1000]

横からですが。クラスモジュールを作ってオブジェクト名を「CmdBtnWithLabel」にしてくださいね。

[hatena19]

radames1000さん、フォローありがとうございます。
作成したクラスモジュールの名前を「CmdBtnWithLabel」にしてください。