【VB】GetFolder(フォルダ名).SubFoldersで取得できるフォルダの並び方について

Question

#質問内容
あるフォルダのサブフォルダ名を全て取得する処理をForEachを用いてコーディングしています。

For Each name In .GetFolder(folder).SubFolders
 Debug.Print "フォルダ名：" & name
Next

取得対称のフォルダ構成は

親フォルダ-１
　　　　　∟２
　　　　　∟３
　　　　　∟４
　　　　　∟５
　　　　　(中略)
　　　　　∟１９８
　　　　　∟１９９
　　　　　∟２００

と、１から２００までの数字でフォルダ命名されています。

エクスプローラ上ではフォルダ１、フォルダ２、フォルダ３、フォルダ４・・・
という順番に上から並んでおり、この並び順でフォルダ名を取得したいのですが前述のコードだと

フォルダ名：１
フォルダ名：１０
フォルダ名：１００
フォルダ名：１０１
フォルダ名：１０２
フォルダ名：１０３
（中略)

何故かソートされてしまいます。

#実現したい内容
エクスプローラー上の見た目通りにフォルダ名を取得する方法はありますか？

Answer 1

StrCmpLogicalW API を使った Sort のサンプルです。

Private Declare Function StrCmpLogicalW Lib "Shlwapi.dll" (ByVal psz1 As Long, ByVal psz2 As Long) As Long

Function ExplorerCompare(ByVal psz1 As String, ByVal psz2 As String, ByVal reverse As Boolean) As Long
    Dim result As Long
    result = StrCmpLogicalW(StrPtr(psz1), StrPtr(psz2))
    If reverse Then
        ExplorerCompare = 0 - result
    Else
        ExplorerCompare = result
    End If
End Function

Sub ExplorerSort(ByRef sortArray() As String, ByVal reverse As Boolean)
    Dim i As Long
    Dim j As Long
    Dim k As Long
    Dim lngLow As Long
    Dim lngHigh As Long
    Dim tmp As String
    
    lngLow = LBound(sortArray)
    lngHigh = UBound(sortArray)
    
    For i = lngHigh To lngLow Step -1
        For j = lngLow + 1 To i
            k = j - 1
            If ExplorerCompare(sortArray(k), sortArray(j), reverse) > 0 Then
                tmp = sortArray(j)
                sortArray(j) = sortArray(k)
                sortArray(k) = tmp
            End If
        Next j
    Next i
End Sub

使い方

Const MaxCount As Long = 100

Dim sortArray(MaxCount - 1) As String
Dim i As Integer
Dim v As Variant

For i = 0 To MaxCount - 1
    sortArray(i) = StrConv(CStr(i), vbWide)
Next

Debug.Print "---- 逆順 ----"
ExplorerSort sortArray, True
For Each v In sortArray
    Debug.Print v
Next

Debug.Print "---- 昇順 ----"
ExplorerSort sortArray, False

For Each v In sortArray
    Debug.Print v
Next

Answer 2

エクスプローラのファイル順のように、自然順ソートで並び替える
こちらにあるように自分でソートする形になるかと思います。
参考にあげたページのサンプルはVB.NETなので、VB6に移植する必要があります。

数字が連番であるだけなのであれば、ttyp03さんの仰るようにループで回したほうが楽です。

Answer 3

確か無理だったと思います。
というか１～２００と決まっているのであれば、For～Nextで1～200まで回して全角変換したらいかがでしょうか。
わざわざ実際のフォルダを取得する必要はないかと思います。