EXCEL VBAマクロでフォルダに入っているEXCELブックのシートを参照して集計ブックに保存していきたいが、シート名が違う

Question

EXCEL VBAマクロでフォルダに入っているEXCELブックのシートを参照して集計ブックに保存していきたいが、シート名が違う

ご質問させていただきます。

EXCEL VBAマクロでフォルダに入っているEXCELブックのシートを参照して集計ブックに保存して行こうと下記のマクロで動かしておりますが、
現在、EXCELブック（名前は複数）のシートAのG1とF25を引っ張り、集計ブックに入れ込んでおります。
しかし、新たにシートBのH1とG25を引っ張る必要がでてきました。
ただシートの名前が違う状況ですと、抽出する事ができず、違うシート名のブックにあたった時点でデバッグエラーと出てしまいます。

下記のマクロで

Do Until myFile = ""
Workbooks.Open myPath & myFile
With Workbooks("集計.xls").Worksheets("Sheet1").Range("A65536").End(xlUp)
.Offset(1, 0).Value = myFile
.Offset(1, 1).Value = Workbooks(myFile).Worksheets("シートA").Range("G1").Value
.Offset(1, 2).Value = Workbooks(myFile).Worksheets("シートA").Range("F25").Value
もしシート名がシートBならばH1を抽出
End With

くわえて、参照するデータが無ければデバッグエラーではなく無視してマクロ続行というマクロは組み込めるのでしょうか。

大変恐縮ですが、ご教示の程よろしくお願い致します。

Sub macro1()
Dim myPath As String
Dim myFile As String

myPath = "C:\Users\test\Desktop\フォルダ1"
myFile = Dir(myPath & "*.xls")

Do Until myFile = ""
Workbooks.Open myPath & myFile
With Workbooks("集計.xls").Worksheets("Sheet1").Range("A65536").End(xlUp)
.Offset(1, 0).Value = myFile
.Offset(1, 1).Value = Workbooks(myFile).Worksheets("シートA").Range("G1").Value
.Offset(1, 2).Value = Workbooks(myFile).Worksheets("シートA").Range("F25").Value
End With
Workbooks(myFile).Close savechanges:=False
myFile = Dir()
Loop
End Sub

Answer 1

もうちょっと柔軟な作りにするべきかと思います。
全シートを回して、特定のシート名で切り分けるような作りの方がよいでしょう。
例えばこんな感じ（動作未確認です）

Sub macro1()
    Dim myPath As String
    Dim myFile As String
    Dim myBk As Workbook
    Dim ws As Worksheet
    
    myPath = "C:\Users\test\Desktop\フォルダ1"
    myFile = Dir(myPath & "*.xls")
    
    Do Until myFile = ""
        
        Set myBk = Workbooks.Open(myPath & myFile)
        With Workbooks("集計.xls").Worksheets("Sheet1").Range("A65536").End(xlUp)
            For Each ws In myBk.Worksheets
                Select Case ws.Name
                    Case "シートA"
                        .Offset(1, 0).Value = myFile
                        .Offset(1, 1).Value = ws.Range("G1").Value
                        .Offset(1, 2).Value = ws.Range("F25").Value
                        Exit For
                    Case "シートB"
                        .Offset(1, 0).Value = myFile
                        .Offset(1, 1).Value = ws.Range("H1").Value
                        .Offset(1, 2).Value = ws.Range("G25").Value
                        Exit For
                End Select
            Next
        End With
        
        myBk.Close savechanges:=False
        myFile = Dir()
        
    Loop
    
End Sub

くわえて、参照するデータが無ければデバッグエラーではなく無視してマクロ続行というマクロは組み込めるのでしょうか。

On Error Resume Nextを使えば可能ですが、本当に必要かどうかを考えて使ってください。
ほとんどのエラーは事前にチェックすることで回避が可能です。
それでも回避できない場合、Resume Next を使うことが妥当であるなら使うべきです。

Comments

[DreamTheater]

ttyp03さんの（特に）最後の３行に非常に同意します。
安易にエラースキップを使用するべきではありません。

[ttyp03]

安易にResumeNextしちゃうとホントのエラー（バグ）を見逃しちゃいますからね。

[ko1]

ありがとうございます。頂きました上記ソースで実行できました。
お手数をおかけいたしました。

Answer 2

こんにちは。
目的のシートが存在するか否かをチェックできれば回避できると解釈しました。

Workbookオブジェクトとシート名を渡して、そのブックにそのシート名が存在するか否かを返す
こんな関数を作れば判定できませんか？

Pubic Function IsExistSheetName(sheetName As String, wb As Workbook) As Boolean
	Dim ws As Worksheet

	IsExistSheetName = False
	For Each ws In wb.Worksheets
		If ws.Name = sheetName Then
			IsExistSheetName = True
			Exit Function
		End If
	Next
End Function

Trueが返ればシート名あり、Falseならシート名なし。

Comments

[ko1]

ありがとうございます。ご参考にさせて頂きます。

Answer 3

無視してマクロ続行

詳しく見ていないですがOn ErrorステートメントのOn Error Resume Nextですね。

ただ、意味不明な結果になる事もある（そんな時に何が原因なのか？が分からない）事もあるので、分かるならエラーする箇所をIf文で飛ばすようにした方がいいとは思います。

Comments

[ko1]

ありがとうございます。参考にさせて頂きます。