VBAでHTMLのタグを消したい

Question

文字が<>で囲まれている部分を消すには、どうすればよろしいですか？
元の文字列が<div></div>ああああああああ< /br></script>のような場合にHTMLタグだけ消したいのです。

私がしようとしていることは以下のような感じです。これは、構文エラーになりますが。
出来れば、< /br>タグだけは残したいです。
Replace(文字列, "<" & * & ">", "")

Comments

[m.ts10806]

本来の目的や背景、要件が不明瞭すぎます。
赤の他人が初めて見てもなんのことか分かるように具体的に記載してください。

[m.ts10806]

そもそものそのHTMLとなるものはどこから取得されるものなのでしょうか。
あとできれば質問は質問テンプレートにそってお書きください。

>< /br>タグだけは残したいです。
動作確認したわけじゃないですが、<br />はありますが、</br>というタグはないはずですけど。

[Y.H.]

確認です。
タグにある通り「VBA」ですよね？「VBScript」じゃないですよね？
もし「VBScript」ならタグを修正お願いします。

Answer 1

こんにちは。
BRタグを<br />とした前提で、正規表現を使えばこんな感じです。

Public Function deleteHTML(htmlText As String) As String
    Dim regObj As New VBScript_RegExp_10.RegExp
    
    '正規表現オブジェクトの設定
    With regObj
        'BRタグを否定的先読みし、残りのHTMLタグにパターンマッチさせる正規表現
        .Pattern = "(?!\<\s*br\s+/?\s*\>)(\<(""[^""]*""|'[^']*'|[^'""\>])*\>)"
        '英大文字小文字を区別しない
        .IgnoreCase = True
        '文字列全体に対してパターンマッチさせる
        .Global = True
    End With
    
    '正規表現による置換
    deleteHTML = regObj.Replace(htmlText, "")

    Set regObj = Nothing
End Function

Sub sampleTest()
    Dim html As String
    
    html = "<div></div>ああああああああ<br /></script>"
    Debug.Print html
    Debug.Print deleteHTML(html)
End Sub

実行結果

<div></div>ああああああああ<br /></script> ああああああああ<br />

Comments

[na58chan]

ありがとうございます。しかし、Dim regObj As New VBScript_RegExp_10.RegExpここでエラーが出てきます。ユーザー定義型は定義されていません。との表示がでてきます。

[DreamTheater]

すみません、遅くなりました。
ツール⇒参照設定から「Microsoft VBScript Regular Expressions 1.0」を追加してください。