未入力箇所があったらメッセージボックスを表示させてマクロを実行させないようにしたい

Question

型が一致しません　とエラーメッセージがでます。

C2からC11の間で数値が入力されていなければ、メッセージボックスでエラーメッセージを出力させ、以降の処理を中断させたいと思っております。
しかし、こちらを実行すると型が一致しませんとエラーメッセージが出力し、原因が分かりません。

Sub 合否判定()
    
       
    If Range("C2:C11") = " " Then
        MsgBox "未記入箇所があります！"
        
        Exit Sub
    End If
    
    Dim i As Long
    
    For i = 1 To 10
        If Cells(1 + i, 3) >= 70 Then
            Cells(1 + i, 4) = "合格"
        Else
            Cells(1 + i, 4) = "不合格"
        End If
    Next i

End Sub

Answer 1

未入力のセルとは「なにも入力されていないセル」とします。

If Range("C2:C11") = " " Then
        MsgBox "未記入箇所があります！"

        Exit Sub
End If

を

    Dim rng As Range
    Dim rg As Range
    Set rng = Range("C2:C11")
    For Each rg In rng
        If rg.Value = "" Then
            MsgBox "未記入箇所があります！"
            Exit Sub
        End If
    Next rg

に変えてください。

Comments

[saki_program]

For Eachを使われてますね。こちらは未学習でした。これから学習を深め、理解できるようにいたします。

Answer 2

" "の型は文字列型でRange("C2:C11")の型は8204(バリアント型の配列)のため、=で比較することが出来ません。

各セルの値を順に比較するかFindメソッド等を使う必要があるかと思います。

Comments

[saki_program]

Findメソッド・・・どう使うかはこれから学習して理解していきます。

Answer 3

「型が一致しません」とエラーメッセージは、下記の行で発生します。

If Range("C2:C11") = " " Then

Range("C2:C11")の型は Range で、" "の型は Strings ですから一致しません。
型の違うものを = で比較することは出来ません。

未記入かどうかは、C2からC11までのセルを順に調べましょう。

修正すると、こんな感じでしょうか。

Sub 合否判定()
   Dim row As Long　'行を示す変数

   ' C2からC11のセルで、未記入("")がないかチェック。
   ' あったら"セルが未記入です"とMagBoxで表示する
   For row = 2 To 11
     If Cells(row, 3) = "" Then
       MsgBox "C" & row & "セルが未記入です" & vbCrLf & "処理を中断します"
       Exit Sub
     End If
   Next row
   
   ' C2からC11のセルの値が70以上ならD列のセルに"合格"、そうでないならD列のセルに"不合格"
   For row = 2 To 11
        If Cells(row, 3) >= 70 Then
            Cells(row, 4) = "合格"
        Else
            Cells(row, 4) = "不合格"
        End If
    Next row

End Sub

MsgBoxに表示するメッセージは、単に"未記入箇所があります！"ではなく、どのセルが未記入なのかを判るようにしました。また、中断する旨の説明も付けました。
丁寧な説明があると、使い勝手がぐんと上がりますからね。

変数 i だと、どういう意味を持つ値か判りませんが、変数 row だと、rowは、行、という意味ですから、行をしているのだなというのが判ります。
少し手間に感じるかもしれませんが、後でプログラムを見直す時に、意味のある変数名をつかっておくと理解しやすいですよ。

Comments

[saki_program]

まだまだ簡単なコードしか書けない私でも理解できました。丁寧な回答ありがとうございます。感謝いたします。