Arduinoで複数のソース内で変数を共有する方法

Question

前提・実現したいこと

Arduinoで、複数のソース内で変数を共有するにはどのようにしたらよろしいでしょうか？

例えば、下記のような感じです。

int testint = 4;  // この変数をグローバル変数にして全てのファイルから参照させたい
void setup() {
 test();
}
void loop() {
}

void test() {
    testint = 8;  // ここで、mainのtestintの内容を変えたいが、exception (28)エラーが発生する
}

Answer 1

C/C++は1970年代仕様(?)なので、他のファイルを自動で調べてくれるなんてしないんですよね。Arduino言語もC++をベースにしてるからその辺はまんま。

もちろん、使うファイルそれぞれでexternで変数を宣言してやれば文法的にも正しくて完全に動くんですが、手法としてはそういう共有で使う変数や関数の宣言を括りだして拡張子.hの「ヘッダファイル」にまとめるのが普通かと思います。

今回であれば

//test1.h
#pragma once //同じヘッダを何度も読み込んで多重定義等不都合が起こるのを防ぐおまじない。知りたければ「インクルードガード」で調べて下さい

extern int testint; //変数の宣言。こういう名前、型の変数があるとコンパイラに知らせる
void test();//関数の宣言。こういう名前、返り値、引数リストの関数があるとコンパイラに知らせる

というのがヘッダファイルになります。Arduino IDEであれば新規タブで作ってやればいいです。
で、このファイルを.inoファイルや.cppファイルで#includeで指定してやります。

//main.ino
#include "test1.h" //ファイル名を囲むのは< >ではなくて" "なのに注意

int testint = 4;  // この変数をグローバル変数にして全てのファイルから参照させたい
void setup() {
 test();
}
void loop() {
}

//sub.cpp
#include "test1.h"

void test() {
    testint = 8;  
}

#includeはライブラリを使うときに使っていると思いますが、実は単に指定されたファイルをその場に展開する、という働きを持っています(コンパイルの内部処理なので通常その結果は見えませんが)。ファイル名を< >で囲むか" "で囲むかはファイルを探す範囲の違い。< >だと、ライブラリの場所(フォルダ/ディレクトリ)から探す、" "ではソースファイルと同じ場所を探してから無ければライブラリの方も探しにいく、ということになります。今回は作成中のソースと密着したヘッダで、.inoや.cppと同じところに作りましたから" "で囲むことになりますね。
さて。その場にファイルを展開するので、ファイルはこのように変形されます。

//main.ino
extern int testint;
void test();

int testint = 4;  // 宣言と矛盾しないので問題は起こらない
void setup() {
 test(); // test関数がどんなものかの情報は得ている
}
void loop() {
}

//sub.cpp
extern int testint;
void test();

void test() { // 宣言と矛盾しないので問題は起こらない
    testint = 8;  //testint関数がどんなものかの情報は得ている
}

ということで無事コンパイルが出来ることになります。
(ライブラリを使うのにヘッダを#include するのも同じ話。クラスや関数、変数、マクロの宣言等をソース上に展開して、そういうものがあることをコンパイラに教えているわけです)

ソース中にexternを書くのと同等、ファイルを作るだけ面倒...まぁ、これだけならその通りなんてすが、プログラムを書いていて、ありゃ、testintの値がintじゃ収まらなくなっちゃった、long型に変えよう...なんてことが起こったとします。もちろん、正しく関係する箇所を全部変更すればいいんですが、main.inoだけ変更して「修正できたつもり」になっていたとします。そうすると、

//main.ino
//test1.hが展開されたもの
extern int testint;
void test();

long testint = 4;  // 矛盾するので"ちゃんと"エラーになる
void setup() {
 test();
}
void loop() {
}

となるので間違いが検出されます。これが、プログラム中に直接externで書き込んであったとすると

//sub.cpp
extern int testint;

void test() {
    testint = 8;  //このファイルの範囲では矛盾は発生しない
}

はエラー無くコンパイルが完了してしまいます、しかしmain側はtestintはlongとして、sub側はintとして扱うので矛盾し、プログラムは期待通りに動かない...関数の中身だけを見ても原因はわからないという悩ましい事態に陥ることになります。

間違いがあるときには確実にエラーにする仕組み、これ意外と大事。

ある程度以上の規模のプログラムになったら、変数や関数も多くなり、あちこちのファイルで使用されていて修正漏れなども出てくるでしょう。自分は絶対にミスなどしない、という自信があるので無い限り、その被害を防ぐためにヘッダファイルを適切に作成する習慣をつけてしまうことをお勧めします。

Comments

[raizun]

ご回答ありがとうございます。

今は小規模な開発だけを行っていますが、先の事を考えて
ヘッダファイルに宣言を纏めて書くようにします。

Answer 2

方法1:
sub.cppの方でextern int testint;と宣言するか、

// sub.cpp
extern int testint;

void test() {
    testint = 8;
}

方法2:
test()関数にint *型の引数を加えて

// main.cpp
int testint = 4;  // この変数をグローバル変数にして全てのファイルから参照させたい

void test(int *intval);

void setup() {
 test(&testint);
}
void loop() {
}

// sub.cpp
void test(int *intval) {
    *intval = 8;
}

でしょうか。

Comments

[raizun]

ご回答ありがとうございます。

方法１のextern を用いる方法で変数を共有する事ができました。