VBAのPDF出力処理を高速化したい

Question

先日の質問からの続きで大変恐縮なのですが
無事こちらで質問させてもらったおかげで条件分岐してPDF出力処理ができたのですが
ここから出力される際に「保存中　処理中のページ」とエクセルが開いて表示され動きが重たくなります。
ファイル数が多いのでせっかく自動化したものの恩恵を感じにくい状態となっております。

このウィンドウを消して処理を早くする方法が知りたいです。
宜しくお願い致します。

Sub EXCELファイルPDF化03() 'フォルダのEXCELファイルの一括変換
Application.ScreenUpdating = False
    Dim Button, T, I, L As Integer
    Dim OpenExcelFileName, ExcelFileName, ExcelFilePath, ExFileName As String
     
    Application.DisplayAlerts = False  '確認メッセージを無効化します。
    
    
    Button = MsgBox("EXCEファイルの一括PDF変を行いますか？", vbYesNo + vbQuestion, "確認")
    If Button = vbYes Then
            
            OpenExcelFileName = Application.GetOpenFilename 'ダイアログを表示取り込むフォルダーにあるファイルを選択します。
            
            If OpenExcelFileName <> "False" Then
                ExcelFileName = Dir(OpenExcelFileName)  '指定したファイルパスからファイル名を代入します。
                ExcelFilePath = Replace(OpenExcelFileName, ExcelFileName, "")  '指定したファイルパスを指定します。（ファイルパスからファイル名を取り除く）
                        
                MsgBox ExcelFilePath & "この選択フォルダからPDFに変換します。"
            Else
                MsgBox "キャンセルされました"
                Exit Sub  'キャンセルでプログラムを終了します。
                
            End If
        
            ExFileName = Dir(ExcelFilePath & "*.xls?")  '指定したフォルダーから一件目のEXCELファイルを指定します。
 

            Do While ExFileName <> ""    '読み込むファイルがなくなるまで繰り返す。
                
                Workbooks.Open fileName:=ExcelFilePath & ExFileName, ReadOnly:=True, UpdateLinks:=0  'EXCELファイルを読み取り専用で読み込む
                ExFileName = Left(ExFileName, InStr(ExFileName, ".") - 1) ' ファイル名から拡張子を取り除く（.xls?）
                
                'ActiveWorkbook の記述はいらなかった
                'レポートの記述にいらないスペースがあったかも
              Dim ws As Worksheet

                    On Error Resume Next 'エラー無視
                    Set ws = Worksheets("レポート")
                    On Error GoTo 0 'エラー無視解除
                    If ws Is Nothing Then '"レポート"シートが存在しなければ、
                        Worksheets(Array("表紙", "検索", "表示箇所", "行動", "順位")).Select
                        ActiveSheet.ExportAsFixedFormat _
                            Type:=xlTypePDF, _
                            fileName:=ExcelFilePath & ExFileName, _
                            OpenAfterPublish:=True
                    Else
                        ws.ExportAsFixedFormat _
                             Type:=xlTypePDF, _
                             fileName:=ExcelFilePath & ExFileName, _
                             OpenAfterPublish:=True
                    End If
                        
            
            ActiveWindow.Close  '読み込んだファイルを閉じます。
            
            ExFileName = Dir() '次のファイルを指定する。
 
            Loop
            
            MsgBox "PDFファイルに一括変換しました。"
    Else
        MsgBox "処理を中断します"
    End If
    
    Application.DisplayAlerts = True  '確認メッセージを有効化します。
    
End Sub

参考にした記事：　https://www.tipsfound.com/vba/02014

OS：macOS Catalina バージョン10.15.3
Excelバージョン： Microsoft Excel for Mac バージョン16.39

補足：追加記載した画像の表示を消したり裏で？作業させたりできないかという事です。
このウィンドウが出る時は毎回エクセルも開かれます

Answer 1

手動でやっても、VBAでやっても
エクセル君が作業している時間は変わりません。
ただ、煩雑な手順の繰り返しを自動化できるだけでもマクロ化の意味は十分あると思います。
画面の更新を止めたり、表示を隠したところで数にもよりますが、
大した高速化は望めないと思います。
画面がちらちらするのを止めるなら更新を止めてもいいですが、
なんか仕事をやってくれてる感があるので、
個人的には画面の更新を止めることはあまりやりません。個人の好みの問題ですが。。。

Option Explicit

Sub test()
    Dim sFolderPath As String
    Dim sFilePath As String
    Dim wsh As Worksheet
    
    If GetFolderPath(sFolderPath) = False Then Exit Sub
    
    sFilePath = Dir(sFolderPath & "*.xlsx")
    Do Until Len(sFilePath) = 0
        With Workbooks.Open(sFolderPath & "\" & sFilePath)
            .ExportAsFixedFormat Type:=xlTypePDF, _
                                 Filename:=Replace(.FullName, "xlsx", "pdf"), _
                                 OpenAfterPublish:=False
            .Close False
            sFilePath = Dir()
        End With
    Loop
End Sub

Private Function GetFolderPath(ByRef sFileName As String) As Boolean
    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = "C:\Users\Guest\test\"
        If .Show = -1 Then
            sFileName = .SelectedItems(1)
            GetFolderPath = True
        End If
    End With
End Function

とりあえず、ブック全体でサンプル書いてます。
条件分岐が必要な部分は改変願います。
（なんか上手くグループ化して指定ができなかったけど、時間がないので＾＾；）
参考になれば。

Comments

[taka-hoop]

ご回答ありがとうございます！
返答遅れてしまい申し訳ありません！

なるほど！非常に参考になります。
そうですね確かに多数のPDF出力を自動化できただけでもマクロ化した意味は十分ですよね！
コードすごく勉強になります！

ご丁寧に返答頂きありがとうございます！

Answer 2

プログレスバーを消したところで速くはならないと思いますよ。
Excelの標準機能を使ってPDFに変換するには、まずブックを開く必要があり、開くブックが大きければ大きいほど、数が多ければ多いほど時間がかかります。
開く処理(Open)と変換処理(ExportAsFixedFormat)が重い処理になるかと思いますが、閉じた世界ですので外からどうこうするのは厳しいかと思います。

Comments

[taka-hoop]

ご回答ありがとうございます！
お返事遅れて申し訳ありません。

なるほど、やはり作業的には厳しい感じなんですね
とても参考なりました！ありがとうございます！

Answer 3

素人考えですが

Application.ScreenUpdating = False '描画省略
Application.DisplayAlerts = False '警告省略

と記述されていますので、VBAのロジックを最適化できればいいと思いますが
簡単には最適化できなさそうな雰囲気を感じます・・・。
エクセルそのもののPDF変換そのものは高コストのような気がします。

Comments

[taka-hoop]

ご回答ありがとうございます！

エクセルファイルからPDFに変換する時が一番重くて
変換される際に毎回ファイルが開かれ表示されるのでそれが重い原因なのかなと感じています。

エクセルのPDF出力はそもそも重たい作業という事でしょうか？

[mako1972]

確かにエクセルを開いて閉じる処理自体がファイル数が多いと高コストの処理となります。
PDF作成自体も重い処理となりますので、詳しい方の回答を広く聞いた方がよさそうですね。

[mako1972]

こういう記述もあるようですが・・。
検証してみてください。

Sub test()
Workbooks.Open Filename:="\XXX.xlsx", ReadOnly:=True
ActiveWindow.Visible = False

’XX処理

ActiveWindow.Visible = True
End Sub

[taka-hoop]

ご返答ありがとうございます！

なるほど！一つ理解が進みました。勉強になります！
いつもご丁寧に回答ありがとうございます。

検証コメントもありがとうございます！
ぜひ試させて頂きます！

[mako1972]

あまり変わらない気がします・・。