VisualStudioのテスト機能が使用できない

Question

デバッグを効率的に行いたいと思ったので、
VisualStudioに標準で備わっているテスト機能を
試してみようと思ったのですが、うまくいきません。

以下記載のサンプルプログラムの足し算を行うメソッド(Add)を
右クリックして「テストの実行」を選択 したのですが、
「>1 ミリ秒でテストの実行が終了しました。　
テストの合計 0 成功 0、失敗 0 スキップ 0 」
と表示されるだけで、何も起こりません。
何かテスト機能を使用するために追加で何か設定をしないといけないのでしょうか？

環境：Visual Studio 2019 Community
言語：Visual Basic

＊＊＊サンプルのソースコード＊＊＊
Module Module1

Public Sub Main()

    System.Windows.Forms.MessageBox.Show(Add(1, 2))

End Sub

Private Function Add(ByVal x As Integer, ByVal y As Integer) As Integer

    Return x + y

End Function

End Module
＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊

Answer 1

「テストの実行」は単体テストプロジェクト内のテスト用メソッドを実行するための機能です。
Addを右クリックしたところで意味はありません。

テスト例

テスト対象とするクラスライブラリ(ここでは仮にClassLibrary1とする)を作成し、コードを追加する。

Public Class Class1
    Private Function Add(ByVal x As Integer, ByVal y As Integer) As Integer
        Return x + y
    End Function

    Public Function Mul(ByVal x As Integer, ByVal y As Integer) As Integer
        Return x * y
    End Function
End Class

MSTestテストプロジェクトを作成し、上記テスト対象(ClassLibrary1)への参照を追加し
以下のようなテストコードを追加する。

Imports System.Text
Imports ClassLibrary1
Imports Microsoft.VisualStudio.TestTools.UnitTesting
<TestClass()> Public Class UnitTest1
    <TestMethod()> Public Sub TestAdd()
        'Privateメソッドの実行
        Dim target As New Class1
        Dim po As New Microsoft.VisualStudio.TestTools.UnitTesting.PrivateObject(target)
        Dim result = po.Invoke("Add", {1, 2})

        Assert.AreEqual(3, result)
    End Sub

    <TestMethod()> Public Sub TestMul()
        Dim target As New Class1
        Dim result = target.Mul(2, 3)

        Assert.AreEqual(6, result)
    End Sub

    <TestMethod()> Public Sub TestMulFail()
        Dim target As New Class1
        Dim result = target.Mul(2, 3)

        'テスト失敗例
        Assert.AreEqual(5, result)
    End Sub
End Class

テストは以下の方法で実行できます。

• TestAddやTestMul、TestMulFailを右クリックして「テストの実行」
• テストエクスプローラ内「すべてのテストを実行」
• テストエクスプローラ内でテストしたいメソッドを選択して「実行」