GetOpenFilenameを使用して、ファイルが存在する場合、【開く・処理・閉じる】を繰り返したい

Question

Sub Sample7()
Dim filePath As Variant
filePath = Application.GetOpenFilename _
(FileFilter:="Excelブック(.xlsx;.xlsm),*.xlsx; *.xlsm; *.xls", MultiSelect:=True)

Dim trgt As Variant
Set trgt = Workbooks("a").Sheets("b")
Dim wb As Workbook

If IsArray(filePath) Then
For Each wb In filePath
If Dir(wb) = "123" Then
Set wb = Workbooks.Open("123")
wb.Sheets(2).Range("J19:Q20") = trgt.Range("D55:K56")
wb.Sheets(2).Range("J21:Q22") = trgt.Range("D58:K59")
wb.Close
End If

 If Dir(wb) = "456" Then       
     Set wb = Workbooks.Open("456")
     wb.Sheets(2).Range("J19:Q21") = trgt.Range("D60:K62")
     wb.Close
 End If

.
.
.
.
If Dir(wb) = "789" Then
Set wb = Workbooks.Open("789")
wb.Sheets(2).Range("J19:Q21") = trgt.Range("D63:K65")
wb.Close
End If

Next
End If

どうしてもわからないのでご教授ください。
GetOpenFilenameで複数のファイル選択をし、ファイルを全て開いて、処理する
ではなく
複数のファイル選択後、一つファイルを開き処理し閉じる、一つファイルを開き処理し閉じる、としたいです。
また、Ifステートメントを使用して、ファイルが存在しない場合は処理を無視するとしたいです。
GetOpenFilenameでパスを取得しているので、そこを活用するのかと思いますが、どうしてもわかりません。
どなたかご教授お願いします。

Comments

[meg_]

コードは「コードの挿入｣で記入しましょう。

Answer 1

Option Explicit

Sub Sample7()
    Dim filePath As Variant
    Dim v As Variant
    Dim trgt As Worksheet
    Dim wb As Workbook

    filePath = Application.GetOpenFilename _
               (FileFilter:="Excelブック(*.xlsx;*.xlsm),*.xlsx; *.xlsm; *.xls", MultiSelect:=True)
    If IsArray(filePath) Then Exit Sub

    Set trgt = Workbooks("a").Sheets("b")

    For Each v In filePath
        Set wb = Nothing
        On Error Resume Next
        Set wb = Workbooks.Open(v)
        On Error GoTo 0

        If Not wb Is Nothing Then
            Select Case True
                Case wb.Name Like "123.*"
                    wb.Sheets(2).Range("J19:Q20") = trgt.Range("D55:K56")
                    wb.Sheets(2).Range("J21:Q22") = trgt.Range("D58:K59")
                Case wb.Name Like "456.*"
                    wb.Sheets(2).Range("J19:Q21") = trgt.Range("D60:K62")
                Case wb.Name Like "789.*"
                    wb.Sheets(2).Range("J19:Q21") = trgt.Range("D63:K65")
            End Select
            wb.Close True
        End If
    Next
End Sub

動かしてないけど、イメージ的にはこんな感じですかね？
Select　Case　の時のLike演算子の使い方があっているかうろ覚えなので自信ないです。
選択しているので「存在しない」というこは無いと思いますが、
「開けない」ということがあると思うので、エラー回避を一応入れてます。
ファイルのベースネームを取得する（または抜き取る）とこはもうちょっとちゃんとやってもいいかなと
思います。その辺はご自身の判断でお願いします。
参考になれば。

Comments

[Dis]

非常に参考になりました。
特に以下の文が非常に参考になりました！！！
If Not wb Is Nothing Then
Select Case True
Case wb.Name～
本当にありがとうございました。

Answer 2

GetOpenFilenameで選択した、エクセルブックそれぞれに対して処理を行いたいという話であれば、以下のURLのコードが参考になりませんか。

https://32877.xii.jp/view/263
選択した複数のファイルに同じ処理をするVBA例

ただしこの例では、選択した各ワークブックに対し同じ処理をしたいのではなく、ワークブックのファイル名によって処理が微妙に違うみたいで若干工夫が要ると思います。