ﾕｰｻﾞｰﾌｫｰﾑにコマンドボタン、ﾗﾍﾞﾙが勝手に作成されてしまいます。

Question

以下のコードでﾕｰｻﾞｰﾌｫｰﾑを作成すると、左上に謎のﾗﾍﾞﾙが出現します。
恐らく複数個重なっているものと思われるのですが、作成した覚えがなく、最下部に記載したシートの要素もひとつづつ数えたのですが数が合わず「なぜ出現したのか」がわかりません。
PCの再起動も試したのですが変わらないので、コード内に原因があるのではと思うのですが解析することが出来ませんでした。

以下の画像が原因のﾌｫｰﾑ画面です。

Sub UserForm_Initialize()
Dim Myitem As Object
Dim MyPass As Object
Dim Cpybtm As Object
Dim i As Long
Dim Top As Long '項目入力開始位置
Dim Row As Long
Dim Col As Long
Dim item As String

Row = ActiveCell.Row '行番号取得

With UserForm3
    Top = 20 '項目開始位置
  
   With .Controls.Add("Forms.Label.1", "ﾀｲﾄﾙ", True)
            .Top = 10                      
            .Left = 10                         
            .Height = 20                        
            .Width = 370                        '幅
            .BorderStyle = fmBorderStyleSingle  '枠線
            .BackColor = RGB(128, 128, 128)     '背景色
            .ForeColor = RGB(255, 255, 255)     '文字色
            .Font.Name = "メイリオ"             'テキストのスタイル
            .TextAlign = 2                      'テキストの位置
            .FontSize = 16                      'テキストのサイズ
            .Caption = Cells(Row, 3)            '''ここにパスワードの題名を付ける
   End With
    
 If Cells(Row, 5) <> "" Then 'URL有れば
   With .Controls.Add("Forms.CommandButton.1", "urlb", True)
       .Top = 34
       .Left = 10
       .Height = 20
       .Width = 50
       .Caption = "アクセス"
    End With
    
    With .Controls.Add("Forms.Label.1", "url", True)
        .Top = 34                     　　　'Top位置(表示位置を移動する)
        .Left = 70                          'Left位置
        .Height = 20                        '高さ
        .Width = 310                        '幅
        .BorderStyle = fmBorderStyleSingle  '枠線
        .BackColor = RGB(128, 128, 128)     '背景色
        .ForeColor = RGB(255, 255, 255)     '文字色
        .Font.Name = "メイリオ"             'テキストのスタイル
        .TextAlign = 2                      'テキストの位置
        .FontSize = 16                      'テキストのサイズ
        .Caption = Cells(Row, 5)            '''ここにパスワードの題名を付ける
    End With
    Top = Top + 24
    
 End If
    
    item = "初期値"
    Col = 5
    i = 0
    
    Do While item <> ""
    i = i + 1
    
    Set Cpybtn = .Controls.Add("Forms.CommandButton.1", "copy" & i, True)
    Set Myitem = .Controls.Add("Forms.Label.1", "MyLabel" & i, True)
    Set MyPass = .Controls.Add("Forms.Label.1", "MyPass" & i, True)
        
        Col = Col + 1
        item = Cells(Row, Col)
        
        If item = "" Then
        Exit Do
        End If
        
        With Myitem  'ここは項目表示
            .Top = Top + 24 * i                     'Top位置(表示位置を移動する)
            .Left = 70                          'Left位置
            .Height = 20                        '高さ
            .Width = 150                        '幅
            .BorderStyle = fmBorderStyleSingle  '枠線
            .BackColor = RGB(128, 128, 128)     '背景色
            .ForeColor = RGB(255, 255, 255)     '文字色
            .Font.Name = "メイリオ"             'テキストのスタイル
            .TextAlign = 2                      'テキストの位置
            .FontSize = 16                      'テキストのサイズ
            .Caption = item             '''ここにパスワードの題名を付ける
         End With
        
        Col = Col + 1
        item = Cells(Row, Col)
        
         With MyPass  'ここは内容表示
            .Top = Top + 24 * i                     'Top位置(表示位置を移動する)
            .Left = 230                      'Left位置
            .Height = 20                        '高さ
            .Width = 150                        '幅
            .BorderStyle = fmBorderStyleSingle  '枠線
            .BackColor = RGB(128, 128, 128)     '背景色
            .ForeColor = RGB(255, 255, 255)     '文字色
            .Font.Name = "メイリオ"             'テキストのスタイル
            .TextAlign = 2                      'テキストの位置
            .FontSize = 16                      'テキストのサイズ
            .Caption = item         '''ここにパスワードの題名を付ける
        End With
         
         With Cpybtn
            .Top = Top + 24 * i
            .Left = 10
            .Height = 20
            .Width = 50
            .Caption = "Copy"                   '表示文字
         End With

        Loop
        .Show
End With
End Sub

設定すべきところが未設定で有るなど、初歩的な部分かもしれませんが、ご指摘いただければ幸いです。
よろしくお願いします。

Comments

[radames1000]

ステップインで一行ずつ確認するのが良いですね。
Initializeだから難しいのであれば
一時的にClickにうつしてみてテストをするのもありです。

[ice930]

ちょうどステップインがわかりずらく困ってました！
途中経過に困ったらCommandButton_Clickで確認するようにします！

Answer 1

Doループ内で、コントロールをAddしてからループ終了判定をしているからではないでしょうか？

順番的にはこうじゃないですかね。

		Do While item <> ""

			Col = Col + 1
			item = Cells(Row, Col)

			If item = "" Then
				Exit Do
			End If

			i = i + 1

			Set Cpybtn = .Controls.Add("Forms.CommandButton.1", "copy" & i, True)
			Set Myitem = .Controls.Add("Forms.Label.1", "MyLabel" & i, True)
			Set MyPass = .Controls.Add("Forms.Label.1", "MyPass" & i, True)

以下略