ランダム色のコード簡略化

Question

プログラミング歴1週間の者です。

前提・実現したいこと

要求されている内容は全て達成していますが、
コードをコンパクトにする方法を探しています。
特にランダムを10回も呼ばなくていい方法を探しています。

コードの概要

カーソルの位置によって形を変える円と四角を太さ3の縁付きで描写し、初期の青,赤,黒,そして背景のシアンの色をマウスのクリックによってランダムなRGB色に変化させる(ただし背景の色はグレースケールから変化させる)というものです。

該当のソースコード

color backgroundColour = color(0, 255, 255); //initially cyan
color strokeColour = color(0); //initially black
color rectangleColour = color(255, 0, 0); //initially red
color ellipseColour = color(0, 0, 255); //initially blue

void setup()
{
  size(500, 500);
}

void draw()
{
  background(backgroundColour); //initially cyan
  rectMode(CORNERS); //use 2 diagonal coordinates for the rectangle
  ellipseMode(CORNERS); //use 2 diagonal coordinates for the bounding box
  stroke(strokeColour); //initially black
  strokeWeight(3);
  fill(rectangleColour); //initially red
  rect(mouseX, mouseY, 1.5, height-1.5); //move the shapes towards the centre by 1.5 to show full stroke width
  rect(mouseX, mouseY, width-1.5, 1.5);
  fill(ellipseColour); //initially blue
  ellipse(1.5, 1.5, mouseX-1.5, mouseY-1.5);
  ellipse(height-1.5, width-1.5, mouseX+1.5, mouseY+1.5);
}

void mousePressed()
{
  backgroundColour = color(random(256));
  rectangleColour = color(random(256), random(256), random(256));
  ellipseColour = color(random(256), random(256), random(256));
  strokeColour = color(random(256), random(256), random(256));
}

試した事

色を生成する機能を作り、それをそれぞれの形に適応させる方針で模索しています。

補足情報（FW/ツールのバージョンなど）

Processing 3.5.4
検索スキルの向上は自分の今後の課題です。

Comments

[hoshi-takanori]

コードをコンパクトにする方法ではありませんが、背景、四角、円、線をそれぞれ単純なランダム色にしたいならそれでいいと思いますが、規則性を持たせて連続的に変えた方が美しくなると思います。どうやるかはプログラミングよりも色彩センスの問題になります。

[KeeganP]

要求されている内容が完全ランダムな色彩なので、解決策としてランダムな色を生成する機能を作り,それをそれぞれの形に適応させる方針で模索しています。

[hoshi-takanori]

それなら、ランダムな色を返す関数を作って呼ぶことで、コード上 random の数は減らせますね。実際に random が呼ばれる回数は変わりませんが。

[KeeganP]

正にそれを求めています。現在

```
void generateRandomColour()
{
試行錯誤中 RandomColour = color(random(256),random(256),random(256));
}

```
の様なものを追加していじっています。しかし、void mousePressed() との連動が上手くいっていません。

Answer 1

ランダムな色を返す関数を作って呼ぶ方法ですが、たぶんこんな感じで関数の戻り値を使えばいいと思います。
（Processing 知らないので、エラーが出たらごめんなさい。）

void mousePressed()
{
  backgroundColour = color(random(256));
  rectangleColour = generateRandomColour();
  ellipseColour = generateRandomColour();
  strokeColour = generateRandomColour();
}

color generateRandomColour()
{
  return color(random(256), random(256), random(256));
}

Comments

[KeeganP]

ありがとうございます。非常に簡潔なコードで感激しました

Answer 2

最終的にランダムな10個の要素が必要なのだから、都合10回randomが呼び出されることは避けられないので、それをいかにまとめて書くか、ぐらいしか工夫の余地はなさそう。

color backgroundColour = color(0, 255, 255); //initially cyan
color strokeColour = color(0); //initially black
color rectangleColour = color(255, 0, 0); //initially red
color ellipseColour = color(0, 0, 255); //initially blue

void setup()
{
  size(500, 500);
  //毎回同じ値が設定されるだけなのでsetup()に括りだす
  rectMode(CORNERS); //use 2 diagonal coordinates for the rectangle
  ellipseMode(CORNERS); //use 2 diagonal coordinates for the bounding box
  strokeWeight(3);
}

void draw()
{
  background(backgroundColour); //initially cyan
  stroke(strokeColour); //initially black
  fill(rectangleColour); //initially red
  rect(mouseX, mouseY, 1.5, height-1.5); //move the shapes towards the centre by 1.5 to show full stroke width
  rect(mouseX, mouseY, width-1.5, 1.5);
  fill(ellipseColour); //initially blue
  ellipse(1.5, 1.5, mouseX-1.5, mouseY-1.5);
  ellipse(height-1.5, width-1.5, mouseX+1.5, mouseY+1.5);
}

enum RANDMODE {
  MONOCHROME, 
  COLOR
}

color getRandomColor(RANDMODE mode) {
  color col;
  if (mode==RANDMODE.COLOR) {
    col= color(random(256), random(256), random(256));
  } else {
    col= color(random(256));
  }
  return col;
}

void mousePressed()
{
  backgroundColour = getRandomColor(RANDMODE.MONOCHROME);
  rectangleColour = getRandomColor(RANDMODE.COLOR);
  ellipseColour = getRandomColor(RANDMODE.COLOR);
  strokeColour = getRandomColor(RANDMODE.COLOR);
}

10回繰り返し感を解消して、全体の長さとしてはむしろ長くなった。
無理に縮めるよりは、素直に書いたほうがいい範囲じゃないかしら。

(どうでもいいけど、「英語」colourと「米語」colorの混在はちょっと気になるなぁ。なにかポリシーがあるのでなければ、システム側の米語に合わせたら?)

Comments

[KeeganP]

ありがとうございます。setup()への括り出し、参考になりました。また、イギリス英語主流の国に住んでいるためcolourの綴りはこのままにします。

Answer 3

完全に同じ意味になっているのかは自信ありません。

// 変更ないところ省略

void mousePressed()
{
  backgroundColour = color(random(256)); // これはそのままでいいかな？
  rectangleColour = getRandomColor();
  ellipseColour = getRandomColor();
  strokeColour = getRandomColor();
}
// どういう意味か分かりにくいので関数にしておきたいところ
color getRandomColor() {
  return int(random(0xFFFFFF+1)) | 0xFF000000;
}

color \ Language (API) \ Processing 3+