継承したTextBoxが上寄せになってしまう

Question

https://www.projectgroup.info/tips/Microsoft.NET/comm_0016.html

上記サイトを参考に、枠線の色を変更出来るTextBoxを作成しました。
ビルドしてFormに置き、実際に入力してみると通常のTextBoxより上に表示されてしまいます。

コードの中で影響を及ぼしている箇所があるんでしょうか？
また、中央に表示させるにはどうしたらいいでしょうか？

よろしくお願いします。

Imports System.Drawing
Imports System.Windows.Forms
Imports System.ComponentModel

Public Class ColorTextBox
    Inherits TextBox
    Private Const WM_PAINT = &HF
    Private _CustomBorderColor As Color = Color.FromArgb(171, 173, 179)

    ''' <summary>
    ''' TextBoxの枠線の色を指定します。
    ''' </summary>
    <Description("TextBoxの枠線の色を指定します。")>
    Public Property CustomBorderColor() As Color
        Get
            Return _CustomBorderColor
        End Get
        Set(ByVal value As Color)
            If _CustomBorderColor <> value Then
                _CustomBorderColor = value
                Me.Refresh()
            End If
        End Set
    End Property

    ''' <summary>
    ''' WndProcメソッドオーバーライド
    ''' </summary>
    ''' <param name="m"></param>
    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        MyBase.WndProc(m)
        If (m.Msg = WM_PAINT) Then
            Using g As Graphics = CreateGraphics()
                If _CustomBorderColor <> Color.FromArgb(171, 173, 179) Then
                    Dim p As New System.Drawing.Pen(_CustomBorderColor)
                    g.DrawRectangle(p, 0, 0, Me.Width - 1, Me.Height - 1)
                Else
                    ControlPaint.DrawVisualStyleBorder(g, New Rectangle(0, 0, Me.Width - 1, Me.Height - 1))
                End If
            End Using
        End If
    End Sub
End Class

追記
参考画像はっておきます
左：継承TB　右：通常TB

Answer 1

ウインドウには、クライアント領域と、非クライアント領域があります。
フォームでいうとタイトルバー、枠線、AutoScroll のときのスクロールバーが非クライアント領域になります。

BorderStyle.FixedSingle のとき、非クライアント領域は存在せず、枠線はクライアント領域に描画されます。

対して、BorderStyle.Fixed3D のとき、枠線は非クライアント領域に描画されますので CreateGraphics で作成した Graphics オブジェクトでは上書きできません。

非クライアント領域に描画するには、GetWindowDC API で取得したデバイスコンテキストハンドルから Graphics オブジェクトを作成して描画します。

Imports System.Drawing
Imports System.Windows.Forms
Imports System.ComponentModel
Imports System.Runtime.InteropServices

Public Class ColorTextBox
    Inherits TextBox

    Private _CustomBorderColor As Color = Color.FromArgb(171, 173, 179)

    Public Property CustomBorderColor() As Color
        Get
            Return _CustomBorderColor
        End Get
        Set(ByVal value As Color)
            If _CustomBorderColor <> value Then
                _CustomBorderColor = value
                Me.Refresh()
            End If
        End Set
    End Property

    Private Const WM_PAINT As Integer = &HF
    Private Const WM_NCPAINT As Integer = &H85
    Private Const WM_NCACTIVATE As Integer = &H86

    <DllImport("User32")>
    Private Shared Function GetWindowDC(hWnd As IntPtr) As IntPtr
    End Function

    <DllImport("User32")>
    Private Shared Function ReleaseDC(hwnd As IntPtr, hdc As IntPtr) As Integer
    End Function

    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        MyBase.WndProc(m)
        Select Case m.Msg
            Case WM_NCACTIVATE, WM_NCPAINT, WM_PAINT
                Select Case BorderStyle
                    Case BorderStyle.Fixed3D
                        Dim hdc As IntPtr = GetWindowDC(m.HWnd)
                        Using g As Graphics = Graphics.FromHdc(hdc)
                            DrawBorder(g)
                        End Using
                        ReleaseDC(m.HWnd, hdc)
                    Case BorderStyle.FixedSingle
                        Using g As Graphics = CreateGraphics()
                            DrawBorder(g)
                        End Using
                End Select
        End Select
    End Sub

    Private Sub DrawBorder(g As Graphics)
        Dim bounds As New Rectangle(0, 0, Me.Width - 1, Me.Height - 1)
        If _CustomBorderColor <> Color.FromArgb(171, 173, 179) Then
            Using p As New System.Drawing.Pen(_CustomBorderColor)
                g.DrawRectangle(p, bounds)
            End Using
        Else
            ControlPaint.DrawVisualStyleBorder(g, bounds)
        End If
    End Sub

End Class

Answer 2

SingleでのDrawRectangleが開始点を0,0にしても
TB枠内に表示されてしまいます

この意味が分からなかったのですが、BorderStyle=Fixed3Dの時
ということでしょうか。(参考画像ではSingleで重なっているように見えますが)

ここからは推測です。

文字縦位置を厳密に中心にする為にBorderStyle=Fixed3Dにしたが開始点を0,0
にしても今度は枠線が描画できなかったということですね。
この場合独自コントロールを描画する等の工夫が必要です。
下記が参考になるかと思います。

テキストボックスに入力する値を上下中央揃えにしたい

Answer 3

継承TBと通常TBで文字の縦位置が異なっているのは恐らく

継承TBのBorderStyleはBorderStyle.FixedSingle
通常TBのBorderStyleはBorderStyle.Fixed3D

になっているからだと思います。通常TBをFixedSingleにして比べてみてください。

Comments

[Kruth]

ありがとうございます。

通常TBでもSingleにしたら上よりになりました、これで原因は判明したんですが、SingleでのDrawRectangleが開始点を0,0にしてもTB枠内に表示されてしまいます。

どうしたら枠線の上に描画できますか？
因みに-1,-,1にしたら線が消えました。

[polupolu_0218]

>SingleでのDrawRectangleが開始点を0,0にしても
>TB枠内に表示されてしまいます

この意味が分からなかったのですが、BorderStyle=Fixed3Dの時
ということでしょうか。(参考画像ではSingleで重なっているように見えますが)

ここからは推測です。

文字縦位置を厳密に中心にする為にBorderStyle=Fixed3Dにしたが開始点を0,0
にしても今度は枠線が描画できなかったということですね。
この場合独自コントロールを描画する等の工夫が必要です。
下記が参考になるかと思います。

https://teratail.com/questions/61641