batで「,」が削除されるのを防ぎたい

Question

前提・実現したいこと

言語:batファイル
環境:Windows10 64bit

以下のように変数にjsonを代入し、
jqによって抽出した数値を変数に格納するバッチを作りたいと考えています

例)
set JSONDATA={"status":200,"ids":[{"id":76}]}
filter.bat "%JSONDATA%" ".ids[].id"
echo %ANS%
=> 76と出力されてほしい

該当のソースコード

@echo on
for /f %%i in ('echo %~1 ^| jq.exe %2') do set ANS=%%i

発生している問題・エラーメッセージ

しかし、上のようなバッチを書いたところ、以下のように出力されました。

> filter.bat "%JSONDATA%" ".ids[].id"
for /F %i in ('echo {"status":200 "ids":[{"id":76}]} | jq.exe ".status"') do set ANS=%i
parse error: Expected separator between values at line 1, column 19

試したこと

出力から、上のエラーはcmdの仕様でJSON内の「,」が削除された為だろうと考えています。
しかし、「,」を削除されないようにしようと「%~1」を""で囲むと、
そのままjson全体が""で囲まれた状態になってしまうため、jqがフォーマットエラーを出してしまいます。

どのように書けば期待通りの挙動にすることができるのでしょうか？

Answer 1

jqに環境変数を読む機能があるとは知りませんでしたが、一般論的に解決すると、,をエスケープします。

set JS=%~1
for /f %%i in ('echo %JS:,=^,% ^| jq.exe %2') do set ANS=%%i

'～～'でサブシェルを起動するときに','が落ちるようです。
for in ( )の括弧の中では、, ; =などが空白となってしまいます。
参考：for %%A in (a b,c;d=e) do echo %%A

最初、

echo %~1 | for /f %%i in ('jq.exe %2') do set ANS=%%i

でいいかと思ったのですが、パイプの為にサブシェルが起動され、ANSはサブシェル内の変数になってしまい、次の行で参照できません。

Comments

[bsdfan]

バッチファイルのエスケープのやり方を知らなかったので、だいたいツールかスクリプトでどうにか迂回してやり過ごしてきたのですが、こうすればできるんですね！

[dasugar]

こちらのやり方でも動作することが確認できました！
%環境変数名:置換対象=置換先% の記法があるのですね。

bsdfanさんのご回答で十分満足でしたが、
このQ&Aのタイトルからはotnさんのご回答の方が適していると思われるため、
他の方が見た時の為にこちらにベストアンサーを移させていただきます。

ご回答いただきありがとうございます。

[otn]

この問題に関しては、bsdfanさんのがB.A.かと思いますが、
確かに、タイトルと合うのは私の方ですね。
それよりPowerShellかWSL+Bashを使いましょうという方針がいい気もします。

> バッチファイルのエスケープのやり方を知らなかったので、
カンマならできますが、記号によってはどうしようもなくてお手上げです。
= とかは多分無理です。

Answer 2

コンマを削除させない方法は分かりませんでしたが、文字列を環境変数にセットして、jqの中でその環境変数の文字列を展開するという風にすれば、データを取り出すことはできそうです。

@echo off
setlocal
set JSONTEXT=%~1
for /f "usebackq" %%i in (`jq.exe -n "env.JSONTEXT|fromjson|%~2"`) do set ANS=%%i
echo %ANS%

JSON文字列が長すぎると、問題があるかもしれません。

Comments

[dasugar]

ご教示頂いたやり方で動作することが確認できました！
jqに環境変数を読む機能があったのですね。勉強不足でした。

ご回答いただきありがとうございます。
大変助かりました。

Answer 3

for文の出力結果では確かにカンマは表示されていませんが、echoだけ見ればカンマは残っているようです。
バッチファイルはこうなるような気がします。
"usebackq"を追加、()内をバッククォートに変更。

@echo on
for /f "usebackq" %%i in (`echo %~1 ^| jq.exe %2`) do set ANS=%%i

バッチファイルに与えるパラメーターは以下でしょうか。
（第2パラメーターの先頭にピリオドを追加）

> filter.bat "%JSONDATA%" ".ids[].id"

動作未検証です。

Comments

[dasugar]

ご回答いただきありがとうございます。

ご指摘の通りにバッククォートを使うようコードを変更しても出力は同じでした。
そもそもjson内にはシングルクォートは含まれておらず、
usebackqで区切り文字が変わっただけであるため、挙動は変わらない、と考えます。

加えて、「echoだけ見ればカンマは残っている」と頂いておりますが、
jsonの「200,"ids」がechoでは「200 "ids」になっているので、
カンマはやはり消えているのではないでしょうか？

> バッチファイルに与えるパラメーターは以下でしょうか。
> （第2パラメーターの先頭にピリオドを追加）
こちらコピペミスしておりましたので修正いたしました。
大変失礼いたしました。

[ttyp03]

ごめんなさい。
あまり関係ありませんでしたね。
どうもfor文内でのみカンマが消えてしまうようで困りましたね。
代替案として、一旦%JSONDATA%をファイルに出力して、それをjqに与えるのではどうでしょうか？
当方jqの環境がないため確認できていませんが。。。
echo %~1 > tmp.txt
for /f %%i in ('type tmp.txt ^| jq.exe %2') do set ANS=%%i
del tmp.txt

[ttyp03]

もしくはjqの結果をファイルに出力する方が素直な考え方かもしれません。
echo %~1 | jq.exe %2 > tmp.txt
for /f %%i in (tmp.txt) do set ANS=%%i
del tmp.txt

[dasugar]

説明不足ですみません。
実は現在は提案頂いたようなコードでファイルに読み書きすることで代替していました。
しかし、毎度ファイルに出すのも無駄なので質問させていただいておりました。

今回はbsdfanさんのご回答で解決できましたが、
カンマが消されること自体は防げていないのでまた勉強するように致します。

ご回答いただきありがとうございました。