VBAでグラフの特定要素を色付けしたい

Question

お世話になっております。
表題の件で質問をさせてください。

環境：
Windows 10 Pro x64
Excel 2016

前回の質問を元にVBAでグラフ作成までを完成させました。
VBAでグラフを作るとExcelが落ちる

特定の文字("ここではProduct10"の色を変更したいです。

ソースは以下の様になります(修正を加えたため色々プロパティ変更のソースも入っています)

Option Explicit
Sub AddGraph()

	'グラフの対象データ範囲を定義
	Dim trgtSh As Worksheet
	Set trgtSh = ThisWorkbook.Worksheets("Sheet1")
	Dim dataRng As Range
	Set dataRng = trgtSh.Range("A1:B16")

	'グラフを貼り付けたいセルを定義
	Dim pasteRng As Range
	Set pasteRng = trgtSh.Range("D2")

	'グラフの対象データをソートする(昇順)
	With trgtSh
	    .Sort.SortFields.Clear
	    .Sort.SortFields.Add Key:=.Range("B1"), Order:=xlAscending  '第1優先
	    .Sort.SortFields.Add Key:=.Range("A1"), Order:=xlAscending  '第2優先
	    .Sort.SetRange dataRng  'ソートの範囲
	    .Sort.Header = xlNo '最初のセルをヘッダ固定にするかどうか
	    .Sort.Apply
	End With

	'グラフ編集
	With trgtSh.Shapes.AddChart2.Chart

	    'グラフの種類を指定（ここでは「集合縦棒」）
	    .ChartType = xlColumnClustered
	    'グラフの対象データ範囲を指定
	    .SetSourceData dataRng


	    Dim tmp As Variant, I As Long
	    tmp = .SeriesCollection(1).Values

	    For I = 1 To UBound(tmp)
	        '系列内で"Product10"の要素だけ色を変える
	        '.SeriesCollection(1).Points(1).Interior.ColorIndex = 3 '&H0000FF
	    Next I

	    'グラフの貼り付け位置を指定
	    .Parent.Top = pasteRng.Top
	    .Parent.Left = pasteRng.Left
	End With
End Sub

真ん中にあるPrduct10を検索する方法が分からずに困っております。
ご教授お願い致します。

Answer 1

Pointsコレクションの中から使えそうなプロパティがあればそれを基に検索すればいいのですが、私にはわかりませんでした。

代わりにシート上からProduct10を検索し、その行番号を要素位置として使うサンプルです。

Dim f As Range
Set f = Columns(1).Find(what:="Product10", LookAt:=xlWhole)
Shapes(1).Chart.SeriesCollection(1).Points(f.Row).Interior.ColorIndex = 3 '&H0000FF

Comments

[izuki_y]

ご回答ありがとうございます。
こちらの方法でやりたい事が出来ましたありがとうございます。

別回答として下記の方法でもできました。

Dim tmp As Variant, I As Long
tmp = .SeriesCollection(1).XValues 'X軸の要素

For I = 1 To UBound(tmp)
'系列内で"Product10"の要素だけ色を変える
If InStr(tmp(I), "Product10") > 0 Then
With .SeriesCollection(1).Points(I)
.Interior.ColorIndex = 3 '&H0000FF
End With
Next I

[ttyp03]

XValues で参照できたのですね。
勉強になります。

[izuki_y]

Markdownが上手くいかずに何回も編集しまくったので通知がめちゃくちゃ飛んできてたら申し訳ございません（汗）

[ttyp03]

いえ、大丈夫ですよい。飛んできてません。
コメント欄の編集は通知が来ないみたいです。
ちなみにコメント欄だとMarkdownつかえません。不便ですねぇ。