CSVデータを参照して呼び出すフォームを変えるログインフォームを作りたいです

Question

前提・実現したいこと

ユーザーにIDを入力させ外部のCSVファイルの中に、入力されたIDと同じものがあるかを確認し一致するIDがあった場合は特定のフォームを呼び出す処理を行うログインフォームを作りたいです。
CSVファイルのデータを、TextFieldParserクラスを使用して読み込む処理まではできましたが読み込んだデータに対しての処理で詰まってしまいました。

CSVファイルの中身は以下のようになっております。
ID,ユーザー名,呼び出すフォームの種類を判別する番号※CSVファイル内に表題行は無くデータのみです

1000,田中一郎,1
1001,山田次郎,2
1003,佐藤三郎,1
1004,加藤司郎,3

呼び出すフォームの番号
1→Form1
2→Form2
3→Form3

たとえばユーザーIDが1000の田中さんがログインした場合、呼び出すフォームは1番が割り振られたForm1に、ユーザーIDが1001の山田さんがログインした場合はForm2を呼び出すといった制御にしたいです。

該当のソースコード

 Private Sub OK_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles OK.Click

        '各テキストボックスが空欄の場合メッセージボックスを表示
        If UsernameTextBox.Text = "" Then
            MsgBox("ユーザー名を入力してください。")
            Return
        ElseIf PasswordTextBox.Text = "" Then
            MsgBox("パスワードを入力してください。")
            Return
        End If

	Dim csvRecords As New System.Collections.ArrayList()

        'CSVファイル名
        Dim csvFileName As String = "C:\LoginDate\ID.csv"　'テスト段階なのでローカルです

        'Shift JISで読み込む
        Dim tfp As New FileIO.TextFieldParser(csvFileName,
            System.Text.Encoding.GetEncoding(932))

        'カンマで区切られたデータを仕分ける
        tfp.TextFieldType = FileIO.FieldType.Delimited

        tfp.Delimiters = New String() {","}

        tfp.HasFieldsEnclosedInQuotes = True

        'フィールドの前後からスペースを削除する
        tfp.TrimWhiteSpace = True

        While Not tfp.EndOfData
            'フィールドを読み込む
            Dim fields As String() = tfp.ReadFields()
            '保存
            csvRecords.Add(fields)
        End While


        'フォームを呼び出した後ログインフォームを閉じる
        Me.Close()

    End Sub

補足情報（FW/ツールのバージョンなど）

開発環境：Visual Studio 2017

Comments

[YAmaGNZ]

それで何が分からないのでしょうか？
IDの比較ですか？フォームの呼び出し方ですか？

[退会済みユーザー]

個人に配布する Windows Forms アプリで質問に書かれている個人別のログインフォームを作るのですか？ ユーザーが増えて新たにフォームを作るといった保守ができるのでしょうか？ 将来そういう問題が起きる可能性があるなら、今のうちに方針転換して、Web アプリにすることを考えてみてはいかがですか？

[bv_beg]

質問力が低く、すみません。
3列のデータを読み込み特定の列の値を取得する処理と、取得した値を元にIF文の処理を行う、の二つの処理を行いたかったです。
また、保守運用についてもご指摘いただきありがとうございます。
作成したアプリをサンプルにチーム内で相談いたします。

Answer 1

Dim csvRecords As New System.Collections.ArrayList()

ここなんですが、クラスを作って

Class CsvRecord

    Public Sub New(fields As String())
        Id = fields(0)
        Name = fields(1)
        FormIndex = fields(2)
    End Sub

    Public ReadOnly Property Id As String
    Public ReadOnly Property Name As String
    Public ReadOnly Property FormIndex As String
End Class

Private csvRecords As List(Of CsvRecord) 'モジュールのスコープ

のようにしたほうがいいと思います。

CSV から読み取って csvRecords に格納するのは Load イベントに移して

(略)
csvRecords = New List(Of CsvRecord)()
While Not tfp.EndOfData
    Dim fields As String() = tfp.ReadFields()
    csvRecords.Add(New CsvRecord(fields))
End While

UsernameTextBox の内容から次に起動するフォームを取得する処理は

Private Function GetNextForm() As Form
    For Each item As CsvRecord In csvRecords
        If item.Id = UsernameTextBox.Text Then
            Select Case item.FormIndex
                Case "1"
                    Return New Form1()
                Case "2"
                    Return New Form2()
                Case "3"
                    Return New Form3()
                Case Else
                    Exit For
            End Select
        End If
    Next
    Return Nothing
End Function

となり「フォームを呼び出した後ログインフォームを閉じる」のところは

Dim nextForm As Form = GetNextForm()
If nextForm Is Nothing Then
    MessageBox.Show("ユーザ名またはパスワードが違います。")
    Return
End If
nextForm.Show()
Me.Close()

と書けます。

Comments

[bv_beg]

回答ありがとうございます。
大変助かりました！クラスの作成の勉強にもなりました。
本当にありがとうございました！