proseccing ゲームタイトルの付け方

Question

このゲームの始まりに”press button　to start”みたいなテキストを入れてゲームの進行をしたいのですが

int title(){
  text("Game Title", width * 0.5, height * 0.3);
  text("Press button to start", width * 0.5, height * 0.7);
  if(keyPressed)

このような感じのコードを挿入したいです。しかしコードも不十分です。また入れる場所も分かりません。
いれるとしたらほかに必要な要素は何なのでしょうか。
教えてください。

Bullet bullet;
private Boss boss = new Boss(75, 35);
private ArrayList<Bullet> danmaku = new ArrayList<Bullet>();

float[] z = new float[500];
float[] y = new float[500]; 

void setup() {
  size(450, 600);

  frameRate(40);

  noCursor();

  bullet = new Bullet(width/2, height/2, 10, 0, 0 );

  for (int r = 0; r < z.length; r++) {
    z[r] = random(-1000,300);
    y[r] = random(height); 
  }
}

void ship(int x, int y) {こ
  noStroke();

  fill(255, 0, 0);

  ellipse(mouseX, mouseY, 7.5, 7.5); 
}



class Boss {
  private int tx, ty;
  private int dx, dy;
  private long routine = 0;
  Boss(int x, int y) {
    tx = x;
    ty = y;
    dx = 1;
    dy = -5;
  }
  void move() {
    tx += dx;
    ty += dy;
    if (tx < 0 || tx > width) {
      dx*= -1;
    }
    if (ty < 0 || ty > height) {
      dy*= -1;
    }
  }
  void doShinking() {
    routine++;
    if (routine % 10 == 0) {
      move();
    }
    if (routine % 30 == 0) {
      danmaku.addAll(this.shot());
      println("#shot" +routine + ":" + tx + "," + ty);
    }
  }
  ArrayList<Bullet> shot() {
    ArrayList<Bullet> danmaku = new ArrayList();
    for (int i = 0; i < 360; i+= 11.5) { 
      double rad = radians(i);
      danmaku.add(new Bullet(this.tx, this.ty, 10, Math.cos(rad), Math.sin(rad)));
    }
    return danmaku;
  }
}

class Bullet {

  private double tx, ty;
  private final double tr;
  private double dx, dy;
  private boolean is_alive = true;
  Bullet(double x, double y, double r, double temp_dx, double temp_dy ) {
    tx = x;
    ty = y;
    tr = r;
    dx = temp_dx;
    dy = temp_dy;
  }
  boolean isAlive() {
    return is_alive;
  }
  void update() { 
    tx += dx;
    ty += dy;
    if (Math.min(tx, ty) < 0) {
      is_alive = false;
      return ;
    }
    if (tx > width || ty > height) {
      is_alive = false;
      return ;
    }
    stroke(255, 0, 255);

    fill(0, 0, 255);

    ellipse((float)tx, (float)ty, (float)tr, (float)tr);
  }
}



void draw() {
  background(0); 

  ship(mouseX, mouseY);
  boss.doShinking();

  for (int i = danmaku.size() -1; i  >= 0; i--) {
    Bullet b = (Bullet)danmaku.get(i);
    if (!b.isAlive()) {
      danmaku.remove(i);
      continue;
    }
    b.update();
  }


  for (int r = 0; r < z.length; r++) {
    z[r] += 2;
    if(z[r] > width + 7.5){ 
      z[r] = random(-1000,-10); 
      y[r] = random(height);
    }
    stroke(255, 0, 255); 
    fill(0,0,255); 
    ellipse(z[r], y[r], 10, 10); 
  }
}

```ここに言語名を入力
ソースコード

試したこと

ここに問題に対して試したことを記載してください。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

int title() { }？？
と思ったら Processing で状態遷移のあるゲーム・アプリを作る こちらのサイトですね？

引用にもなっていませんし、参考にするにしても参考サイトがあるのであれば明示してください。

確かにちょっと凝ったことをしているので、わかりにくくなっているかもしれませんね。
わかりやすいようにもっとシンプルに書き直してみました。

Bullet bullet;
Boss boss;
ArrayList<Bullet> danmaku;
float[] z;
float[] y;

int state;            // 今の画面状態
final int TITLE = 0;  // タイトル画面
final int GAME = 1;   // ゲーム画面
final int ENDING = 2; // ゲームオーバー画面

void setup() {
  size(450, 600);
  frameRate(40);
  noCursor();

  init(); // 各変数の初期化
}

// 各変数の初期化
void init() {
  boss = new Boss(75, 35);
  danmaku = new ArrayList<Bullet>();
  bullet = new Bullet(width / 2, height / 2, 10, 0, 0 );
  z = new float[500];
  y = new float[500]; 

  for (int r = 0; r < z.length; r++) {
    z[r] = random(-1000, 300);
    y[r] = random(height);
  }
}

void draw() {
  if (state == TITLE) { // 今の画面状態がタイトル画面だったら。。。
    title();            // タイトル画面の描画
  } else if (state == GAME) { // 今の画面状態がゲーム画面だったら。。。
    game();                   // ゲーム画面の描画
  } else if (state == ENDING) { // 今の画面状態がゲームオーバー画面だったら。。。
    ending();                   // ゲームオーバー画面の描画
  }
}

// タイトル画面の描画
void title() {
  background(0); 
  fill(255);
  textSize(24);
  textAlign(CENTER);
  text("Game Title", width * 0.5, height * 0.3);
  text("Press any key to start", width * 0.5, height * 0.7);
  if (keyPressed) { // 何かのキーが押されていれば。。。
    state = GAME;   // ゲーム画面に遷移
  }
}

// ゲーム画面の描画
void game() {
  background(0); 
  ship(mouseX, mouseY);
  boss.doShinking();

  for (int i = danmaku.size() -1; i >= 0; i--) {
    Bullet b = (Bullet)danmaku.get(i);
    if (!b.isAlive()) {
      danmaku.remove(i);
      continue;
    }
    b.update();
  }

  for (int r = 0; r < z.length; r++) {
    z[r] += 2;
    if (z[r] > width + 7.5) { 
      z[r] = random(-1000, -10); 
      y[r] = random(height);
    }
    stroke(255, 0, 255); 
    fill(0, 0, 255); 
    ellipse(z[r], y[r], 10, 10);
  }
}

// ゲームオーバー画面の描画
void ending() {
  fill(255);
  textSize(24);
  textAlign(CENTER);
  text("try again?", width * 0.5, height * 0.3);
  text("Press any key to restart", width * 0.5, height * 0.7);
  if (keyPressed) { // 何かのキーが押されていれば。。。
    state = GAME;   // ゲーム画面に遷移
    init();         // 各変数の初期化
  }
}

void ship(int x, int y) {
  noStroke();
  fill(255, 0, 0);
  ellipse(mouseX, mouseY, 7.5, 7.5);
}

// 以下各classは変更無いので省略

Comments

[miiso_soup]

ご指摘ありがとうございます。
しかもとても親切に書き直していただけるなんて。
これを見て少し勉強します。
ありがとうございました。
引用の件は気を付けます。

Answer 2

見りゃだいたいわかると思うけど。

boolean isTitle=true;//タイトル表示中かどうか?

final int R=50;
final int DX=2;
final int DY=1;
int x,y;
int dx=2;
int dy=1;

void setup() {
  size(640, 480);
  x=width/2;
  y=height/2;
  textAlign(CENTER,TOP);
}

void title() {
  text("Game Title", width * 0.5, height * 0.3);
  text("Press button to start", width * 0.5, height * 0.7);
}

void draw() {
  if(isTitle){ //タイトル表示状態だったら
    background(32,32,64);
    title();//タイトル表示して
    if(keyPressed){//キー検査して
      isTitle=false;//押されてたら次回以降はここに来ない
    }
    return;//さっさと抜けちゃう
  }
  //本番処理
  background(204);
  circle(x,y,R);
  x+=dx;
  y+=dy;
  if(x<R/2){
    x=10;
    dx=DX;
  }else if(x>width-R/2){
    x=width-R/2;
    dx=-DX;
  }
  if(y<R/2){
    y=R/2;
    dy=DY;
  }else if(y>height-R/2){
    y=height-R/2;
    dy=-DY;
  }
}