1ページのみをPDFで保存したい

Question

エクセル初心者で最近業務でVBAを使う事になった者です。

フォルダないにあるエクセルファイルを一括でPDF化したいと考え以下のコードに書きました。

Sub EXCELファイルPDF化03() 'フォルダのEXCELファイルの一括変換
        
    Dim Button, T, I, L As Integer
    Dim OpenExcelFileName, ExcelFileName, ExcelFilePath, ExFileName As String
     
    Application.DisplayAlerts = False  '確認メッセージを無効化します。
    
    
    Button = MsgBox("EXCEファイルの一括PDF変を行いますか？", vbYesNo + vbQuestion, "確認")
    If Button = vbYes Then
            
            OpenExcelFileName = Application.GetOpenFilename 'ダイアログを表示取り込むフォルダーにあるファイルを選択します。
            
            If OpenExcelFileName <> "False" Then
                ExcelFileName = Dir(OpenExcelFileName)  '指定したファイルパスからファイル名を代入します。
                ExcelFilePath = Replace(OpenExcelFileName, ExcelFileName, "")  '指定したファイルパスを指定します。（ファイルパスからファイル名を取り除く）
                        
                MsgBox ExcelFilePath & "この選択フォルダからPDFに変換します。"
            Else
                MsgBox "キャンセルされました"
                Exit Sub  'キャンセルでプログラムを終了します。
                
            End If
        
            ExFileName = Dir(ExcelFilePath & "*.xls?")  '指定したフォルダーから一件目のEXCELファイルを指定します。
 
            
            Do While ExFileName <> ""    '読み込むファイルがなくなるまで繰り返す。
                
                
                Workbooks.Open FileName:=ExcelFilePath & ExFileName, ReadOnly:=True, UpdateLinks:=0  'EXCELファイルを読み取り専用で読み込む
                ExFileName = Left(ExFileName, InStr(ExFileName, ".") - 1) ' ファイル名から拡張子を取り除く（.xls?）
                ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, FileName:=ExcelFilePath & ExFileName  '選択したシートをPDF出力
            
            ActiveWindow.Close  '読み込んだファイルを閉じます。
            
            ExFileName = Dir() '次のファイルを指定する。
 
            Loop
            
            MsgBox "PDFファイルに一括変換しました。"
    Else
        MsgBox "処理を中断します"
    End If
    
    Application.DisplayAlerts = True  '確認メッセージを有効化します。
    
End Sub

コード

問題なく実行されPDF化されるのですがエクセルファイルのうち１のシートだけをPDF化したいと考えております。
検索してみて以下のコードを試してみましたがMacでの書き方ではないのかコンパイルエラーが出てしまいます。

From:=1, To:=1, OpenAfterPublish:=True
コード

エクセルファイルをページ指定してPDFファイルに変換する方法が知りたいです。
宜しくお願い致します。

OS：macOS Catalina バージョン10.15.3
Excelバージョン： Microsoft Excel for Mac バージョン16.39

Answer 1

windows10 Excel2019でVBAを検証してみました。windowsでもPDFが作成されました。
はじめの1ページのみということで、下記のように修正してみましたところうまくいきました。

ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:=ExcelFilePath & ExFileName
↓
ActiveWorkbook.Sheets(1).ExportAsFixedFormat　Type:=xlTypePDF, Filename:=ExcelFilePath & ExFileName

に修正して、windowsでは１ページのみのPDFとなりました。

Comments

[taka-hoop]

ご回答ありがとうございます！
MacではWorksheets(1)等の記述を追記する事により任意のシートのみをPDF化することができました！

基礎的な部分みたいでしたが丁寧に回答頂きありがとうございました！

[mako1972]

回答ありがとうございました。
勉強になります。