フォーカスが移動したときに全選択の状態にしたい

Question

下記の通りコードを書きました。
フォーカスは、TabやEnterで「日付」→「開始日」→「終了日」の順で移動し、「終了日」の次は「日付」に戻ります。
起動時は、「日付」が全選択となるのですが、TabやEnterで移動しても「開始日」や「終了日」は全選択となりません。
マウスで移動すると全選択となり、以降はTabやEnterで移動しても全選択状態となります。つまりマウスで一度でも全選択状態としないといけないようです。
どのように書けばTabやEnterの移動で、最初から「開始日」や「終了日」を全選択状態とできますか。
ちなみに、「日付」はTextBox、その他はMaskedTextBoxです。

        '操作当日の年月だけの表示とします。
        Dim 日付 = DateTime.Now
        Me.日付.Text = Date.Now.ToString("yyyy-MM")

        '処理する月の初日をセット
        日付 = New Date(日付.Year, 日付.Month, 1) '指定年月での最初日
        開始日.Text = 日付

        '処理する月の末日をセット
        日付 = New Date(日付.Year, 日付.Month, 1) '指定年月での最初日
        日付 = 日付.AddMonths(1).AddDays(-1)      '次月の1日前を計算
        終了日.Text = 日付

    End Sub

    'TextBoxにカーソルを移動させたときに「全選択」状態にする。(ここから始まり)
    Private m_bFlag As Boolean = False

    ' Enterイベント
    Private Sub 開始日_Enter(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles 開始日.Enter
        開始日.SelectAll()
        If Control.MouseButtons <> Windows.Forms.MouseButtons.None Then
            m_bFlag = True
        End If
    End Sub

    ' MouseDownイベント
    Private Sub 開始日_MouseDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles 開始日.MouseDown
        If m_bFlag Then
            開始日.SelectAll()
            m_bFlag = False
        End If
    End Sub

    Private m_bFlag2 As Boolean = False

    Private Sub 終了日_Enter(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles 終了日.Enter
        終了日.SelectAll()
        If Control.MouseButtons <> Windows.Forms.MouseButtons.None Then
            m_bFlag2 = True
        End If
    End Sub

    Private Sub 終了日_MouseDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles 終了日.MouseDown
        If m_bFlag2 Then
            終了日.SelectAll()
            m_bFlag2 = False
        End If
    End Sub

    Private m_bFlag3 As Boolean = False

    Private Sub 日付_Enter(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles 日付.Enter
        日付.SelectAll()
        If Control.MouseButtons <> Windows.Forms.MouseButtons.None Then
            m_bFlag3 = True
        End If
    End Sub

    Private Sub 日付_MouseDown(ByVal sender As System.Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles 日付.MouseDown
        If m_bFlag3 Then
            日付.SelectAll()
            m_bFlag3 = False
        End If
    End Sub
    'TextBoxにカーソルを移動させたときに「全選択」状態にする。(ここで終わり)

よろしくお願いします。

Comments

[退会済みユーザー]

何を作っているかと開発環境は書けませんか？

[Umeda2019]

日付を限定してデータを呼び出す仕組みを作っています。今作業しているのはメニュー画面ですが、これに限らずあらゆる場面で利用したいと考えています。
開発環境は、Visual Studio 2019(VB.net)、Windows Formアプリケーションです。

Answer 1

こんな感じでどうでしょう？

Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

        '操作当日の年月だけの表示とします。
        Dim 日付 = DateTime.Now
        Me.日付.Text = Date.Now.ToString("yyyy-MM")

        '処理する月の初日をセット
        日付 = New Date(日付.Year, 日付.Month, 1) '指定年月での最初日
        開始日.Text = 日付

        '処理する月の末日をセット
        日付 = New Date(日付.Year, 日付.Month, 1) '指定年月での最初日
        日付 = 日付.AddMonths(1).AddDays(-1)      '次月の1日前を計算
        終了日.Text = 日付

        Me.KeyPreview = True
        AddHandler Me.日付.Enter, AddressOf TextBoxes_Enter
        AddHandler Me.開始日.Enter, AddressOf TextBoxes_Enter
        AddHandler Me.終了日.Enter, AddressOf TextBoxes_Enter
    End Sub

    Protected Overrides Sub OnKeyPress(e As KeyPressEventArgs)
        MyBase.OnKeyPress(e)
        ' Enter キーで移動する処理
        If e.KeyChar = vbCr Then
            ProcessTabKey((Control.ModifierKeys And Keys.Shift) = 0)
            e.Handled = True
        End If
    End Sub

    Private Sub TextBoxes_Enter(ByVal sender As Object, e As EventArgs)
        BeginInvoke(Sub(ctl As Object)
                        Dim box As TextBoxBase = TryCast(ctl, TextBoxBase)
                        If box IsNot Nothing Then
                            box.SelectAll()
                        End If
                    End Sub, sender)
    End Sub

End Class

Comments

[KOZ6.0]

個人的にはマウスでポイントしたときに全選択されるのは煩わしい気がします。

[Umeda2019]

回答ありがとうございます。
見事に狙い通りの動きとなりました。
様々な場面で応用できそうです。

Answer 2

マウスで移動しないと、 m_bFlag2 が Trueとならないため、EnterイベントでSelectAllが実行されません。
これをどーにかしましょう

---

おっと、Enterイベントではとりあえず実行してるんですね。見誤ってました

それでは、EnterイベントにはSelectAll() のみにして、全選択の動作がどうなるかをチェックしてみればどうでしょう。
そこから、マウス移動のコードを追加していき、どこでおかしくなるかを探っていけばいいかと思います

Comments

[y_waiwai]

回答に追記

[Umeda2019]

回答ありがとうございます。
一度試してみます。