VB　エクセル書き込み

VB で新規にエクセルを開き，一定時間ごとに変更するリッチテキストボックスやラベルの文字をエクセルのセルに自動で入力させ，エクセルを名前をつけて保存するということをしたいです．

VBでエクセルを開く方法を調べると，プロジェクトの参照設定で Microsoft Excel.ObjectLibrary にチェックを入れなければならないようなのですが，見当たりません．
コードをかくだけではエクセルは開けないのでしょうか？
また，
Dim xlApp As Excel.Application
Dim xlBook As Excel.Workbook
Dim xlSheet As Excel.Worksheet
Set xlApp = CreateObject("Excel.Application")
Set xlBook = xlApp.Workbooks.Add
Set xlSheet = xlBook.Worksheets(1)

というコードでは実行できませんでした．
アドバイスよろしくお願いします．

追記：
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim ExcApp As Object
Dim n As Integer
Dim myPath As String = "C:\Users\Ikumi Fukiishi\Desktop\Book1.xlsx"
ExcApp = CreateObject("Excel.Application")
ExcApp.workbooks.open(myPath)
ExcApp.visible = True

    ExcApp.cells(n, 1).value = RichTextBox1.Text
    ExcApp.cells(n, 2).value = Label1.Text
End Sub

リッチテキストボックスやラベルの文字を開いたエクセルのセルに入力していきたいです．
上の追記したコードではエラーがでました．
アドバイスをよろしくお願いします．

行動規範の内容に同意します

回答1件

ベストアンサー

Excelがインストールされていれば参照設定のCOMタブにExcelの名前が出てくると思いますが・・・見つかりませんか？

あと技術的な部分ですが、以下の宣言

Dim xlApp As Excel.Application 
Dim xlBook As Excel.Workbook 
Dim xlSheet As Excel.Worksheet

は参照設定をすることで使用できるようになります。（事前バインディング）
参照設定を行っていなければ、まずこの部分でエラーが発生するのではないかと思われます。

これに対して、

Set xlApp = CreateObject("Excel.Application")

で行っているのは、事前バインディングせず、実行時にExcelオブジェクトを生成するやり方（遅延バインディング）です。
クライアントのExcelバージョンに依存しないようにする目的などで利用され、参照設定も必要ありません。

遅延バインディングで実装する場合、各変数の宣言はobject型で行えばよいです。
ただし、コーディング時にパラメータの候補が表示されないなどのデメリットもあるため、開発時は参照設定できたほうが楽です。

Dim xlApp As Object 
Dim xlBook As Object
Dim xlSheet As Object

Set xlApp = CreateObject("Excel.Application")

（追記）
セルの値を参照・編集するためには、対象のブックやシートまで特定してあげる必要があります。
まずは開いたエクセルに対する操作の仕方を勉強しましょう。
⇒参考

事前バインディングの場合 (参照設定が必要)

Imports Microsoft.Office.Interop.Excel

Public Class Form1
  Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
    '変数宣言
    Dim myPath As String = "C:\Users\Ikumi Fukiishi\Desktop\Book1.xlsx"
    Dim xlApp As New Application()
    Dim xlBook As Excel.Workbook
    Dim xlSheet As Excel.Worksheet
    
    'ファイルオープン
    xlBook = xlApp.Workbooks.Open(myPath) 
    xlSheet = xlBook.Worksheets(1)
    xlApp.Visible = True
    
    'Excel操作
    xlSheet.Cells(1, 1).value = RichTextBox1.Text 
    xlSheet.Cells(1, 2).value = Label1.Text 
    
    '上書保存
    xlBook.Save()
    
    'Excelを閉じる
    xlApp.Workbooks.Close()
    xlApp.Quit()
    
  End Sub
End Class

遅延バインディングの場合

Public Class Form1
  Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
    '変数宣言
    Dim myPath As String = "C:\Users\Ikumi Fukiishi\Desktop\Book1.xlsx"
    Dim xlApp As Object
    Dim xlBook As Object
    Dim xlSheet As Object
    
    'Excelオブジェクト作成
    xlApp = CreateObject("Excel.Application")
    
    'ファイルオープン
    xlBook = xlApp.Workbooks.Open(myPath) 
    xlSheet = xlBook.Worksheets(1)
    xlApp.Visible = True
    
    'Excel操作
    xlSheet.Cells(1, 1).value = RichTextBox1.Text 
    xlSheet.Cells(1, 2).value = Label1.Text 
    
    '上書保存
    xlBook.Save()
    
    'Excelを閉じる
    xlApp.Workbooks.Close()
    xlApp.Quit()
  End Sub
End Class

なお、ご覧になってわかるとおり、違いは変数宣言とExcelオブジェクトの作成までで、あとは共通の記述です。

投稿2016/01/21 03:37

編集2016/01/21 07:03

jawa

総合スコア3020