VBAでインプットボックスでキャンセルか入力なしの場合ループから抜け出したいがエラーになってしまう

Question

マイクロソフト360エクセルのVBAで
A1に年月を入力し、そのまま2345列に日付の数値を入れると年月に日付をセットしてうえで、入力した日付のみ表示するプログラムです。
インプットボックスでキャンセルか、入力なしの場合にループから抜けるようにしたいのですが、型が一致しないというエラーが出てしまいます。代入された値の長さが0ならという条件にしてみています。
その後、1列目に名前を入力していくのですが、その時も同じことをしているつもりですがここは問題なく動くようです。
よろしくお願いいたします。

Private Sub CommandButton1_Click()

InputYearMonth: 'A1セルに年月を入力させる。日付の形でなければループさせる
Dim ym As String
Dim flg As Boolean

  flg = False
  Do
  
    ym = InputBox(Prompt:="年月を入力してください", Title:="年月入力")
    If Len(ym) = 0 Then Exit Sub
    If IsDate(ym) Then flg = True
  Loop Until flg = True
        
Cells(1, 1).Value = ym

InputDays:
Dim ds As Integer
Dim dates As Date
Dim i As Long

 For i = 1 To 4
    Do
   flg = False
   ds = InputBox(Prompt:=i & "日目の日付を入れてください", Title:="日付入力")'ここで止まってしまう
    If Len(ds) = 0 Then
    Exit For
    ElseIf Len(ds) <> 0 Then
    dates = DateAdd("d", ds - 1, Cells(1, 1).Value)
    End If
   If Month(dates) = Month(CDate(ym)) Then flg = True
   Debug.Print Month(dates)
   Debug.Print Month(CDate(ym))
   If flg = False Then MsgBox "月は変えられません", vbExclamation
  Loop Until flg = True
  
  Range(Cells(1, i + 1), Cells(2, i + 1)).Value = dates
  Cells(1, i + 1).NumberFormatLocal = "d"
  Cells(2, i + 1).NumberFormatLocal = "aaaa"
 Next i
 
Inputpts: '顧客名を入力していく　キャンセルか入力なしで終わりか聞く
Dim pts As String
Dim Result As Long
Dim k As Integer
Dim flg2 As Boolean

 k = 5
 pts = 0
 flg2 = False

Do
 Do
  pts = InputBox(Prompt:="顧客名を入れてください", Title:="名前入力")'ここで同じような処理をさせているつもり
   If Len(pts) <> 0 Then
   Cells(k, 1).Value = pts
   k = k + 1
   End If
 Loop Until Len(pts) = 0
 
   Result = MsgBox("入力を終了しますか？", vbYesNo + vbExclamation)
    If Result = vbYes Then
    flg2 = True
    End If
  
Loop Until flg2 = True

Comments

[maisumakun]

どのようなエラーが出るのですか？

[halmichi]

ありがとうございます。「型が一致しません」というエラーが出ます。

Answer 1

InputBox 関数は戻り値が文字列なので、 Integer 型の変数には結果を受け取れません。
Application オブジェクトの InputBox では Type 引数に 1 を指定すると数値入力ができます。

簡単に使い方を示すと次のようになります。

Dim ds As Integer
ds = Application.InputBox(Prompt:="数値を入力してください", Type:=1)
If ds = False Then
    Debug.Print "Canceled"
    Exit Sub
End If
        
Debug.Print "input value=" + ds

他のパラメーターは InputBox 関数と同じように指定できます。
また、 Application.InputBox は、 Typeパラメーターで入力値を数値に指定すると、未入力の状態で OKボタンを押すと数式エラーとなります。
Typeパラメーターに文字列(指定値としては 2)を指定した時、キャンセルボタンを押すと上の例のように False との比較でキャンセルされたかどうかを判定できます。一方で、未入力の状態でOKボタンを押すと空の(長さがゼロの)文字列を受け取れるので、キャンセルと長さがゼロの文字列を入力したことを区別できます。
これは InputBox 関数では実現できないでしょう。

Answer 2

InputBox 関数 (Visual Basic for Applications) | Microsoft Docs

ダイアログ ボックスにプロンプトを表示し、ユーザーがテキストを入力するかボタンをクリックするまで待機し、テキスト ボックスのコンテンツが含まれる文字列を返します。

　

ユーザーが [キャンセル] を選択すると、この関数は長さ 0 の文字列 ("") を返します。

InputBox 関数は文字列を返します。

Dim ds As String

Comments

[halmichi]

ありがとうございます！

[hatena19]

返す型を限定したいなら、他の方の回答にあるように Application.InputBoxメソッドを使った方がいいですね。

Answer 3

InputBoxの戻り値を入れる変数の型を変更すると動作します。

Dim ds As Variant
'Dim ds As Integer

Comments

[halmichi]

ありがとうございます！