VBScriptの関数について

Question

前提・実現したいこと

初心者です。VBScriptで逆ポーランド記法を使った簡易電卓を作っている途中です。
PopとPushを関数で表したいのですが、Private Function Push(a, b)でPushの関数を作り、UBoundをつかって1番上に乗せていく？という方向性で作っていくのがいいのかな、と考えたところで行き詰まってしまいました。ご教授頂けますでしょうか。

発生している問題・エラーメッセージ

エラーメッセージ

該当のソースコード

ソースコード

試したこと

ここに問題に対して試したことを記載してください。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

配列をスタック代わりにするのを無理やりやるとこんな感じでどうでしょう。

class STACK_OBJECT
    private STACK

    private sub class_Initialize
        init_stack
    end sub

    ' STACK の初期化
    private sub init_stack()
        STACK = array()
        ' この時点で UBound(STACK) = -1 となる（これをしないとUBoundがエラー）
    end sub

    ' STACK の拡張
    private sub expand_stack()
        if UBound(STACK) = -1 then
            Redim STACK(0)
        else
            Redim preserve STACK(UBound(STACK)+1)
        end if
    end sub

    ' STACK の縮小
    private sub reduce_stack()
        select case UBound(STACK)
        case -1
            ' 既に空配列（この場合何をしたいかは要件次第）
        case 0
            init_stack
        case else
            Redim preserve STACK(UBound(STACK)-1)
        end select
    end sub




    ' 引数をSTACKに積む
    sub push(a)
        expand_stack
        STACK(UBound(STACK)) = a
    end sub

    ' STACKの最後の要素を取得し、要素を詰める
    function pop()
        Dim tmp
        tmp = STACK(UBound(STACK))
        reduce_stack

        pop = tmp
    end function

    ' STACK の状態を出力するデバッグ関数
    sub debug()
        Dim tmp, i

        for i = LBound(STACK) to UBound(STACK)
            tmp = tmp & "STACK(" & i & ")" & " : " & STACK(i) & vbCrLf
        next

        msgbox tmp
    end sub

end class


' テストコード

Dim OBJ

Set OBJ = new STACK_OBJECT

' push
obj.push 1
obj.push 2
obj.push 3
obj.debug

' pop
msgbox obj.pop

' pop後
obj.debug

Set OBJ = Nothing

Answer 2

.NET のスタックが COM 公開されているので使えます。

実験記録　No.02 : VBSでキュー(Queue)、スタック(Stack)を使う

Answer 3

UBoundは、宣言されたサイズ（＝指定可能な最大の添え字）を返しますので、その目的には使えません。
データを格納した最大添え字を変数で管理してください。

Answer 4

Stackの簡単な実装をVBScriptでやるなら、Stack用配列を用意し、

PushでRedim Preserve Stack(Ubound(Stack)+1)
Pop でRedim Preserve Stack(Ubound(Stack)-1)

でいいんじゃないかな？

Dim Stack()
Const MaxStackPointer = 32767
ReDim Stack(0)

SUB Push(obj)
    If UBound(Stack) >= MaxStackPointer Then
        Err.Raise vbObjectError + 1, "Push", "Stack Overflow."
    End If

    ReDim Preserve Stack(UBound(Stack)+1)
    Stack(UBound(Stack)) = obj
END SUB

Function Pop()
    If UBound(Stack) <= 0 Then
        Err.Raise vbObjectError + 1, "Pop", "Stack Underflow."
    End If

    Pop = Stack(UBound(Stack))
    ReDim Preserve Stack(UBound(Stack)-1)
END Function

WScript.Echo "Init:" & "  - StackPointer:" & UBound(Stack)
WScript.Echo ""

Push("2")
WScript.Echo "Push:" & "2   - StackPointer:" & UBound(Stack)
Push("3")
WScript.Echo "Push:" & "3   - StackPointer:" & UBound(Stack)
Push("4")
WScript.Echo "Push:" & "4   - StackPointer:" & UBound(Stack)
Push("100")
WScript.Echo "Push:" & "100 - StackPointer:" & UBound(Stack)

WScript.Echo ""

WScript.Echo "Pop:" & Pop() & " - StackPointer:" & UBound(Stack)
WScript.Echo "Pop:" & Pop() & "   - StackPointer:" & UBound(Stack)
WScript.Echo "Pop:" & Pop() & "   - StackPointer:" & UBound(Stack)
WScript.Echo "Pop:" & Pop() & "   - StackPointer:" & UBound(Stack)

WScript.Echo "Pop:" & Pop() & "   - StackPointer:" & UBound(Stack)

C:\temp>cscript Stacktest.vbs
Init:  - StackPointer:0

Push:2   - StackPointer:1
Push:3   - StackPointer:2
Push:4   - StackPointer:3
Push:100 - StackPointer:4

Pop:100 - StackPointer:3
Pop:4   - StackPointer:2
Pop:3   - StackPointer:1
Pop:2   - StackPointer:0
C:\temp\Stacktest.vbs(17, 9) Pop: Stack Underflow.

Comments

[Y.H.]

あぁ何か間違ってましたか。
バグ箇所のご指摘コメントで頂きたいです。