エクセルVBAのFor文について

Question

エクセルVBAにて質問です。
下記のマクロにおいて、For文が回らずiの初期値のみの動作しかしません。
暫く考えているのですがわからないので、どなたかご教授頂けると幸いです。

Private Sub CommandButton1_Click()
Dim i As Integer

For i = 2 To 5

    If ActiveSheet.Range("A" & i).Value <> "" And ActiveSheet.Range("B" & i).Value <> "" Then
        Select Case ActiveSheet.Range("A" & i).Value
            Case 1
                Sheets("1年").Copy After:=Sheets(Worksheets.Count)
                ActiveSheet.Name = Sheets("master").Range("B" & i).Value
                ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
            Case 2
                Sheets("2年").Copy After:=Sheets(Worksheets.Count)
                ActiveSheet.Name = Sheets("master").Range("B" & i).Value
                ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
            Case 3
                Sheets("3年").Copy After:=Sheets(Worksheets.Count)
                ActiveSheet.Name = Sheets("master").Range("B" & i).Value
                ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
           
        End Select
    
    End If
Next i

End Sub

Answer 1

ループの１回目にコピーして作ったシートがアクティブになってしまっています。
よってループの２回目以降は ActiveSheet の指しているシートが違います。

ActiveSheet は止めて Sheets("master") のようにきちんとシートを指定するか、
ループの最後で Active を最初のシートに戻せば上手くいくと思います。

つまり

Dim i As Integer
For i = 2 To 5

	If Sheets("master").Range("A" & i).Value <> "" And Sheets("master").Range("B" & i).Value <> "" Then
		Select Case Sheets("master").Range("A" & i).Value

		Case 1
			Sheets("1年").Copy After:=Sheets(Worksheets.Count)
			ActiveSheet.Name = Sheets("master").Range("B" & i).Value
			ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
		Case 2
			Sheets("2年").Copy After:=Sheets(Worksheets.Count)
			ActiveSheet.Name = Sheets("master").Range("B" & i).Value
			ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
		Case 3
			Sheets("3年").Copy After:=Sheets(Worksheets.Count)
			ActiveSheet.Name = Sheets("master").Range("B" & i).Value
			ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
		End Select
	End If
Next i

もしくは

Dim i As Integer
For i = 2 To 5
	If ActiveSheet.Range("A" & i).Value <> "" And ActiveSheet.Range("B" & i).Value <> "" Then
		Select Case ActiveSheet.Range("A" & i).Value
		Case 1
			Sheets("1年").Copy After:=Sheets(Worksheets.Count)
			ActiveSheet.Name = Sheets("master").Range("B" & i).Value
			ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
		Case 2
			Sheets("2年").Copy After:=Sheets(Worksheets.Count)
			ActiveSheet.Name = Sheets("master").Range("B" & i).Value
			ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
		Case 3
			Sheets("3年").Copy After:=Sheets(Worksheets.Count)
			ActiveSheet.Name = Sheets("master").Range("B" & i).Value
			ActiveSheet.Range("C2").Value = Sheets("master").Range("B" & i).Value
		End Select

		Sheets("master").Activate

	End If
Next i

です。

ActiveSheet は現在どのシートを指しているか分からなくなりやすく
バグを誘発することが多いので、なるべく使用しないことをおすすめします。

Comments

[nina1326]

解決しました！確かにですね、わかりやすい解説ありがとうございました！！

[twck]

ちなみに頻繁に使用するシートは変数に入れて使うといいです。
（１、２回しか出てこないシートなら変数に入れなくてよい）

Dim sheetMaster As Worksheet
Set sheetMaster = Sheets("master")
If sheetMaster.Range("A" & i).Value <> "" And sheetMaster.Range("B" & i).Value <> "" Then

「Sheets("master")」だとそのたびに "master" という名前のシートを検索するので遅くなりますし、シート名を間違えてもコンパイラのチェックに引っかからないので。

あと、お願いなのですが、質問のタグが「VBA」だけなので、「EXCEL」のタグも追加してください。

Answer 2

ブレークポイントつけて、デバッグしてみてはいかがでしょうか？

想定する数値になっているかどうか実際に動かしながら見てみると
原因が分かるかもしれませんよ。

あとは、A3・B3のセルが空になってたりしませんか？

Comments

[nina1326]

セルは空になっておりません。F8でステップインで確かめてみたところ全ての処理を通っているはずなのですが、シートが一つしか作成できません。。。

[nina1326]

解決できました！ありがとうございました！＾＾

Answer 3

処理の内容まではみれてませんが
以下のように単純な記述でメッセージボックスがでないか確認してみてはいかがでしょうか。

    Dim i As Integer
    For i = 2 To 5
        MsgBox (i)
    Next i

Comments

[nina1326]

解決できました！ありがとうございました！＾＾