wordのVBAで、指定の色で塗りつぶされた箇所のフォントを変更したい

Question

word内の表で、指定の色で塗りつぶされたセルに記載された文字に対して、以下を実現したいと思っています

塗りつぶしの色：RGBで79・129・189
このセルに対して実現したいこと：「テキストの中央揃え」「文字の太字」「MS P ゴシック」

表が多いため、これをVBAで実現したいのですが、表の塗りつぶしの色で場所を指定する方法がわかりませんでした。

どのようにすればいいのでしょうか？

Dim tbl As Table
For Each tbl In ActiveDocument.Tables
（ここでどのように指定すればいいのでしょうか？）
Next

Answer 1

こんなところでどうでしょう。

Dim tbl As Table
Dim clm As Column
Dim cell As cell
For Each tbl In ActiveDocument.Tables
    For Each clm In tbl.Columns
        For Each cell In clm.Cells
            If cell.Shading.BackgroundPatternColor = RGB(79, 129, 189) Then
                With cell.Range
                    .Font.Name = "ＭＳ Ｐゴシック"
                    .Font.Bold = True
                    .ParagraphFormat.Alignment = wdAlignParagraphCenter
                End With
            End If
        Next
    Next
Next

追記
確かに結合セルがあるとエラーになります。
結合セルを考慮して修正するとこのようになりましたが、
まだ問題があるようでしたらコメントをお願いします。

Sub Sample()
    Dim tbl As Table
    Dim row As row
    Dim cell As cell
    For Each tbl In ActiveDocument.Tables
        Dim rowNum As Long: rowNum = 1
        Do While rowNum <= tbl.Rows.Count
            tbl.cell(rowNum, 1).Select
            With Selection
                .SelectRow
                For Each cell In .Cells
                    If cell.Shading.BackgroundPatternColor = RGB(79, 129, 189) Then
                        With cell.Range
                            .Font.Name = "ＭＳ Ｐゴシック"
                            .Font.Bold = True
                            .ParagraphFormat.Alignment = wdAlignParagraphCenter
                        End With
                    End If
                Next
                rowNum = .Information(wdEndOfRangeRowNumber) + 1
            End With
        Loop
    Next
End Sub

Comments

[amatsuno]

上記を実行したのですが、以下のエラーで実行できませんでした

「実行時エラー 5992 セル幅がすべて同じではないため、このコレクションの個別の列にアクセスすることができません。」

表内でセルの結合部分などがあるのですが、この場合は不可能なのでしょうか？

[amatsuno]

ありがとうございます。
上記を応用して作成することができそうです