いま動いてるプロセスのユーザを知る方法ってあるでしょうか。

Question

たとえば二重起動しては困るようなアプリを起動するときに、起動前に「そのプロセスが既にありますか？」と確認する動作を入れます。

それで
たとえばそのプロセスがメモ帳だとして
こんな感じでメモ帳のプロセスがあるかぐるぐる回して探します。（全部じゃなくその回す動作のところだけ書きます）

for each p as system.diagnostics.process in system.diagnostics.process.getprocessesbyname("notepad")
  exists = true
  exit sub
next

今日、あるアプリを、絶対に起動してないことを目視で確認したのに、これを回すと「そのプロセスあります」と出てしまうのです。
おかしいなと思って、プロセスの稼働状況を見てみました。

いつも、プロセスの稼働状況を詳しく見るときは
Process Explorer
を使って見ます。
これで見てわかったのは
私がこの作業をしていたのはWindowsServerで
私の他にあと何人か別のユーザがログインしていて、
そのなかの誰かがそのアプリを使っていたのでした。

なので、知りたいのは、「そのプロセスが自分のプロセスかどうか」です。
自分のじゃないってわかればユーザ名はわからなくていいです。
Linuxだとpsで見るところですが
VB.NETならどのように書けば、「プロセス名を指定して、当該のプロセスが自分のプロセスかどうかを返り値で得る」ことができるのでしょうか。

上に書いたものは「プロセス名が探しているものと一致したらOK」なのですが、
これにさらに「自分のプロセスだったら」という条件を足したいのです。
が、書き方がわかりません。
よろしくお願いします。

#補足
Blue Prismのタグをつけていますが、これはBlue Prismのコードステージに書いて実行しています。
なので、制御室からRRで実行する場合は、ひとつのRRにロボットアカウント1個しかいないので、この問題は出ません。
たとえば開発環境のようなインタラクティブクライアントで、複数のユーザがデバッグ実行するときに問題になるものです。
だからまあ本番で問題ないからいいじゃんと言われればそうなので今すぐ超困る話ではないのですが、
開発ユーザが増えてくるとそこそこ困るというお話です……。

Comments

[Zuishin]

WMI を使えばできると思います。

https://docs.microsoft.com/en-us/windows/win32/cimwin32prov/getowner-method-in-class-win32-process
https://uchukamen.com/Programming/WMI/

[sumire_cl]

おおありがとうございます、
検索します。

Answer 1

「WMI プロセス ユーザ名」でググると結構ヒットします。
VB.NET で書かれたものを抜粋すると
https://dobon.net/vb/bbs/log3-3/1615.html

https://okwave.jp/qa/q2467712.html

https://qa.itmedia.co.jp/qa2467712.html

などいろいろ
なんだか元ネタが同一っぽい気もしますが・・・

他のユーザが起動したプロセスはユーザ名取得時、エラーになることががありますが、
自分かそうでないかを判断すればよいわけで、エラーになれば自分のプロセスではない、
というロジックで良いと思います、

WMI はちょっと遅いので API でゴリゴリ書いた例を紹介しておきます。(C#)
http://kozhouse.homeip.net/dotnet/etc/10/

###追記
Framework に何か部品がないかなーと調べてみたのですが、System.Security.Principal.WindowsIdentity を使うと、もっと簡単になります。

Imports System.Runtime.InteropServices
Imports System.Security.Principal

Module Module1

    Sub Main()
        For Each p In Process.GetProcesses()
            Using wid As WindowsIdentity = GetWindowsIdentity(p)
                Debug.WriteLine("{0} {1}", p.ProcessName, If(wid Is Nothing, "(Error)", wid.Name))
            End Using
            p.Dispose()
        Next
    End Sub

    Public Function GetWindowsIdentity(ByVal process As Process) As WindowsIdentity
        Dim tokenHandle As IntPtr
        Try
            If OpenProcessToken(process.Handle, TOKEN_QUERY, tokenHandle) Then
                Return New WindowsIdentity(tokenHandle)
            End If
        Catch ex As Exception
        Finally
            If tokenHandle <> IntPtr.Zero Then
                CloseHandle(tokenHandle)
            End If
        End Try
        Return Nothing
    End Function

    Private Const TOKEN_QUERY = &H8

    <DllImport("advapi32.dll", SetLastError:=True)>
    Private Function OpenProcessToken(ByVal ProcessHandle As IntPtr, ByVal DesiredAccess As Integer, ByRef TokenHandle As IntPtr) As Boolean
    End Function

    <DllImport("kernel32.dll", SetLastError:=True)>
    Private Function CloseHandle(ByVal hHandle As IntPtr) As Boolean
    End Function

End Module

OpenProcessToken を公開しているメソッドがあれば、API 使わなくて済むのですが、今のところ見つからないです。