VBA 実行時エラー'91'の解決法(2)

Question

前提・実現したいこと

いつもありがとうございます。
VBAでエクセルの勤務表から勤務日等を抽出し、別のソフトウェアに読み込ませる転換マクロツールを作っています。
以下のVBAを実行したところ、1回目は正常に動作するのですが、2回目以降、初回に読み込んだものと違う階層のエクセルファイルを読み込もうとすると、以下のエラーメッセージが再現性ありで発生します。

発生している問題・エラーメッセージ

実行時エラー'91'
オブジェクト変数またはWithブロック変数が設定されていません。

該当のソースコード

Private Sub btnGetFilePath() 'ファイル選択ダイアログモジュール

Dim fType As Variant
Dim fPath As Variant

'選択できるファイルの種類はすべてのファイル
fType = ""

'ファイル参照ダイアログの表示
fPath = Application.GetOpenFilename(fType, , "") 'fType = fPath。

If fPath = False Then
'ダイアログでキャンセルボタンが押された場合は処理を終了します
End
End If

Dim Target As Workbook 'コンバートモジュール
Set Target = Workbooks.Open(fPath)

'これをセル抜き出しから数値抜出に変更⇔循環小数エラーの解決。
Target.Sheets(1).Range("G2").Copy ThisWorkbook.Sheets(2).Range("A2")
Target.Sheets(1).Range("H2").Copy ThisWorkbook.Sheets(2).Range("A3")

End Sub

試したこと

前回質問したと同一のVBAですが、不要な記述を削除して整形しました。
今回のエラーの再現性から、"1回目にエクセルファイルを開いたときにどこかに値を取得して"しまっていて、"2回目以降、その1回目に取得したパスの値と違う"ことが"実行時エラー'91'"の原因なのではと考えました。
すると例えば、23行End Subの真上に〇〇.Clearと処理完了時に値をクリアする命令文を入れれば解決するのかと思い、該当する記述を調べましたがわかりませんでした。もしおわかりになればお願いします。

補足情報（FW/ツールのバージョンなど）

Excle2016

Comments

[end-u]

Q1)どの行がエラーになるのでしょうか？
Q2)
>前回質問したと同一のVBAですが、不要な記述を削除して整形しました。
その整形後のコードだけでエラーになりますか？
Q3)そのコードは標準モジュールに書かれたものですか？＆そのモジュールに他のプロシージャはありますか？

[r_o_234]

end-uさん
情報追記します。

Q1)どの行がエラーになるのでしょうか？
　21行目のTarget.Sheets(1).Range("G2").Copy ThisWorkbook.Sheets(2).Range("A2")の行です。
Q2)
>前回質問したと同一のVBAですが、不要な記述を削除して整形しました。
その整形後のコードだけでエラーになりますか？
　はい。この成型後のコードだけでエラーになります。
Q3)そのコードは標準モジュールに書かれたものですか？＆そのモジュールに他のプロシージャはありますか？
　このコードは標準モジュールに書かれたものです。このモジュールに他のプロシージャはありません。

よろしくお願いします。

Answer 1

開くファイルは読み取り専用で良いのですよね？
ちょいと↓のテストお願いします

Private Sub testmacro()
    Dim fType As Variant
    Dim fPath As Variant
    '選択できるファイルの種類はすべてのファイル★Excelファイルに限定していいんじゃ？
    fType = "Excel,*.xls*"
    'ファイル参照ダイアログの表示
    fPath = Application.GetOpenFilename(fType)
    If fPath = False Then
        'ダイアログでキャンセルボタンが押された場合は処理を終了します
        'End は使わない★
        Exit Sub
    End If

    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets(2)
    Application.EnableEvents = False
    Dim wb As Workbook
    Set wb = Workbooks.Open(fPath, UpdateLinks:=False, ReadOnly:=True)
    Application.EnableEvents = True
    MsgBox wb.Name
    'これをセル抜き出しから数値抜出に変更⇔循環小数エラーの解決。★コメント内容不一致？
    wb.Sheets(1).Range("G2").Copy ws.Range("A2")
    wb.Sheets(1).Range("H2").Copy ws.Range("A3")
End Sub

Comments

[r_o_234]

end-uさん
添削ありがとうございます。
end-uさんのを実行した所、残念ながら実行時エラー'91'が出ました。
上記のhatena19さんのコードで解決したので、恐らく、開いたブックを逐次閉じて、変数開放してNothingしクリアする必要があったのだと思います。
ご協力ありがとうございました！

Answer 2

エラーの解決になるかどうかはわかりませんが、ちょっと気になったところを修正してみました。

Private Sub btnGetFilePath() 'ファイル選択ダイアログモジュール

    Dim fType As Variant
    Dim fPath As Variant

'※選択できるファイルの種類はエクセルファイルのみ
    fType = "Microsoft Excelブック,*.xls?" '※

'ファイル参照ダイアログの表示
    fPath = Application.GetOpenFilename(fType, , "") 'fType = fPath。
    Debug.Print fPath
    If fPath = False Then
'ダイアログでキャンセルボタンが押された場合は処理を終了します
       Exit Sub 'Endで強制終了はよろしくない
    End If

    Dim Target As Workbook 'コンバートモジュール
    Set Target = Workbooks.Open(fPath)

    'これをセル抜き出しから数値抜出に変更⇔循環小数エラーの解決｡
    Target.Sheets(1).Range("G2").Copy ThisWorkbook.Sheets(2).Range("A2")
    Target.Sheets(1).Range("H2").Copy ThisWorkbook.Sheets(2).Range("A3")
    
     Target.Close '※開いたブックは閉じておく
     Set Target = Nothing '念のため、変数開放

End Sub

Comments

[r_o_234]

hatena19さん
修正ありがとうございます。エラー解消して動くようになりました！

1,選択をエクセルに限定。2,Endで終了する前にExitする。3,Taget.Closeでブックを閉じる。4,変数開放する。の4点の修正を施して頂いたと思いますが、恐らく特に3,4,の修正が原因を解決したのではと思います。

ありがとうございました！もっとVBAのレベルを高めます！