[VB.NET]DataGridViewで時間計算の方法と時間形式(hhmm→hh:mm)への変換方法がわかりません。。

Question

前提・実現したいこと

VB.NETのDataGridViewで時間入力し、計算結果をSQL Serverに登録する機能を作成しています。

現状、登録は出来るのですが、時間計算を行うためのソースがいまいちわかりません。
またhhmmと入力しているとセルからマウスが離れるとhh:mmに変換する方法も合わせて教えていただきたいです。

例：
列1 列2
09:00　 17:45 →　列1と列2から減算を行いたい。

このような初歩的な質問で申し訳ございません。

発生している問題・エラーメッセージ

「型'String'"09:00" から型 'Decimal' への変換は無効です。'」

該当のソースコード

 For Each c As DataGridViewCell In DataGridView1.SelectedCells
                A = DataGridView1(6, c.RowIndex).Value
                B = DataGridView1(8, c.RowIndex).Value
                Kekka = CStr(CDec(DataGridView1(6, c.RowIndex).Value) - CDec(DataGridView1(8, c.RowIndex).Value))
                'If DataGridView1.SelectedCells(c.ColumnIndex).Value = Nothing Then
                '    DataGridView1.SelectedCells(c.ColumnIndex).Value = ""
                'End If
            Next

試したこと

補足情報（FW/ツールのバージョンなど）

Visual Studio2017,SQL Server

Answer 1

やり方はいろいろあるでしょうけどサンプルです。

' hhmm → hh:mm
Public Function EditTime(ByVal value As String) As String
    Dim hh As String = Nothing
    Dim mm As String = Nothing
    DivideTime(value, hh, mm)
    Return hh & ":" & mm
End Function

' hh:mm → hhmm
Public Function RestoreTime(ByVal value As String) As String
    Dim hh As String = Nothing
    Dim mm As String = Nothing
    DivideTime(value, hh, mm)
    Return hh & mm
End Function

' 入力文字列を TimeSpan に
Public Function ToTimeSpan(ByVal value As String) As TimeSpan
    Dim hh As String = Nothing
    Dim mm As String = Nothing
    DivideTime(value, hh, mm)
    Return New TimeSpan(CInt(hh), CInt(mm), 0)
End Function

' 左側にゼロを埋めて指定した桁数にする
Private Function LPadZero(ByVal value As String, ByVal point As Integer) As String
    Dim padStr As String = New String("0"c, point)
    value = padStr & value
    Return value.Substring(value.Length - point)
End Function

' 入力文字列を hh, mm に分ける
Private Sub DivideTime(ByVal value As String, ByRef hh As String, ByRef mm As String)
    '「:」があるか検査
    Dim index As Integer = value.IndexOf(":"c)
    If index = -1 Then
        ' 「:」が無いとき左側をゼロ埋めして４文字にする
        value = LPadZero(value, 4)
        ' ２文字に分ける
        hh = value.Substring(0, 2)
        mm = value.Substring(2, 2)
    Else
        '「:」がある場合は左右に分ける
        hh = value.Substring(0, index)
        mm = value.Substring(index + 1)
        ' 左側をゼロ埋めして２文字にする
        hh = LPadZero(hh, 2)
        mm = LPadZero(mm, 2)
    End If
End Sub

使い方

Dim A As String = "09:00"
Dim B As String = "17:45"

Dim T As TimeSpan = ToTimeSpan(B) - ToTimeSpan(A)
Dim TM As Double = T.TotalMinutes
Dim h As Double = TM \ 60
Dim m As Double = TM Mod 60
Dim hhmm As String = h.ToString() & ":" & m.ToString()
Dim result As String = EditTime(hhmm) ’ 08:45 になる

Comments

[退会済みユーザー]

返信が遅くなり申し訳ありません！
ありがとうございます。
様々なやり方があることがわかり、大変勉強になりました！
いろいろなパターンを試してみたいと思います。

Answer 2

cellの表記は "09:00" でよろしいでしょうか？

これをDecimal型に変換したときに ":" があるせいで失敗しています。
なので ":" を取り除く必要があります。

A = A.Replace(":", "")

ただ、Decimal型に変換すると "0900" が "900" になってしまい
cellに戻す際は "0900" に戻して ":" を追加する必要があります。

'A, BはDecimal

kekka = (A + B).ToString("00:00")

代替案なのですが、Decimal型ではなくDateTime型に変換して計算してはいかがでしょうか。

Comments

[退会済みユーザー]

返信が遅くなり、申し訳ございません。
型に関しての知識があまりなく、DateTime型に変換するという方法すら知りませんでした！
大変勉強になりました。
ありがとうございます！