vbsファイルで自動ログインを実現したい

Question

##実現したいこと
現在 vbsファイルで"Classi"に自動ログインさせるコードを書いたのですが、buttonを押すところでうまくいかず、色々試行錯誤を繰り返したのですが解決できなかったので質問させていただきます。

##試したコード

Option Explicit
 
    Dim objIE
    Dim el
 
    Set objIE = CreateObject("InternetExplorer.Application")
    objIE.Visible = True
 
    'IEを開く
    objIE.navigate "https://auth.classi.jp/students"
    
    'ページが読み込まれるまで待つ
    Do While objIE.Busy = True Or objIE.readyState <> 4
        WScript.Sleep 100        
    Loop
    
     'a要素にログインがあったらクリックする
    For each el In objIE.document.Links             
        if instr(el.innerText,"ログイン") then
            el.click
            exit for    
        end if
    next    
    
    'ページが読み込まれるまで待つ
    Do While objIE.Busy = True Or objIE.readyState <> 4
        WScript.Sleep 100        
    Loop    
    
     'IDとパスワードを入力する
     With objIE.document      
        .getElementsByName("classi_id")(0).Value = "ここにID"   
        .getElementsByName("password")(0).Value ="ここにPassword"   
     End With     
     
    Dim objbutton
    
    'button要素をコレクションとして取得
    Set objbutton = objIE.document.getElementsByTagName("button")
    
    'button要素にログインがあったらクリックする
    For each el In objbutton
        if instr(el.innerText,"ClassiのIDでログイン") then 
            el.click
            exit for
        end if         
    next 

上記のコードではフォームにIDとパスワードを入力するところまでは可能です

Answer 1

以下のように form の submit を読んだら、こちらでは動きました。

    Dim objForms
    Dim form

    'Form要素をコレクションとして取得
    Set objForms = objIE.document.getElementsByTagName("form")

    'Form要素に指定のアクションがあったら submit する
    For each form In objForms
        if instr(form.action,"https://auth.classi.jp/login/validate") then 
            form.submit
            exit for
        end if         
    next

Comments

[SAAT]

ご回答いただきありがとうございます!!
具体的なコードを示していただき本当にありがたいです

Answer 2

ボタンクリック部分のエラー処理を削除してとりあえず、単純化して
IDを直接指定やってみてはどうですか？

Comments

[SAAT]

el.click
ではクリックさせていないという事でしょうか

[SAAT]

もしよろしければコードの誤った部分と訂正したところをお教えいただければ幸いです

[AMK]

あ、ごめんなさい
それ見落としてました

[SAAT]

お手数をおかけしてすみません;;

[AMK]

Forとか複雑なので、一度単純化して
対象のボタンを押すように改造してみてはどうですか？

[SAAT]

了解です試してみます ありがとうございました!