mql4でiCustom関数を使ってインジケーターの値を取得できない

Question

現在、iCustom関数を使用して既存のRCIインジケータのバッファーから値の抽出を試みています。
１番目のバッファーについては、上手く出来ているのですが、２番目のバッファーについて、上手くいきません。どなたかご助言いただければ、助かります。

インデックスの概要　

　
　// インデックス名　fxnav_RCI

 IndicatorBuffers(6); 

   SetIndexBuffer(0, rci);
   SetIndexBuffer(1, signal);   ←　このバッファーの値を取得したい
   SetIndexBuffer(2, up);
   SetIndexBuffer(3, down);  
   SetIndexBuffer(4, rci_up);
   SetIndexBuffer(5, rci_down);  

  以下省略

自分のスクリプト全文

//+------------------------------------------------------------------+
//|                                                  custom_test.mq4 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+

input int RCI_period = 21;

input int singal_period = 5;

//input int mode = 0;

void OnStart()
  {
   double curRCI_cus =iCustom(NULL,0,"Bands",RCI_period,0,0);
   
   double curSIG_cus =iCustom(NULL,0,"Bands",singal_period,1,0);
   
   Alert("RCI_custom:      ",curRCI_cus);
   Alert("preRCI_custom:      ",preRCI_cus);
   Alert("curSIG_cus:      ",curSIG_cus);
   Alert("preSIG_cus:      ",preSIG_cus);
   
  }

インジケータのコード全文

https://drive.google.com/file/d/1UnOwQ5KpsKRpHlXySI9BbcsE8FOmEf-4/view?usp=sharing

回答欄にて頂いたコードの結果と比較

Answer 1

呼び出しに関しては特に問題があるようには見えません。
前後のコードに何か問題があるのではないでしょうか？

参考までにfxnav_RCIを呼び出すだけのインジケータのサンプルです。
1本目のラインがrci_period1のRCIで2本目のラインがrci_period2のSignalのラインです。

#property strict
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot RCI
#property indicator_label1  "RCI"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrMediumBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot Signal
#property indicator_label2  "Signal"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrRed
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//---
input int rci_period1 = 5;
input int rci_period2 = 22;
//--- indicator buffers
double RCIBuffer[];
double SignalBuffer[];
//---
int max_period = 0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
{
    max_period = MathMax(rci_period1, rci_period2);

    SetIndexBuffer(0, RCIBuffer);
    SetIndexBuffer(1, SignalBuffer);

    SetIndexDrawBegin(0, max_period);
    SetIndexDrawBegin(1, max_period);

    IndicatorShortName("fxnav_RCI_test (" + IntegerToString(rci_period1) + "," + IntegerToString(rci_period2) + ")");

	SetIndexLabel(0, "RCI (" + IntegerToString(rci_period1) + ")");
	SetIndexLabel(1, "Signal (" + IntegerToString(rci_period2) + ")");

    return INIT_SUCCEEDED;
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
    if (rates_total < max_period) {
        return 0;
    }

    if (prev_calculated <= 0) {
        ArrayFill(RCIBuffer, 0, rates_total, EMPTY_VALUE);
        ArrayFill(SignalBuffer, 0, rates_total, EMPTY_VALUE);
    }

    int limit = MathMin(rates_total - max_period - 1, rates_total - prev_calculated);

    for (int index = limit; index >= 0; index--) {
        RCIBuffer[index] = iCustom(NULL, 0, "fxnav_RCI", rci_period1, 0, index);
        SignalBuffer[index] = iCustom(NULL, 0, "fxnav_RCI", rci_period2, 1, index);
    }

    return rates_total;
}

同じ値になっているのが確認できると思います。

Comments

[hiroshi77]

ご丁寧にご回答ありがとうございます。不思議なのですが、自分のもっているfxnav_RCIのインジケータを使った際と、上記コードを貼り付けて新たに作ったインジケータの値が異なります。期間設定は、RCIを５とシグナルを２１で設定しているのですが、理由がわかりません。結果と、自分の持っているインジケータのコードリンクを追記しますので、改めてご助言いただけないでしょうか。

indicator window1 が自分の持っているインジケーター（fxnav_RCI）で、Value2がシグナルラインの値になります。
下のindicator window2 が今回コードを頂いたインジケータになります。

[mah]

質問の画像のindicator window2のSignalにindicator window1のValue 2が表示されてほしいのでしょうか？

その場合、スクリプトの記述は下記のようにする必要があります。
double curSIG_cus =iCustom(NULL,0,"fxnav_RCI",RCI_period,singal_period,1,0);

下記の記述だと、fxnav_RCIの最初のパラメータのみ指定することになります。
つまり、fxnav_RCIのrci_periodパラメータにsingal_period(5)を指定しています。
double curSIG_cus =iCustom(NULL,0,"fxnav_RCI",singal_period,1,0);

[hiroshi77]

お～凄いです！上記のとおりにしたらインジケータ通りの結果になりました。
どうもありがとうございます！
signalラインのバッファーは2番目のバッファなので、iCustomのmodeを1にすれば良いと考えていたのですが、なぜそれだけでは１番目のバッファーのパラメータを指定することになるのでしょうか？

[mah]

元の書き方だと
iCustom(NULL,0,"fxnav_RCI",5,1,0);
と書いたのと同じになります。

指定したパラメータは対象のインジケータの宣言順に渡されるので、
これだと、fxnav_RCIのパラメータを
rci_period = 5
signal_period = 5
に設定したのと同じになってしまいます。

詳細はリファレンスを参照してください。
https://yukifx.web.fc2.com/sub/reference/22_technical_ind/cone/tec_custom.html
https://docs.mql4.com/indicators/icustom

[hiroshi77]

ありがとうございます。ようやく腑に落ちました。
バッファーが複数あり、そのパラメータが分かれている場合は、modeの引数でそのバッファーが何番目に宣言されるているかを指定するだけではなく、その前のパラメーターの引数をそのバッファー分（１番目のバッファーのパラメータ、2番目のバッファーのパラメータ）を宣言順に記載しなければならなかったのですね。
何度もご質問してしまいましてすみませんでした。とても助かりました。