VBA 数値が入力されているセルを探しユーザーフォームに表示させたい

Question

前提・実現したいこと

ExcelVBAについての質問です。
数式が入力されている列に、誤って数値が入っていないかチェックし（文字列はOK）、
もし数値があればそのセルアドレスをユーザーフォームに表示させたいと思っています。

できれば、ユーザーフォーム内で選択したときにそのセルへジャンプしてくれればいいなと思っていますが
うまく出来ず詰まってしまいました。

どのようにすれば、この問題を解決することが出来るでしょうか。
アドバイスよろしくお願いいたします。

現在の状況

検索については下記が理想に一番近いです。

Range("H:H").SpecialCells(xlCellTypeConstants, xlNumbers).Select

動作や結果についてはいろいろと検索した結果、下記が一番近いです。

Set FoundCell = Cells.find(What:="任意")
If FoundCell Is Nothing Then
    MsgBox "計算式列に数値入力は見つかりませんでした"
    Exit Sub
Else
    Set FirstCell = FoundCell
    Userform1.ListBox1.AddItem FoundCell.Address & vbTab & FoundCell.Value
End If

Do
    Set FoundCell = Cells.FindNext(FoundCell)
    If FoundCell.Address = FirstCell.Address Then
        Exit Do
    Else
        Userform1.ListBox1.AddItem FoundCell.Address & vbTab & FoundCell.Value
    End If
Loop

Comments

[tosi]

(参考)
>セルへジャンプしてくれればいい････
form起動にはModal/Modelessがあります。
UserForm1.Show (vbModal)
UserForm1.Show (vbModeless)
ジャンプ後の操作が変わります。チェックした方が良いかも知れません。

Answer 1

どのタイミングで実行するか不明なので、
ユーザーフォームのコマンドボタンをクリックすると表示するようにしました。

Option Explicit

Private Sub CommandButton1_Click()
    Dim FoundCells As Range
    On Error Resume Next
    Set FoundCells = Range("H:H").SpecialCells(xlCellTypeConstants, xlNumbers)
    If Err.Number = 1004 Then
        MsgBox "計算式列に数値入力は見つかりませんでした"
        Exit Sub
    End If
    On Error GoTo 0
    
    With Me.ListBox1
        .Clear
        .ColumnCount = 2
        Dim FoundCell As Range
        For Each FoundCell In FoundCells
            .AddItem FoundCell.Address
            .List(.ListCount - 1, 1) = FoundCell.Value
        Next
    End With

End Sub

Private Sub ListBox1_Change()
    If IsNull(Me.ListBox1.Value) Then Exit Sub
    Range(Me.ListBox1.Value).Select
End Sub

Comments

[usamix]

早速動作を確認したところ、理想の動作をしてくれました！
Err.Numberを用いる方法などは思いつきもしなかったので、もっと勉強したいと思います。
ありがとうございました！

[mako1972]

くだらないことをする日曜プログラマの点綴的な例ですな。

Answer 2

この場合は、worksheetchangeイベントでその都度msgboxなどで
警告・判定したらよろしいと思います。
Uerformを使いたい気持ちは尊重しますが、
正直、どうでもいい質問です。

Comments

[usamix]

既に完成しているデータに対するアプローチで考えていましたので
worksheetchangeを使用するという考えに及びませんでした
また、質問時の言葉足らずを反省いたしました。

ですがこれから新しく作成するデータに対してはイベントを用いて警告を出したいと思います！
確かにそちらのほうが正しいアプローチだと感じました。
ご回答ありがとうございました！