ＬＩＳＰのエラーが解決できない

Question

簡単な英文（肯定文）を疑問文にする以下のプログラムを作成しました。

入力例：(question '(this is a simple lisp function))
出力例：(is this a simple lisp function ?)

(defun question (arg)
     (
       (let ( (be) (a ()) ) 
         (loop
           (cond ( (equal be (car arg)) (return arg) ) ) 
           (setq be (car arg))
           (setq arg (cdr arg))
           (cond ( (or (equal 'am be) (equal 'is be) (equal 'are be) 
                       (equal 'was be) (equal 'were be) )
                   (setq arg (cons be (append (reverse a) arg)))
                 )
           )
           (setq a (cons be a) )
         )
       )
     )
)

すると以下のエラーが表示されました。

*** - SYSTEM::%EXPAND-FORM:
       (LET ((BE) (A NIL))
        (LOOP (COND ((EQUAL BE (CAR ARG)) (RETURN ARG))) (SETQ BE (CAR ARG))
         (SETQ ARG (CDR ARG))
         (COND
          ((OR (EQUAL 'AM BE) (EQUAL 'IS BE) (EQUAL 'ARE BE) (EQUAL 'WAS BE) (EQUAL 'WERE BE))
           (SETQ ARG (CONS BE (APPEND (REVERSE A) ARG)))))
         (SETQ A (CONS BE A))))
      should be a lambda expression
The following restarts are available:
ABORT          :R1      Abort main loop

このエラーの意味と、どうすれば直るのかを回答していただけると幸いです。
環境は、Windows10で、バーチャルボックス上でubuntuを起動しています。

Answer 1

んん〜。
ANSI Common Lispユーザーがなんて言うか、と言うのは難しい問題だけど、少なくとも、モダンな「関数型プログラミング」の観点から言うとsetqの多用はどうだろうか、ってのがある。
関数型プログラミングだと「なるたけ代入は避ける」。
少なくとも同じLispユーザーでもSchemeユーザーにはその傾向がある。

例えばこんなコードはどうだろう。

(defun question (arg)
  (let ((be (catch 'result
              (reduce #'(lambda (y x)
                          (if (member x arg :test #'eq)
                              (throw 'result x)
                              y))
                      '(am is are was were) :initial-value nil))))
    (when be
      `(,be ,@(remove be arg) ?))))

これでも要求仕様は満たすだろう。

CL-USER> (question '(this is a simple lisp function))
(IS THIS A SIMPLE LISP FUNCTION ?)

condとorとequalで場合分けするより、ANSI Common Lispにはmemberと言う便利な関数がある。
こいつは第1引数が第2引数として与えられたリストの要素として含まれているかどうかを調べる。
含まれた場合は第1引数を先頭とした第2引数の残りのリストを返し、そうじゃない時はnilを返す。

CL-USER> (member 'am '(this is a simple lisp function) :test #'eq)
NIL
CL-USER> (member 'is '(this is a simple lisp function) :test #'eq)
(IS A SIMPLE LISP FUNCTION)

memberではキーワード引数:testで等価判定関数を指定できる。このケースでは、比較対象はシンボルなんで、一番高速なeqで比較可能だ(これはC言語で言うポインタ比較となる)。

関数reduceは誤解を恐れずに言うと非破壊的なfor文だ。あるいはその役目を果たす。
与えられたリスト、この場合だと'(am is are was were)の先頭からmemberの第1引数へと渡していき、それらがリストarg内に含まれているかどうかを調べていく。
ここは基本的には、例えばPythonで言うとこういう形式に近い。

for x in ['am', 'is', 'are', 'was', 'were']:
    member(x, arg)

特殊形式catchとthrowは脱出の為の構文だ。もうちょっと言うとジャンプ構文で、throwで「投げた」計算結果をcatchが受け取る。文字通りだ。
今、'(this is a simple lisp function)と言うリストに対してリスト'(am is are was were)の先頭要素から順繰りにそれが与えられたリストの要素に含まれているかどうかを調べていってるわけだ。
'amは含まれてないんで棄却だが2番目の'isは含まれている。そして、2番目の'isが含まれている、と分かった時点で、残りの'(are was were)は調べなくても良い、って事が決定する。
すなわち、'isを持ってreduceを止めて脱出したい。
それが故にthrowで'isを投げてその外側でcatchし、それをそのままletで変数beに束縛する。
結果、変数beの内容は'isとなる。

あとは簡単だろう。beが取り得る結果は「何らかがあった」か、見つからなかった(つまりnil)か、だ。whenで変数beが非nilの時、単純には、リストargからbeをフィルタリング(remove)したモノのケツに'?を結合したリストを作り、先頭にbeをconsしたモノを返せば題意を満たせる。

Answer 2

let の外にある括弧が一個余分で、
エラーメッセージに表示されているコード全体は、
lambda式であるべきと言われてます。

(defun question (arg)
  (let ((be) (a ())) 
    (loop
     (cond ((equal be (car arg)) (return arg))) 
     (setq be (car arg))
     (setq arg (cdr arg))
     (cond ((or (equal 'am be)
                (equal 'is be)
                (equal 'are be) 
                (equal 'was be)
                (equal 'were be))
            (setq arg (cons be (append (reverse a) arg)))))
     (setq a (cons be a)))))

(print (question '(this is a simple lisp function)))

ちなみに、文字列ではなくシンボルなので出力は

(IS THIS A SIMPLE LISP FUNCTION)

Comments

[subaru-k]

丁寧なご回答ありがとうございます。
理解できました！！