VBAでループのシート移動をしたい

Question

前提・実現したいこと

シートに「前へ」「次へ」ボタンを設置してそれを押すとページ移動できるようにしたいです。
また、シートは
HOME|移動範囲1|移動範囲2|移動範囲3|移動範囲4|科目
このようにあり、移動範囲内をループで移動したいです。

例：移動範囲３で次へ→移動範囲４に移動→移動範囲４で次へ→移動範囲１に移動
例：移動範囲２で前へ→移動範囲１に移動→移動範囲１で前へ→移動範囲４に移動

このような形にしたいと思っています。

また、移動範囲のシートは追加することがあるので後ろの判定を科目シートの1つ前で取りたいと思っております。

該当のソースコード

'ページ移動前へ
Sub PrevPage()
    
    ActiveSheet.Previous.Activate
    
End Sub


'ページ移動次へ
Sub NextPage()
    
    ActiveSheet.Next.Activate
    
End Sub

試したこと

IF文の利用も考えたのですが、For Next文の方がいいのでしょうか？
また、とりあえず次への方から取り組んでみたのですが、上手く動作しませんでした。

'ページ移動前へ
Sub PrevPage()
    
    ActiveSheet.Previous.Activate
    
End Sub


'ページ移動次へ
Sub NextPage()
    Dim i As Long
    
    For i = 2 To Worksheets("科目") '←科目のひとつ前の判定の取り方がわからないです
        
    Next
    ActiveSheet.Next.Activate
    
End Sub

Answer 1

参考程度です。
アドインメニューへComboboxをシート名で登録して選択する様にすると楽ですよ。

Option Explicit
'
Public gobjCmdBar As CommandBar
Public gCmdBarBtn As CommandBarButton
Public gobjCmdCombo As CommandBarComboBox

' ***********************************************
' コマンドバー登録
' ***********************************************
Function Test_Sample_Miniature() As Boolean

    Dim MySheet As Worksheet
    Dim Bar As CommandBar
    Dim blnFlag As Boolean
    
    '試験用でメニュー削除
    Call Close_CommandBar
    
    'メニュー登録済み確認
    For Each Bar In Application.CommandBars
        If Bar.Name = "メニュー" Then
            Exit Function
        End If
    Next Bar
    
    'メニュー追加
    Set gobjCmdBar = Application.CommandBars.Add(Name:="メニュー", Temporary:=True)
    gobjCmdBar.Position = msoBarTop
    gobjCmdBar.Visible = True
    
    'コンボBox追加
    Set gobjCmdBar = gobjCmdBar
    Set gobjCmdCombo = gobjCmdBar.Controls.Add(Type:=msoControlComboBox)

    'コンボBoxリスト追加
    For Each MySheet In ThisWorkbook.Worksheets
        blnFlag = True
        If InStr(MySheet.Name, "Home") > 0 Then blnFlag = False
        If InStr(MySheet.Name, "科目") > 0 Then blnFlag = False
        If blnFlag = True Then
          gobjCmdCombo.AddItem Text:=MySheet.Name
          gobjCmdCombo.OnAction = "SelectSheetActive処理"
        End If
    Next
    gobjCmdCombo.Style = msoComboLabel
    gobjCmdCombo.Text = gobjCmdCombo.List(1)

    '開放
    Set gCmdBarBtn = Nothing
    Set gobjCmdBar = Nothing

End Function

' ***********************************************
' SelectSheetActive処理
' ***********************************************
Function SelectSheetActive処理() As Boolean
    ThisWorkbook.Worksheets(gobjCmdCombo.Text).Activate
End Function

' ***********************************************
' コマンドバーを削除する
' ***********************************************
Function Close_CommandBar() As Boolean
    On Error Resume Next
    gobjCmdCombo.Delete
    Application.CommandBars("メニュー").Delete
End Function

Answer 2

こんなんですかね。
それぞれ関数をボタンに割り当ててください。

Sub Next_Click()
    Dim sh As Worksheet
    Set sh = ActiveSheet
    Dim n As Long
    If Worksheets(sh.Index + 1).Name = "科目" Then
        n = Worksheets("HOME").Index
    Else
        n = sh.Index + 1
    End If
    sh.Move after:=Worksheets(n)
End Sub

Sub Prev_Click()
    Dim sh As Worksheet
    Set sh = ActiveSheet
    Dim n As Long
    If Worksheets(sh.Index - 1).Name = "HOME" Then
        n = Worksheets("科目").Index
    Else
        n = sh.Index - 1
    End If
    sh.Move before:=Worksheets(n)
End Sub

Comments

[radames1000]

誤投稿でしょうか。

[ttyp03]

すみません。
職場の環境から投稿するとたまにこうなります。
再投稿しましたのでご確認ください。

[radames1000]

ありがとうございます。
Moveで書かれてますが、質問者さんがActivateとされてるのでSelectが意図したものかと思いました。
Sub Next_Click()
Dim sh As Worksheet
Set sh = ActiveSheet
Dim n As Long
If Worksheets(sh.Index + 1).Name = "科目" Then
n = Worksheets("HOME").Index + 1
Else
n = sh.Index + 1
End If
Sheets(n).Select
End Sub

Sub Prev_Click()
Dim sh As Worksheet
Set sh = ActiveSheet
Dim n As Long
If Worksheets(sh.Index - 1).Name = "HOME" Then
n = Worksheets("科目").Index - 1
Else
n = sh.Index - 1
End If
Sheets(n).Select
End Sub

[ttyp03]

質問の意図を読み違えたか。。。
シートを移動させたいではなく、表示するシートを変更したいってことですか。
だとすればradames1000さんが修正してくださったものでよさそうですね。

[ttyp03]

MoveなのかSelectなのか、どちらが求めているものだったのでしょうか？