[Excel][VBA] 指定の文字列を含むシートのみコピーして1シートにまとめる方法

Question

複数シートが存在するブックにて、
シート名に”食”が含まれるシートのみ抽出し、
シート内容をすべてコピーしたうえで
一つのシートにまとめたいです。(縦追加)

マクロとしては、
・シート名の指定にワイルドカードを使用
・シートをループして条件式を適用
がポイントかと思っておりますが
条件指定が正しくなく全てのシートをコピーしてしまう状態です。

アドバイス等ありましたら教示いただけると幸いです。

使用のマクロです＿＿＿＿＿＿＿＿＿＿＿＿＿＿
Sub Test()
Dim i As Long, ad As Integer, r As Long
Dim ws As Worksheet
Dim wsname As String
wsname = "食"

Sheets(1).Cells.Clear
For Each ws In Worksheets
If ws.Name Like "*" & wsname Then
For i = 2 To ActiveWorkbook.Sheets.Count
Sheets(i).UsedRange.Copy
r = Sheets(1).UsedRange.Rows.Count
If i = 2 Then ad = 0 Else ad = 2 '※
Cells(r, 1).Offset(ad).Select '※
ActiveSheet.Paste
End If
Next
Next

Sheets(1).Columns.AutoFit
End Sub

Answer 1

食が必ずシート名の最後に来るなら問題ありませんがその条件だとそれ以外が一致しません。
また全シート分コピーされてしまうのは、
シート名の判定のIF文内のFor文で全シート分処理を回してしまっているからでしょう。
外側のFor文で全シート分処理を回しているのでそちらを利用すればいいと思います。

Sub Test()
    Dim aws As Worksheet, ws As Worksheet
    Dim wsname As String
    Dim copyRow As Long
    wsname = "食"
    
    'ActiveSheetをコピー先シートとする
    Set aws = ActiveSheet
    aws.Cells.Clear
    
    'コピー行位置
    copyRow = 1
    
    For Each ws In Worksheets
        'シート名が"*食*"にLIKE一致する場合
        If ws.Name Like "*" & wsname & "*" Then
            'ループさせているシートの入力範囲をコピー先シートのコピー行、A列にコピー
            ws.UsedRange.Copy Destination:=aws.Cells(copyRow, "A")
            'コピー行位置にループさせているシートの入力範囲の最終行数を加算
            copyRow = copyRow + ws.UsedRange.Rows.Count
        End If
    Next ws
    
    aws.Columns.AutoFit
End Sub

Comments

[tesgakr]

まさに目的が実現できました！
初歩的な質問で大変失礼いたしました。
ご丁寧かつ迅速な対応をいただきありがとうございました。
大変大変助かりました。