Excelでプルダウンリストのズーム後左上にスクロール

Question

VBAの知識は全くないのですが、ドロップダウンリストの文字が小さすぎて見づらかったので、自分でいろいろと調べて下のコードまでは辿り着きました。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
'updateby Extendoffice 20160530
    On Error GoTo LZoom
    Dim xZoom As Long
    xZoom = 70
    If Target.Validation.Type = xlValidateList Then xZoom = 130
LZoom:
    ActiveWindow.Zoom = xZoom
    ActiveWindow.ScrollColumn = 1
End Sub

このコードだと、Data ValiationがListになっているセルを選択すると130%にズームし、それ以外のセルを選択すると70%に戻ります。(もとの一番見やすい倍率が70%)
コードを調べた段階ではEnd Subのすぐ上のActiveWindow.ScrollColumn = 1の記述はありませんでしたが、70%に戻る時に右側にスクロールされた状態でズームアウトされるのが嫌で、左詰めに戻るように、これを追加しました。
ここまではよかったのですが、今度はListのセルを選択した時もそのセルを中心にズームされるのではなく、左端にスクロールされた状態でズームされるようになってしまいました。
Listのセルを選択したときにはそのセルを中心にズームして、それ以外を選択したときは左端にスクロールしてズームアウトされるようにするにはどうすればいいですか？
よろしくお願いします。

Answer 1

以下のコードに変えたところ、解決しました。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  Dim lZoom As Long
  Dim lZoomDV As Long
  Dim lDVType As Long
  lZoom = 70
  lZoomDV = 130
  lDVType = 0
  Application.EnableEvents = False
  On Error Resume Next
  lDVType = Target.Validation.Type
    On Error GoTo errHandler
    If lDVType <> 3 Then
      With ActiveWindow
        If .Zoom <> lZoom Then
          .Zoom = lZoom
          .ScrollColumn = 1
          .ScrollRow = 1
        End If
      End With
    Else
      With ActiveWindow
        If .Zoom <> lZoomDV Then
          .Zoom = lZoomDV
        End If
      End With
    End If
exitHandler:
  Application.EnableEvents = True
  Exit Sub
errHandler:
  GoTo exitHandler
End Sub