Redmine Rest APIでチケット登録するときのカスタムフィールドに値を入れたい

Question

お世話になります。
VBAを使ったRedmineのチケット登録で困っています。

・やりたいこと
Redmineのチケット新規登録をExcel　VBAで行いたい。

・質問したいこと
チケットのタイトルだけ指定した場合は問題なくチケットの新規登録できますが、カスタムフィールドに値をいれると「400」という戻り値が返ってきてチケットが登録できません。
カスタムフィールドに値を入れて新規チケット登録するにはどうすればいいのでしょうか？

・試したこと
テスト用のソースコードですが、下記のコードで試しています。
「ここからカスタムフィールド」と「ここまでカスタムフィールド」の間のコードをコメントアウトすると正常にチケットが登録されます。
しかし、コメントアウトを解除すると「400」というエラーが出てチケットが登録できません。

下記の記述以外に下記のような記述を85試してみましたが結果は同じでした。

<custom_field_values>
<85>カスタムなテキストフィールド</85>
</custom_field_values>

カスタムフィールドIDはRedmineの「管理」「カスタムフィールド」の項目のソースを表示させ下記の項目で調べました。

Option Explicit

Public Const REDMINE_URL As String = "https://'URL'"

Public Sub Test1()

    Dim requestStatus As String
    requestStatus = addIssue( _
        "'APIキー'", _
        "追加テスト")
    MsgBox requestStatus

End Sub

Public Function addIssue( _
    ByVal apiKey As String, _
    ByVal subject As String) As String

    Dim sendBody As Variant
    sendBody = "<?xml version=""1.0""?><issue>"
    sendBody = sendBody & "<project_id>9</project_id>"
    sendBody = sendBody & "<subject>" & subject & "</subject>"
'ここからカスタムフィールド
    sendBody = sendBody & "<custom_fields type=array>"
    sendBody = sendBody & "<custom_field id=""85"">"
    sendBody = sendBody & "<value>5</value>"
    sendBody = sendBody & "</custom_field>"
    sendBody = sendBody & "</custom_fields>"
'ここまでカスタムフィールド
    sendBody = sendBody & "</issue>"

    Dim xmlHttp As New MSXML2.XMLHTTP60
    With xmlHttp
        .Open "POST", REDMINE_URL & "issues.xml?format=xml&?key=" & apiKey, False
        .SetRequestHeader "Content-Type", "text/xml"
        .Send sendBody
        addIssue = CStr(.Status)
    End With
    Set xmlHttp = Nothing

End Function

・環境
OS：Windows10
Excel：Office 365 ProPlus　バージョン1908
Redmine：3.4.4.stable
Redmine稼働サーバーOS:不明

よろしくお願いします。

Answer 1

自己解決しました。

【修正前】
sendBody = sendBody & "<custom_fields type=array>"

【修正後】
sendBody = sendBody & "<custom_fields type=""array"">"