requireと importの違いが分からない

Question

requireと importの違いが分かりません。教えてください。

Answer 1

Elixirのrequireとimportには以下の機能があります。

• require：指定したモジュールで定義されたマクロを使えるようにするためのもの
• import：指定したモジュールで定義された関数とマクロを、モジュール名抜きで使えるようにするためのもの

Elixirのマクロはrequireで明示的にオプトインしないと使えません。一方、publicな関数（defで定義した関数）は、モジュール名.サブモジュール名.関数名()のように完全修飾名（fully-qualified name）で指定すれば使えます。requireによるオプトインは必要ありません。

$ iex
# マクロは使用に先立ってrequireが必要。requireしないとエラーになる
iex> Integer.is_odd(3)
** (CompileError) iex:1: you must require Integer before invoking the macro Integer.is_odd/1
    (elixir) src/elixir_dispatch.erl:97: :elixir_dispatch.dispatch_require/6

# requireすれば使えるようになる。
iex> require Integer
Integer
iex> Integer.is_odd(3)
true

# 関数はrequireなしで使える
iex> List.flatten [1, [2, 3], 4]
[1, 2, 3, 4]

importを使うと関数やマクロを関数名()のようにモジュール名やサブモジュール名抜きの省略形で使えるようになります。

iex> import Integer, only: [ is_odd: 1 ]
Integer
iex> is_odd(3)
true
iex> import List, only: [ flatten: 1 ] 
List
iex> flatten [1, [2, 3], 4]
[1, 2, 3, 4]

なおマクロをimportするとモジュールを自動的にrequireしてくれますので、requireは省略できます。

# iexを立ち上げ直す
$ iex

# この状態ではマクロは使えない
iex> Integer.is_odd(3)
** (CompileError) iex:1: you must require Integer before invoking the macro Integer.is_odd/1
    (elixir) src/elixir_dispatch.erl:97: :elixir_dispatch.dispatch_require/6

# importすると自動的にrequireしてくれるので、別途requireを書かなくてよい
iex> import Integer, only: [ is_odd: 1 ]
Integer
iex> is_odd(3)
true