指定した値を特定のセル範囲に転記

Question

前提・実現したいこと

sheet1のA1の値をsheet2のA2以降にA列の値が空欄ではなくなるまで、
B2以降に値貼付けにしたい。
sheet2のB2以降の書式は"yyyy/mm/dd"の形式にして貼り付けたい

発生している問題・エラーメッセージ

型が一致しません

試したこと

Sub 書き出し2()

Dim i As Range
Dim j As Range
Dim d As Range

j = Sheets("sheet2").Range("A3", Cells(Rows.Count, 1).End(xlUp))
d = Sheets("sheet1").Range("A1")

If j <> "" Then
For i = Sheets("sheet2").Range("A3") To j
d.Value = Sheets("sheet2").Range("B2", Cells(Rows.Count, 2).End(xlUp)).Value
Next
MsgBox "発行日が設定されていません"

End Sub

補足情報（FW/ツールのバージョンなど）

そもそも一つの値をsheet2のB2以降に転記するというソースを間違えている気がします。
sheet2のA2以降に値が入っていれば、sheet2のB2以降に転記するという形で記述したいと思ってます。
A列に値が入る最終行は、日によって変わるため、B列に入る値もA列の値の行数分だけになります。

Comments

[meg_]

１．> sheet1のA1の値をsheet2のA2以降にA列の値が空欄ではなくなるまで、B2以降に値貼付けにしたい。
意味が分かりません。sheet2のA列に張り付けたいのか？B列に張り付けたいのか？ 画像で補足説明いただきたいです。

２．コードは「コードの挿入」で記入してください。

Answer 1

足らない部分は勝手に推測して、下記のような仕様だとして回答します。

sheet1 の A1セルに日付が入力されている。

sheet1 の A1、B1 には項目名が入力されていて、
A2以降にデータが入力されている。

sheet1のA1セルの日付を、A列のデータが入っている最終行までB2以降のB列に転記。

質問のコードはほとんどの行が間違っているので、間違いを一つずつ指摘していくときりがないので、
とりあえず間違いを修正した動くコードを提示しておきます。

Sub 書き出し2()
    Dim i As Long
    Dim j As Long
    Dim d As Date

    j = Sheets("sheet2").Cells(Rows.Count, 1).End(xlUp).Row 'A列最終行

    If IsDate(Sheets("sheet1").Range("A1").Value) Then
        d = Sheets("sheet1").Range("A1").Value

        For i = 2 To j
            Sheets("sheet2").Cells(i, 2).Value = d
        Next
    Else
        MsgBox "発行日が設定されていません"
    End If
End Sub

ご自身のコードとこのコードを比べて違っている部分をなぜ違っているのか調べてください。
それでも分からない場合は、どこがどのように分からないか質問してください。

別案

同じ値を入力するならループを使わなくてもセル範囲に一気に代入することもできます。

Sub 書き出し2()
    Dim j As Long
    Dim d As Date

    If IsDate(Sheets("sheet1").Range("A1").Value) Then
        j = Sheets("sheet2").Cells(Rows.Count, 1).End(xlUp).Row
        d = Sheets("sheet1").Range("A1").Value
        Sheets("sheet2").Range("B2:B" & j).Value = d
    Else
        MsgBox "発行日が設定されていません"
    End If
End Sub

Comments

[VBA_Beginner_yu]

解答ありがとうございます！無事やりたいことができました！
まずはsheet2のA列が空白であるかどうかという判定を書くものかと思い、if文でくくってました。。

同じ値を連続で入力すると思ったら、ループを使うものかと思ったんですが、
ループを使わないほうが、わかりやすいですね！

別の列を参照して、値を転記するときにRange("B2:B" & j)　の「＆」の使うというイメージなんですかね。