ADODB.Recordset.Filterで実行時エラー3001

Question

前提・実現したいこと

ExcelテーブルからSQLでインプットしたRecordsetに対して複数条件でFilterをかけたい

発生している問題・エラーメッセージ

実行時エラー3001
引数が間違った型、許容範囲外、または競合しています。

該当のソースコード

Class:TableOperator

Dim adoConn As ADODB.Connection
Dim adoRs As ADODB.Recordset

Private inputTable_ As ListObject
Private filter_ As String

Private Sub Class_Initialize()
    Set adoConn = CreateObject("ADODB.Connection")
    Set adoRs = CreateObject("ADODB.Recordset")
End Sub

Public Property Set InputTable(Table As ListObject)
    Set inputTable_ = Table
    Dim ws As Worksheet: Set ws = Table.Parent
    With adoConn
        .Provider = "Microsoft.ACE.OLEDB.12.0"
        .ConnectionString = "Data Source = " & ThisWorkbook.FullName & _
             ";Extended Properties =Excel 12.0;"
        .Open
        
        With adoRs
            .CursorLocation = 3 'adUseClient
            .CursorType = adOpenStatic
            .Open "SELECT [従業員CD],[従業員名],[最新所属名],[職種名],[残業時間],[休出時間],[年間残業時間],[年間残業時間] + [年間休出時間] AS [総残業時間] FROM [" & ws.Name & "$" & ws.ListObjects(inputTable_.Name).Range.Address(False, False) & "]", adoConn, adOpenDynamic
        End With
        
    End With
End Property

Public Property Let Filter(ByVal inputValue As String)
    filter_ = inputValue
    adoRs.Filter = filter_
End Property

Module1

Sub Main()
    With New TableOperator
        Set .InputTable = ThisWorkbook.Sheets("DATA").ListObjects(1)
        .Filter = "(([残業時間] >= 40 AND [残業時間] <= 45) OR ([年間残業時間] >= 350 AND [年間残業時間] <= 360) OR [総残業時間] >= 700) AND 最新所属名 = 'ブロックA'"
    End With
End Sub

試したこと

Filterの条件を減らすとエラーが無くなる

• [総残業時間] >= 700 AND 最新所属名 = 'ブロックA'
  OK
• ([残業時間] >= 40 AND [残業時間] <= 45) OR ([年間残業時間] >= 350 AND [年間残業時間] <= 360)

OK

• (([年間残業時間] >= 350 AND [年間残業時間] <= 360) OR [総残業時間] >= 700) AND 最新所属名 = 'ブロックA'

NG

Answer 1

括弧の数があってないから？

([年間残業時間] >= 350 AND [年間残業時間] <= 360) OR [総残業時間] >= 700) AND 最新所属名 = 'ブロックA'
↓
(([年間残業時間] >= 350 AND [年間残業時間] <= 360) OR [総残業時間] >= 700) AND 最新所属名 = 'ブロックA'

---

括弧の数はコピペミスですかね。失礼しました。
MSのドキュメントを見ると、以下のようにあります。

AND と OR の間に優先順位はありません。句はかっこでグループにまとめることができます。ただし、次のように、 OR で句を結合してできた句のグループを、 AND を使ってさらに別の句と結合することはできません。

この条件に合致していそうです。

また同じような問題で困っている人のページではFilerを並べて書くことで解決しています。
次のように書くことで解消できないでしょうか。

Sub Main()
    With New TableOperator
        Set .InputTable = ThisWorkbook.Sheets("DATA").ListObjects(1)
        .Filter = "最新所属名 = 'ブロックA'"
        .Filter = "([残業時間] >= 40 AND [残業時間] <= 45) OR ([年間残業時間] >= 350 AND [年間残業時間] <= 360) OR [総残業時間] >= 700"
    End With
End Sub

Comments

[woria]

かっこの数は何度か見直しましたが、エラーの解決にはなりませんでした。

[ttyp03]

回答を追記しました。
解決できるかはわかりませんが、ご確認ください。

[woria]

試しましたが、Filterを並べて書いた場合、後から記入したFilterが優先され、先に書かれたFilterの条件が無視されました。
また、SELECTしたRecordsetに対してFilterをかけるのではなく、OpenのSQLの時点でWHERE文を使って検索しようとしましたが、これも複数条件を指定した時にエラーになりました。

[woria]

>AND と OR の間に優先順位はありません。句はかっこでグループにまとめることができます。ただし、次のように、 OR で句を結合してできた句のグループを、 AND を使ってさらに別の句と結合することはできません。
ということであれば、Recordset以外の方法でデータ出力を試してみます。

[ttyp03]

ダメでしたか。
あとは条件の書き方を見直すとかですかね。
ORのグループをANDするのがダメなので、次のような感じにしたらいけるのでは。ちょっと冗長ですが。
.Filter = "([残業時間] >= 40 AND [残業時間] <= 45 AND 最新所属名 = 'ブロックA') OR ([年間残業時間] >= 350 AND [年間残業時間] <= 360 AND 最新所属名 = 'ブロックA') OR ([総残業時間] >= 700 AND 最新所属名 = 'ブロックA')"

[woria]

クラスの汎用性とか諸々無視しましたが、無事解決しました。

adoRs.Open "SELECT [従業員CD],[従業員名],[最新所属名],[職種名],[残業時間],[休出時間],[年間残業時間],[年間残業時間] + [年間休出時間] AS [総残業時間] FROM [" & ws.Name & "$" & ws.ListObjects(inputTable_.Name).Range.Address(False, False) & "] WHERE [残業時間] BETWEEN 40 AND 45 OR [年間残業時間] BETWEEN 350 AND 360 OR [年間残業時間] + [年間休出時間] >= 700;", adoConn, adOpenDynamic

と、Open時点でWHERE文を記入し、
.Filter = "最新所属名 = 'ブロックA'"

として、WHEREとFilterを両採用することで、無事フィルタ処理ができました。