【超初心者】エクセル VBA クラスの作り方

Question

【超初心者】エクセル　VBA　クラスモジュールの使い方・作り方がわかりません

よく使用するコードを汎用型にする方法がわかりません。
クラスモジュールにどのように書けばよいのかわからずつまづいています。
初歩的な内容で申し訳ありませんが、書き方を教えて頂けないでしょうか？

以下が検討内容です。

【TextBox】に入力した文字が【ListBox】に存在したら、その項目を選択する

という処理をしたくて以下のようなコードを書いています。
このコードの内【TextBox】【ListBox】のナンバーが変化したコードをいっぱい書く必要があるので
以下のコードを汎用型（クラス？インスタンス？）にしたいと思っています。

例）【TextBox3】の部分がTextBox5　や　TextBox10　になったりします。【ListBox】も同様です。

コード（VBA）
 Dim i As Integer
    
    If TextBox3.Text = "" Then Exit Sub
    
    For i = 0 To ListBox1.ListCount - 1
        If InStr(ListBox1.List(i), TextBox3.Text) <> 0 Then
            ListBox1.Selected(i) = True
        End If
    Next i

Comments

[m.ts10806]

「初心者アイコン」があるのでタイトルや本文に改めて書く必要はないかと思います

Answer 1

それぐらいなら、ユーザー定義関数を作成すればいいのでは。

標準モジュールに

Public Function ListSelect(tarListbox As msForms.Listbox, srcTextbox As msForms.TextBox) As Boolean
    Dim i As Integer

    ListSelect = False
    If srcTextbox.Text = "" Then Exit Function
    With tarListbox
        For i = 0 To .ListCount - 1
            If InStr(.List(i), srcTextbox.Text) <> 0 Then
                .Selected(i) = True
                ListSelect = True
            End If
        Next i
    End With
End Function

使用例

    
    Call ListSelect(ListBox1, TextBox1)

    '結果を確認したいとき
    If ListSelect(ListBox1, TextBox2) = False Then
        MsgBox "該当データはありません。"
    End If

Comments

[riko]

ご回答ありがとうございます。
実際のプログラムで使用させて頂いたところうまくいきました。
書いていただいたコードの内容をよく調べて今後応用させて頂きます。
ありがとうございました！！