batもしくはVBSでファイルの連番を除去する方法を教えてください

Question

以下はとある記事で見かけたbatファイルで
指定のフォルダ以下のファイルすべてに
"[]"付きの連番をファイル先頭に
付与してくれるのですが、

逆に今度は付けた"[]"付きの連番を
削除するbatに改修したいと思っているですが
「正規表現」を使えばいいのかなとは
推測しているのですが、具体的に
どうしたらいいのかわからないので
教えてください。

修正前
[0001]pict_A.jpg
[0002]thum_D.jpg
・
・
・
[0111]thum_D99.jpg

修正後
pict_A.jpg
thum_D.jpg
・
・
・
thum_D99.jpg

@echo off
setlocal enabledelayedexpansion

pushd ..

set rootDi=%cd%
popd


for /f "usebackq delims=" %%f in (`dir /b /a-d`) do (

set /a cnt+=1
set use=0000!cnt!
set use="["!use:~-4!"]"
set fileName=%%f
set newFileName=!use!!fileName!
echo 対象 : !fileName! 
echo リネーム後 : !newFileName!
ren "!fileName!" "!newFileName!"
echo --------------------------
)

)
echo fin

pause

exit

Comments

[Ken.sakanakana]

修正前のファイル名と、修正後のファイル名を記載頂くとより的確な回答がでると思います。連番を取るだけですとファイル名が重複してしまいそうです。
複数のファイルを一つに固めるだけなら、copy /b *sourcefile destfile で一つにまとめられます。

[chrokurojp]

アドバイスありがとうございます。修正例を追記しました

Answer 1

同じ感じで書くとこんなですね(括弧を1つ余計なので取りました)。
先頭に付加されているのが固定長なので、「7文字目以降を取る」というのも有りだと思います。

@echo off
setlocal enabledelayedexpansion

pushd ..
set rootDi=%cd%
popd

for /f "usebackq delims=" %%f in (`dir /b /a-d`) do (
  set fileName=%%f
  set newFileName=!fileName:*]=!
  echo 対象 : !fileName! 
  echo リネーム後 : !newFileName!
  ren "!fileName!" "!newFileName!"
  echo --------------------------
)
echo fin
pause
exit

追記：拡張子BATの時は処理対象外にする。

@echo off
setlocal enabledelayedexpansion

pushd ..
set rootDi=%cd%
popd

for /f "usebackq delims=" %%f in (`dir /b /a-d`) do (
  if /i "%%~xf" neq ".BAT" (
    set fileName=%%f
    set newFileName=!fileName:*]=!
    echo 対象 : !fileName! 
    echo リネーム後 : !newFileName!
    ren "!fileName!" "!newFileName!"
    echo --------------------------
  )
)
echo fin
pause
exit

Comments

[chrokurojp]

ありがとございます。

実現できました！！！

ついでに下記のような拡張子が「.bat」のファイルを
対象外とするにはどうしたらいいのか差し出がましいのですが
教えてくれませんか

for /f "usebackq delims=" %%f in (`dir /b /a-d`) do (
の直後に if文でファイル名文字列に「bat」があれば
スキップするみたいな流れまでしかイメージできていなくて
どう書けばいいのかがわかりません

【SCRIPT】_rename_renban.bat

[otn]

追記しておきます。